X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Freadline.m4;h=a5ab06783aabe2b353dd9e7270f738e56a356b4e;hb=a2eb92ef60dd05e9423948534ab483f7ffeb0647;hp=3082d1bf6de93a923434f93df4cea02c8d016c7c;hpb=2d9b725eac0cc54aa423623ae5c48376d4460722;p=gnulib.git

diff --git a/m4/readline.m4 b/m4/readline.m4
index 3082d1bf6..a5ab06783 100644
--- a/m4/readline.m4
+++ b/m4/readline.m4
@@ -1,5 +1,5 @@
-# readline.m4 serial 2
-dnl Copyright (C) 2005 Free Software Foundation, Inc.
+# readline.m4 serial 9
+dnl Copyright (C) 2005-2006, 2009-2011 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
@@ -9,8 +9,6 @@ dnl Liljeblad.
 
 AC_DEFUN([gl_FUNC_READLINE],
 [
-  AC_LIBSOURCES([readline.c, readline.h])
-
   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
   AC_REQUIRE([AC_LIB_RPATH])
@@ -21,39 +19,47 @@ AC_DEFUN([gl_FUNC_READLINE],
 
   dnl Add $INCREADLINE to CPPFLAGS before performing the following checks,
   dnl because if the user has installed libreadline and not disabled its use
-  dnl via --without-libreadline-prefix, he wants to use it. The AC_TRY_LINK
+  dnl via --without-libreadline-prefix, he wants to use it. The AC_LINK_IFELSE
   dnl will then succeed.
   am_save_CPPFLAGS="$CPPFLAGS"
   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCREADLINE])
 
-  AC_CACHE_CHECK(for readline, gl_cv_lib_readline, [
+  AC_CACHE_CHECK([for readline], [gl_cv_lib_readline], [
     gl_cv_lib_readline=no
     am_save_LIBS="$LIBS"
-    for extra_lib in "" termcap curses ncurses; do
+    dnl On some systems, -lreadline doesn't link without an additional
+    dnl -lncurses or -ltermcap.
+    dnl Try -lncurses before -ltermcap, because libtermcap is unsecure
+    dnl by design and obsolete since 1994. Try -lcurses last, because
+    dnl libcurses is unusable on some old Unices.
+    for extra_lib in "" ncurses termcap curses; do
       LIBS="$am_save_LIBS $LIBREADLINE"
       if test -n "$extra_lib"; then
         LIBS="$LIBS -l$extra_lib"
       fi
-      AC_TRY_LINK([#include <stdio.h>
-#include <readline/readline.h>],
-        [readline((char*)0);],
-        gl_cv_lib_readline=yes)
-      if test "$gl_cv_lib_readline" = yes; then
-        if test -n "$extra_lib"; then
-          LIBREADLINE="$LIBREADLINE -l$extra_lib"
-          LTLIBREADLINE="$LTLIBREADLINE -l$extra_lib"
-        fi
+      AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
+#include <readline/readline.h>]],
+          [[readline((char*)0);]])],
+        [if test -n "$extra_lib"; then
+           gl_cv_lib_readline="yes, requires -l$extra_lib"
+         else
+           gl_cv_lib_readline="yes"
+         fi
+        ])
+      if test "$gl_cv_lib_readline" != no; then
         break
       fi
     done
     LIBS="$am_save_LIBS"
   ])
 
-  if test "$gl_cv_lib_readline" = yes; then
-    AC_DEFINE(HAVE_READLINE, 1, [Define if you have the readline library.])
-  fi
-
-  if test "$gl_cv_lib_readline" = yes; then
+  if test "$gl_cv_lib_readline" != no; then
+    AC_DEFINE([HAVE_READLINE], [1], [Define if you have the readline library.])
+    extra_lib=`echo "$gl_cv_lib_readline" | sed -n -e 's/yes, requires //p'`
+    if test -n "$extra_lib"; then
+      LIBREADLINE="$LIBREADLINE $extra_lib"
+      LTLIBREADLINE="$LTLIBREADLINE $extra_lib"
+    fi
     AC_MSG_CHECKING([how to link with libreadline])
     AC_MSG_RESULT([$LIBREADLINE])
   else
@@ -63,15 +69,10 @@ AC_DEFUN([gl_FUNC_READLINE],
     LIBREADLINE=
     LTLIBREADLINE=
   fi
-  AC_SUBST(LIBREADLINE)
-  AC_SUBST(LTLIBREADLINE)
+  AC_SUBST([LIBREADLINE])
+  AC_SUBST([LTLIBREADLINE])
 
-  AC_CHECK_HEADERS(readline/readline.h)
-
-  if test $gl_cv_lib_readline = no; then
-    AC_LIBOBJ(readline)
-    gl_PREREQ_READLINE
-  fi
+  AC_CHECK_HEADERS([readline/readline.h])
 ])
 
 # Prerequisites of lib/readline.c.