X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fmemcmp.m4;h=db1146b1abcf5f1938a7c965f2ba7805eeae82b2;hb=c140b280d2ce855161817b9a79cfe821b05312b8;hp=1c08adc220cde9e7eb906c2db22e74f8f0b13f71;hpb=e62d4d88ece0086446631e65b3f647d9696b04c3;p=gnulib.git

diff --git a/m4/memcmp.m4 b/m4/memcmp.m4
index 1c08adc22..db1146b1a 100644
--- a/m4/memcmp.m4
+++ b/m4/memcmp.m4
@@ -1,52 +1,68 @@
-#serial 3
+# memcmp.m4 serial 15
+dnl Copyright (C) 2002-2004, 2007-2011 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
 
-dnl A replacement for autoconf's AC_FUNC_MEMCMP that detects
-dnl the losing memcmp on some x86 Next systems.
-AC_DEFUN(jm_AC_FUNC_MEMCMP,
-[AC_CACHE_CHECK([for working memcmp], jm_cv_func_memcmp_working,
-[AC_TRY_RUN(
-changequote(<<, >>)dnl
-<<
-main()
-{
-  /* Some versions of memcmp are not 8-bit clean.  */
-  char c0 = 0x40, c1 = 0x80, c2 = 0x81;
-  if (memcmp(&c0, &c2, 1) >= 0 || memcmp(&c1, &c2, 1) >= 0)
-    exit (1);
-
-  /* The Next x86 OpenStep bug shows up only when comparing 16 bytes
-     or more and with at least one buffer not starting on a 4-byte boundary.
-     William Lewis provided this test program.   */
-  {
-    char foo[21];
-    char bar[21];
-    int i;
-    for (i = 0; i < 4; i++)
-      {
-	char *a = foo + i;
-	char *b = bar + i;
-	strcpy (a, "--------01111111");
-	strcpy (b, "--------10000000");
-	if (memcmp (a, b, 16) >= 0)
-	  exit (1);
-      }
-    exit (0);
-  }
-}
->>,
-changequote([, ])dnl
-   jm_cv_func_memcmp_working=yes,
-   jm_cv_func_memcmp_working=no,
-   jm_cv_func_memcmp_working=no)])
-test $jm_cv_func_memcmp_working = no \
-  && LIBOBJS="$LIBOBJS memcmp.$ac_objext"
-AC_SUBST(LIBOBJS)dnl
+AC_DEFUN([gl_FUNC_MEMCMP],
+[
+  if test $cross_compiling != no; then
+    # AC_FUNC_MEMCMP as of 2.62 defaults to 'no' when cross compiling.
+    # We default to yes if memcmp appears to exist, which works
+    # better for MinGW.
+    AC_CACHE_CHECK([whether cross-compiling target has memcmp],
+                   [ac_cv_func_memcmp_working],
+                   [AC_LINK_IFELSE([
+                        AC_LANG_PROGRAM([[#include <string.h>
+                                ]], [[int ret = memcmp ("foo", "bar", 0);]])],
+                        [ac_cv_func_memcmp_working=yes],
+                        [ac_cv_func_memcmp_working=no])])
+  fi
+  AC_FUNC_MEMCMP
+  dnl Note: AC_FUNC_MEMCMP does AC_LIBOBJ([memcmp]).
+  if test $ac_cv_func_memcmp_working = no; then
+    AC_DEFINE([memcmp], [rpl_memcmp],
+      [Define to rpl_memcmp if the replacement function should be used.])
+    gl_PREREQ_MEMCMP
+  fi
 ])
 
-AC_DEFUN(jm_FUNC_MEMCMP,
-[AC_REQUIRE([jm_AC_FUNC_MEMCMP])dnl
- if test $jm_cv_func_memcmp_working = no; then
-   AC_DEFINE_UNQUOTED(memcmp, rpl_memcmp,
-     [Define to rpl_memcmp if the replacement function should be used.])
- fi
+# Redefine AC_FUNC_MEMCMP, because it is no longer maintained in Autoconf.
+AC_DEFUN([AC_FUNC_MEMCMP],
+[
+  AC_CACHE_CHECK([for working memcmp], [ac_cv_func_memcmp_working],
+    [AC_RUN_IFELSE(
+       [AC_LANG_PROGRAM(
+          [AC_INCLUDES_DEFAULT],
+          [[/* Some versions of memcmp are not 8-bit clean.  */
+            char c0 = '\100', c1 = '\200', c2 = '\201';
+            if (memcmp(&c0, &c2, 1) >= 0 || memcmp(&c1, &c2, 1) >= 0)
+              return 1;
+            /* The Next x86 OpenStep bug shows up only when comparing 16 bytes
+               or more and with at least one buffer not starting on a 4-byte
+               boundary.  William Lewis provided this test program.   */
+            {
+              char foo[21];
+              char bar[21];
+              int i;
+              for (i = 0; i < 4; i++)
+                {
+                  char *a = foo + i;
+                  char *b = bar + i;
+                  strcpy (a, "--------01111111");
+                  strcpy (b, "--------10000000");
+                  if (memcmp (a, b, 16) >= 0)
+                    return 1;
+                }
+              return 0;
+            }
+          ]])],
+       [ac_cv_func_memcmp_working=yes],
+       [ac_cv_func_memcmp_working=no],
+       [ac_cv_func_memcmp_working=no])])
+  test $ac_cv_func_memcmp_working = no &&
+    AC_LIBOBJ([memcmp])
 ])
+
+# Prerequisites of lib/memcmp.c.
+AC_DEFUN([gl_PREREQ_MEMCMP], [:])