X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fpread.m4;h=09a970760a2c68aa8e32fcdaaab57457fa3ad7f0;hb=21492d6c3ca00ff0827528640804732f2ed66470;hp=f1425a6b1de25b30e9c2f598f0a041da416714a8;hpb=978114f6f3d4c5d0c1fd7f2bb1f48a37bab89553;p=gnulib.git

diff --git a/m4/pread.m4 b/m4/pread.m4
index f1425a6b1..09a970760 100644
--- a/m4/pread.m4
+++ b/m4/pread.m4
@@ -1,5 +1,5 @@
-# pread.m4 serial 2
-dnl Copyright (C) 2009-2010 Free Software Foundation, Inc.
+# pread.m4 serial 5
+dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
@@ -7,12 +7,79 @@ dnl with or without modifications, as long as this notice is preserved.
 AC_DEFUN([gl_FUNC_PREAD],
 [
   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+
   dnl Persuade glibc <unistd.h> to declare pread().
   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 
   AC_CHECK_FUNCS_ONCE([pread])
-  if test $ac_cv_func_pread = no; then
+  if test $ac_cv_func_pread = yes; then
+    dnl On HP-UX 11.11 with _FILE_OFFSET_BITS=64, pread() on a file returns 0
+    dnl instead of a positive value.
+    dnl On HP-UX 11.31, pread() on a pipe does not fail.
+    AC_CACHE_CHECK([whether pread works],
+      [gl_cv_func_pread_works],
+      [
+        dnl Initial guess, used when cross-compiling.
+changequote(,)dnl
+        case "$host_os" in
+                 # Guess no on HP-UX.
+          hpux*) gl_cv_func_pread_works="guessing no" ;;
+                 # Guess yes otherwise.
+          *)     gl_cv_func_pread_works="guessing yes" ;;
+        esac
+changequote([,])dnl
+        gl_save_CPPFLAGS="$CPPFLAGS"
+        CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=64"
+        AC_RUN_IFELSE(
+          [AC_LANG_PROGRAM([[
+#include <sys/types.h>
+#include <unistd.h>
+#include <fcntl.h>
+#include <stdio.h>
+             ]],
+             [[
+{
+  int result = 0;
+  /* This test fails on HP-UX 11.00..11.11.  */
+  {
+    int fd = open ("conftest.c", O_RDONLY);
+    if (fd < 0)
+      result |= 1;
+    else
+      {
+        char byte_buf;
+        if (pread (fd, &byte_buf, 1, (off_t) 0) != 1)
+          result |= 2;
+        close (fd);
+      }
+  }
+  /* This test fails on HP-UX 11.00..11.31.  */
+  {
+    FILE *fp = popen ("echo", "r");
+    if (fp == NULL)
+      result |= 1;
+    else
+      {
+        int fd = fileno (fp);
+        char byte_buf;
+        if (pread (fd, &byte_buf, 1, (off_t) 0) >= 0)
+          result |= 4;
+        pclose (fp);
+      }
+  }
+  return result;
+}]])],
+          [gl_cv_func_pread_works=yes],
+          [gl_cv_func_pread_works=no],
+          [:])
+        CPPFLAGS="$gl_save_CPPFLAGS"
+      ])
+    case "$gl_cv_func_pread_works" in
+      *yes) ;;
+      *) REPLACE_PREAD=1 ;;
+    esac
+  else
     HAVE_PREAD=0
-    AC_LIBOBJ([pread])
   fi
 ])