X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fgetline.m4;h=99933455f094b07d37d675e109de3b6483537f91;hb=4097b52187106b6a2940d28968cfecd4e53f9b4e;hp=3564472606e0272610bfb46913bddcd50b0f8553;hpb=409d8f2d902cc6e12e40b08200f5dac27d0e98cb;p=gnulib.git

diff --git a/m4/getline.m4 b/m4/getline.m4
index 356447260..99933455f 100644
--- a/m4/getline.m4
+++ b/m4/getline.m4
@@ -1,32 +1,44 @@
-#serial 1
+# getline.m4 serial 19
+
+dnl Copyright (C) 1998-2003, 2005-2007, 2009 Free Software Foundation, Inc.
+dnl
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_PREREQ([2.59])
 
 dnl See if there's a working, system-supplied version of the getline function.
-dnl We can't just to AC_REPLACE_FUNCS(getline) because some systems
+dnl We can't just do AC_REPLACE_FUNCS([getline]) because some systems
 dnl have a function by that name in -linet that doesn't have anything
 dnl to do with the function we need.
-AC_DEFUN(AM_FUNC_GETLINE,
-[dnl
-  am_getline_needs_run_time_check=no
-  am_cv_func_working_getline=yes
-  AC_CHECK_FUNC(getline,
+AC_DEFUN([gl_FUNC_GETLINE],
+[
+  AC_REQUIRE([gl_STDIO_H_DEFAULTS])
+
+  dnl Persuade glibc <stdio.h> to declare getline().
+  AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
+
+  AC_CHECK_DECLS_ONCE([getline])
+
+  gl_getline_needs_run_time_check=no
+  AC_CHECK_FUNC([getline],
 		dnl Found it in some library.  Verify that it works.
-		am_getline_needs_run_time_check=yes,
+		gl_getline_needs_run_time_check=yes,
 		am_cv_func_working_getline=no)
-  if test $am_getline_needs_run_time_check = yes; then
-    AC_CACHE_CHECK([for working getline function], am_cv_func_working_getline,
-    [echo fooN |tr -d '\012'|tr N '\012' > conftestdata
+  if test $gl_getline_needs_run_time_check = yes; then
+    AC_CACHE_CHECK([for working getline function], [am_cv_func_working_getline],
+    [echo fooN |tr -d '\012'|tr N '\012' > conftest.data
     AC_TRY_RUN([
 #    include <stdio.h>
-#    include <sys/types.h>
-#    if HAVE_STRING_H
-#     include <string.h>
-#    endif
+#    include <stdlib.h>
+#    include <string.h>
     int main ()
     { /* Based on a test program from Karl Heuer.  */
       char *line = NULL;
       size_t siz = 0;
       int len;
-      FILE *in = fopen ("./conftestdata", "r");
+      FILE *in = fopen ("./conftest.data", "r");
       if (!in)
 	return 1;
       len = getline (&line, &siz, in);
@@ -34,12 +46,35 @@ AC_DEFUN(AM_FUNC_GETLINE,
     }
     ], am_cv_func_working_getline=yes dnl The library version works.
     , am_cv_func_working_getline=no dnl The library version does NOT work.
-    , am_cv_func_working_getline=no dnl We're cross compiling.
+    , dnl We're cross compiling. Assume it works on glibc2 systems.
+      [AC_EGREP_CPP([Lucky GNU user],
+         [
+#include <features.h>
+#ifdef __GNU_LIBRARY__
+ #if (__GLIBC__ >= 2)
+  Lucky GNU user
+ #endif
+#endif
+         ],
+         [am_cv_func_working_getline=yes],
+         [am_cv_func_working_getline=no])]
     )])
   fi
 
+  if test $ac_cv_have_decl_getline = no; then
+    HAVE_DECL_GETLINE=0
+  fi
+
   if test $am_cv_func_working_getline = no; then
-    LIBOBJS="$LIBOBJS getline.o"
-    AC_SUBST(LIBOBJS)dnl
+    REPLACE_GETLINE=1
+    AC_LIBOBJ([getline])
+
+    gl_PREREQ_GETLINE
   fi
 ])
+
+# Prerequisites of lib/getline.c.
+AC_DEFUN([gl_PREREQ_GETLINE],
+[
+  gl_FUNC_GETDELIM
+])