X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fgetline.m4;h=57625da5c9d7f5d6279ef8d2826c3ece3f3aa4b7;hb=8eaac7a51d093dbcecc0c2b42a5762a882b4517b;hp=2fd393f0cbffa7b163f9477bf7905e3b83e1a4fc;hpb=06da13180bc1ed8a7ba481ab3308465fdedb649b;p=gnulib.git

diff --git a/m4/getline.m4 b/m4/getline.m4
index 2fd393f0c..57625da5c 100644
--- a/m4/getline.m4
+++ b/m4/getline.m4
@@ -1,32 +1,45 @@
-#serial 2
+# getline.m4 serial 18
+
+dnl Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2005, 2006, 2007 Free
+dnl Software Foundation, Inc.
+dnl
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_PREREQ([2.59])
 
 dnl See if there's a working, system-supplied version of the getline function.
 dnl We can't just do AC_REPLACE_FUNCS(getline) because some systems
 dnl have a function by that name in -linet that doesn't have anything
 dnl to do with the function we need.
-AC_DEFUN(AM_FUNC_GETLINE,
-[dnl
-  am_getline_needs_run_time_check=no
+AC_DEFUN([gl_FUNC_GETLINE],
+[
+  AC_REQUIRE([gl_STDIO_H_DEFAULTS])
+
+  dnl Persuade glibc <stdio.h> to declare getline().
+  AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
+
+  AC_CHECK_DECLS_ONCE([getline])
+
+  gl_getline_needs_run_time_check=no
   AC_CHECK_FUNC(getline,
 		dnl Found it in some library.  Verify that it works.
-		am_getline_needs_run_time_check=yes,
+		gl_getline_needs_run_time_check=yes,
 		am_cv_func_working_getline=no)
-  if test $am_getline_needs_run_time_check = yes; then
-    AC_CHECK_HEADERS(string.h)
+  if test $gl_getline_needs_run_time_check = yes; then
     AC_CACHE_CHECK([for working getline function], am_cv_func_working_getline,
-    [echo fooN |tr -d '\012'|tr N '\012' > conftestdata
+    [echo fooN |tr -d '\012'|tr N '\012' > conftest.data
     AC_TRY_RUN([
 #    include <stdio.h>
-#    include <sys/types.h>
-#    if HAVE_STRING_H
-#     include <string.h>
-#    endif
+#    include <stdlib.h>
+#    include <string.h>
     int main ()
     { /* Based on a test program from Karl Heuer.  */
       char *line = NULL;
       size_t siz = 0;
       int len;
-      FILE *in = fopen ("./conftestdata", "r");
+      FILE *in = fopen ("./conftest.data", "r");
       if (!in)
 	return 1;
       len = getline (&line, &siz, in);
@@ -34,12 +47,35 @@ AC_DEFUN(AM_FUNC_GETLINE,
     }
     ], am_cv_func_working_getline=yes dnl The library version works.
     , am_cv_func_working_getline=no dnl The library version does NOT work.
-    , am_cv_func_working_getline=no dnl We're cross compiling.
+    , dnl We're cross compiling. Assume it works on glibc2 systems.
+      [AC_EGREP_CPP([Lucky GNU user],
+         [
+#include <features.h>
+#ifdef __GNU_LIBRARY__
+ #if (__GLIBC__ >= 2)
+  Lucky GNU user
+ #endif
+#endif
+         ],
+         [am_cv_func_working_getline=yes],
+         [am_cv_func_working_getline=no])]
     )])
   fi
 
+  if test $ac_cv_have_decl_getline = no; then
+    HAVE_DECL_GETLINE=0
+  fi
+
   if test $am_cv_func_working_getline = no; then
-    LIBOBJS="$LIBOBJS getline.o"
-    AC_SUBST(LIBOBJS)dnl
+    REPLACE_GETLINE=1
+    AC_LIBOBJ([getline])
+
+    gl_PREREQ_GETLINE
   fi
 ])
+
+# Prerequisites of lib/getline.c.
+AC_DEFUN([gl_PREREQ_GETLINE],
+[
+  gl_FUNC_GETDELIM
+])