X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fregex.m4;h=a31ef2c0708b3e2fc4dcb49a9ce839f0c2a2b959;hb=dd2c1e84650acc6eaafa2675c5c689104103d029;hp=3047d4d4970aad1bbfb49f8d875a4ba821800b78;hpb=a24cd80cd36f4de9693248ffa746638f1a15bb4c;p=gnulib.git

diff --git a/m4/regex.m4 b/m4/regex.m4
index 3047d4d49..a31ef2c07 100644
--- a/m4/regex.m4
+++ b/m4/regex.m4
@@ -1,11 +1,16 @@
-#serial 5
+#serial 14
 
 dnl Initially derived from code in GNU grep.
 dnl Mostly written by Jim Meyering.
 
+AC_DEFUN([gl_REGEX],
+[
+  jm_INCLUDED_REGEX([lib/regex.c])
+])
+
 dnl Usage: jm_INCLUDED_REGEX([lib/regex.c])
 dnl
-AC_DEFUN(jm_INCLUDED_REGEX,
+AC_DEFUN([jm_INCLUDED_REGEX],
   [
     dnl Even packages that don't use regex.c can use this macro.
     dnl Of course, for them it doesn't do anything.
@@ -16,30 +21,48 @@ AC_DEFUN(jm_INCLUDED_REGEX,
     # However, if the system regex support is good enough that it passes the
     # the following run test, then default to *not* using the included regex.c.
     # If cross compiling, assume the test would fail and use the included
-    # regex.c.  The failing regular expression is from `Spencer ere test #75'
-    # in grep-2.3.
+    # regex.c.  The first failing regular expression is from `Spencer ere
+    # test #75' in grep-2.3.
     AC_CACHE_CHECK([for working re_compile_pattern],
 		   jm_cv_func_working_re_compile_pattern,
       AC_TRY_RUN(
-	changequote(<<, >>)dnl
-	<<
-#include <stdio.h>
+[#include <stdio.h>
+#include <string.h>
 #include <regex.h>
 	  int
 	  main ()
 	  {
 	    static struct re_pattern_buffer regex;
 	    const char *s;
+	    struct re_registers regs;
 	    re_set_syntax (RE_SYNTAX_POSIX_EGREP);
-	    /* Add this third left square bracket, [, to balance the
-	       three right ones below.  Otherwise autoconf-2.14 chokes.  */
-	    s = re_compile_pattern ("a[[:]:]]b\n", 9, &regex);
+	    memset (&regex, 0, sizeof (regex));
+	    [s = re_compile_pattern ("a[[:@:>@:]]b\n", 9, &regex);]
 	    /* This should fail with _Invalid character class name_ error.  */
-	    exit (s ? 0 : 1);
-	  }
-	>>,
-	changequote([, ])dnl
+	    if (!s)
+	      exit (1);
+
+	    /* This should succeed, but doesn't for e.g. glibc-2.1.3.  */
+	    memset (&regex, 0, sizeof (regex));
+	    s = re_compile_pattern ("{1", 2, &regex);
+
+	    if (s)
+	      exit (1);
+
+	    /* The following example is derived from a problem report
+               against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
+	    memset (&regex, 0, sizeof (regex));
+	    s = re_compile_pattern ("[[anù]]*n", 7, &regex);
+	    if (s)
+	      exit (1);
+
+	    /* This should match, but doesn't for e.g. glibc-2.2.1.  */
+	    if (re_match (&regex, "an", 2, 0, &regs) != 2)
+	      exit (1);
 
+	    exit (0);
+	  }
+	],
 	       jm_cv_func_working_re_compile_pattern=yes,
 	       jm_cv_func_working_re_compile_pattern=no,
 	       dnl When crosscompiling, assume it's broken.
@@ -49,10 +72,9 @@ AC_DEFUN(jm_INCLUDED_REGEX,
     fi
 
     test -n "$1" || AC_MSG_ERROR([missing argument])
-    syscmd([test -f $1])
-    ifelse(sysval, 0,
+    m4_syscmd([test -f $1])
+    ifelse(m4_sysval, 0,
       [
-
 	AC_ARG_WITH(included-regex,
 	[  --without-included-regex don't compile regex; this is the default on
                           systems with version 2 of the GNU C library
@@ -60,10 +82,27 @@ AC_DEFUN(jm_INCLUDED_REGEX,
 		    jm_with_regex=$withval,
 		    jm_with_regex=$ac_use_included_regex)
 	if test "$jm_with_regex" = yes; then
-	  AC_SUBST(LIBOBJS)
-	  LIBOBJS="$LIBOBJS regex.$ac_objext"
+	  AC_LIBOBJ(regex)
+	  jm_PREREQ_REGEX
 	fi
       ],
     )
   ]
 )
+
+# Prerequisites of lib/regex.c.
+AC_DEFUN([jm_PREREQ_REGEX],
+[
+  dnl FIXME: Maybe provide a btowc replacement someday: solaris-2.5.1 lacks it.
+  dnl FIXME: Check for wctype and iswctype, and and add -lw if necessary
+  dnl to get them.
+
+  dnl Persuade glibc <string.h> to declare mempcpy().
+  AC_REQUIRE([AC_GNU_SOURCE])
+
+  AC_REQUIRE([AC_FUNC_ALLOCA])
+  AC_REQUIRE([AC_HEADER_STDC])
+  AC_CHECK_HEADERS_ONCE(limits.h string.h wchar.h wctype.h)
+  AC_CHECK_FUNCS_ONCE(isascii mempcpy)
+  AC_CHECK_FUNCS(btowc)
+])