X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fstrerror_r.m4;h=28924b1752b9e96b729643f61127b4efb88d21d6;hb=07ca91adc3957e0066d8813468a71047b5bc1db0;hp=e886b5cc5b8faa3710828740b8aca4c230be0f2d;hpb=daceb50a3ec9cc2768b4849489cb33cf34fedcaa;p=gnulib.git

diff --git a/m4/strerror_r.m4 b/m4/strerror_r.m4
index e886b5cc5..28924b175 100644
--- a/m4/strerror_r.m4
+++ b/m4/strerror_r.m4
@@ -1,39 +1,49 @@
-#serial 1
+#serial 1004
+# This file is not needed if you can assume Autoconf 2.54 or later.
+# Experimental replacement for the function in the latest CVS autoconf.
+# Use with the error.c file in ../lib.
 
-dnl From Jim Meyering.
-dnl Determine whether the strerror_r implementation is one of
-dnl the broken ones that returns `int' rather than `char*'.
-dnl Actually, this tests only whether it returns an array,
-dnl but that should be enough.
-dnl This is used by lib/error.c.
+# Copyright (C) 2001 Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
 
-AC_DEFUN(jm_FUNC_STRERROR_R,
-[
-  # Check strerror_r
-  AC_CHECK_FUNCS([strerror_r])
-  if test $ac_cv_func_strerror_r = yes; then
-    AC_CHECK_HEADERS(string.h)
-    AC_CACHE_CHECK([for working strerror_r],
-                   jm_cv_func_working_strerror_r,
-     [
-      AC_TRY_COMPILE(
-       [
-#       include <stdio.h>
-#       if HAVE_STRING_H
-#        include <string.h>
-#       endif
-       ],
-       [
-	 int buf; /* avoiding square brackets makes this easier */
-	 char x = *strerror_r (0, buf, sizeof buf);
-       ],
-       jm_cv_func_working_strerror_r=yes,
-       jm_cv_func_working_strerror_r=no
-      )
-      if test $jm_cv_func_working_strerror_r = yes; then
-	AC_DEFINE_UNQUOTED(HAVE_WORKING_STRERROR_R, 1,
-	  [Define to 1 if strerror_r returns a string.])
-      fi
-    ])
-  fi
-])
+undefine([AC_FUNC_STRERROR_R])
+
+# AC_FUNC_STRERROR_R
+# ------------------
+AC_DEFUN([AC_FUNC_STRERROR_R],
+[AC_CHECK_DECLS([strerror_r])
+AC_CHECK_FUNCS([strerror_r])
+AC_CACHE_CHECK([whether strerror_r returns char *],
+               ac_cv_func_strerror_r_char_p,
+   [
+    ac_cv_func_strerror_r_char_p=no
+    if test $ac_cv_have_decl_strerror_r = yes; then
+      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
+	[[
+	  char buf[100];
+	  char x = *strerror_r (0, buf, sizeof buf);
+	  char *p = strerror_r (0, buf, sizeof buf);
+	]])],
+			ac_cv_func_strerror_r_char_p=yes)
+    else
+      # strerror_r is not declared.  Choose between
+      # systems that have relatively inaccessible declarations for the
+      # function.  BeOS and DEC UNIX 4.0 fall in this category, but the
+      # former has a strerror_r that returns char*, while the latter
+      # has a strerror_r that returns `int'.
+      # This test should segfault on the DEC system.
+      AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
+	extern char *strerror_r ();],
+	[[char buf[100];
+	  char x = *strerror_r (0, buf, sizeof buf);
+	  exit (!isalpha (x));]])],
+                    ac_cv_func_strerror_r_char_p=yes, , :)
+    fi
+  ])
+if test $ac_cv_func_strerror_r_char_p = yes; then
+  AC_DEFINE([STRERROR_R_CHAR_P], 1,
+	    [Define to 1 if strerror_r returns char *.])
+fi
+])# AC_FUNC_STRERROR_R