X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Freadline.m4;h=60b0aa8fb0a5116af2233cf7535474eeb4436b8c;hb=95be85947415fc9c52cd4ee535fcb3c5eb34bd91;hp=d9555070a7fd200cc9d7b6e91945dc58899f47d5;hpb=907eac00481355b563fd81872899eeea60417904;p=gnulib.git

diff --git a/m4/readline.m4 b/m4/readline.m4
index d9555070a..60b0aa8fb 100644
--- a/m4/readline.m4
+++ b/m4/readline.m4
@@ -1,13 +1,14 @@
-# readline.m4 serial 1
-dnl Copyright (C) 2005 Free Software Foundation, Inc.
+# readline.m4 serial 6
+dnl Copyright (C) 2005, 2006, 2009 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
+dnl Written by Simon Josefsson, with help from Bruno Haible and Oskar
+dnl Liljeblad.
+
 AC_DEFUN([gl_FUNC_READLINE],
 [
-  AC_LIBSOURCES([readline.c, readline.h])
-
   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
   AC_REQUIRE([AC_LIB_RPATH])
@@ -23,36 +24,52 @@ AC_DEFUN([gl_FUNC_READLINE],
   am_save_CPPFLAGS="$CPPFLAGS"
   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE])
 
-  AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
+  AC_CACHE_CHECK([for readline], [gl_cv_lib_readline], [
     gl_cv_lib_readline=no
     am_save_LIBS="$LIBS"
-    LIBS="$LIBS $LIBREADLINE"
-    AC_TRY_LINK([#include <stdio.h>
+    dnl On some systems, -lreadline doesn't link without an additional
+    dnl -lncurses or -ltermcap.
+    dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
+    dnl by design and obsolete since 1994. Try -lcurses last, because
+    dnl libcurses is unusable on some old Unices.
+    for extra_lib in "" ncurses termcap curses; do
+      LIBS="$am_save_LIBS $LIBREADLINE"
+      if test -n "$extra_lib"; then
+        LIBS="$LIBS -l$extra_lib"
+      fi
+      AC_TRY_LINK([#include <stdio.h>
 #include <readline/readline.h>],
-      [readline((char*)0);],
-      gl_cv_lib_readline=yes)
+        [readline((char*)0);],
+        [gl_cv_lib_readline=" -l$extra_lib"])
+      if test "$gl_cv_lib_readline" != no; then
+	break
+      fi
+    done
     LIBS="$am_save_LIBS"
   ])
-  if test "$gl_cv_lib_readline" = yes; then
-    AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline() library.])
-  fi
-  if test "$gl_cv_lib_readline" = yes; then
+
+  if test "$gl_cv_lib_readline" != no; then
+    AC_DEFINE([HAVE_READLINE], [1], [Define if you have the readline library.])
+    if test "$gl_cv_lib_readline" != " -l"; then
+      LIBREADLINE="$LIBREADLINE$gl_cv_lib_readline"
+      LTLIBREADLINE="$LTLIBREADLINE$gl_cv_lib_readline"
+    fi
     AC_MSG_CHECKING([how to link with libreadline])
     AC_MSG_RESULT([$LIBREADLINE])
   else
-    dnl If $LIBREADLINE didn't lead to a usable library, we don't need $INCREADLINE
-    dnl either.
+    dnl If $LIBREADLINE didn't lead to a usable library, we don't
+    dnl need $INCREADLINE either.
     CPPFLAGS="$am_save_CPPFLAGS"
     LIBREADLINE=
     LTLIBREADLINE=
   fi
-  AC_SUBST(LIBREADLINE)
-  AC_SUBST(LTLIBREADLINE)
+  AC_SUBST([LIBREADLINE])
+  AC_SUBST([LTLIBREADLINE])
 
-  AC_CHECK_HEADERS(readline/readline.h)
+  AC_CHECK_HEADERS([readline/readline.h])
 
   if test $gl_cv_lib_readline = no; then
-    AC_LIBOBJ(readline)
+    AC_LIBOBJ([readline])
     gl_PREREQ_READLINE
   fi
 ])