X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Froundl.m4;h=f7fe0e8b88cd994ab1ff6642cb5c19d5394c07a3;hb=ec919e79c7278b5b69aced77c453e5b165accfcf;hp=6bec36bdc1a21d62ab14985486a95d6487ea0c86;hpb=980d2709cea1e46299cb5b4f74f7c7a95d07ef06;p=gnulib.git

diff --git a/m4/roundl.m4 b/m4/roundl.m4
index 6bec36bdc..f7fe0e8b8 100644
--- a/m4/roundl.m4
+++ b/m4/roundl.m4
@@ -1,5 +1,5 @@
-# roundl.m4 serial 1
-dnl Copyright (C) 2007 Free Software Foundation, Inc.
+# roundl.m4 serial 7
+dnl Copyright (C) 2007, 2009-2010 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
@@ -9,14 +9,42 @@ AC_DEFUN([gl_FUNC_ROUNDL],
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   dnl Persuade glibc <math.h> to declare roundl().
   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
-  dnl Test whether roundl() is declared.
-  gl_CHECK_LIBM_FUNC([roundl], [x = roundl(x);], [], [
-    dnl No.  Are both floorl() and ceill() available?  If so then we can use
-    dnl them to implement roundl(), on the assumption that they're fast.
-    gl_CHECK_LIBM_FUNC([floorl], [x = floorl(x);], [
-      AC_CHECK_DECL([ceill], 
-        [dnl Yes.  Both are declared.  Link against the necessary library.
-         ROUNDL_LIBM="$FLOORL_LIBM"],
-        [: dnl No. We will use an implementation that doesn't need them.
-], [#include <math.h>
-])])])])
+  AC_CHECK_DECLS([roundl], , , [#include <math.h>])
+  if test "$ac_cv_have_decl_roundl" = yes; then
+    gl_CHECK_MATH_LIB([ROUNDL_LIBM], [x = roundl (x);])
+    if test "$ROUNDL_LIBM" = missing; then
+      REPLACE_ROUNDL=1
+    fi
+  else
+    HAVE_DECL_ROUNDL=0
+  fi
+  if test $HAVE_DECL_ROUNDL = 0 || test $REPLACE_ROUNDL = 1; then
+    AC_LIBOBJ([roundl])
+    AC_CHECK_DECLS([ceill, floorl], , , [#include <math.h>])
+    if test "$ac_cv_have_decl_floorl" = yes \
+       && test "$ac_cv_have_decl_ceill" = yes; then
+      gl_FUNC_FLOORL_LIBS
+      gl_FUNC_CEILL_LIBS
+      if test "$FLOORL_LIBM" != '?' && test "$CEILL_LIBM" != '?'; then
+        AC_DEFINE([HAVE_FLOORL_AND_CEILL], [1],
+          [Define if the both the floorl() and ceill() functions exist.])
+        ROUNDL_LIBM=
+        dnl Append $FLOORL_LIBM to ROUNDL_LIBM, avoiding gratuitous duplicates.
+        case " $ROUNDL_LIBM " in
+          *" $FLOORL_LIBM "*) ;;
+          *) ROUNDL_LIBM="$ROUNDL_LIBM $FLOORL_LIBM" ;;
+        esac
+        dnl Append $CEILL_LIBM to ROUNDL_LIBM, avoiding gratuitous duplicates.
+        case " $ROUNDL_LIBM " in
+          *" $CEILL_LIBM "*) ;;
+          *) ROUNDL_LIBM="$ROUNDL_LIBM $CEILL_LIBM" ;;
+        esac
+      else
+        ROUNDL_LIBM=
+      fi
+    else
+      ROUNDL_LIBM=
+    fi
+  fi
+  AC_SUBST([ROUNDL_LIBM])
+])