X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fstrndup.m4;h=dd5780b6350859e6c151fa86f61525e65670ca33;hb=69d25acfd85067031a54285fb933d2e3ccfb0055;hp=66cedb4334c1af2cf0292db9f5738129343254cf;hpb=4a31fee0519738513fdc037c8022384db8c1239d;p=gnulib.git

diff --git a/m4/strndup.m4 b/m4/strndup.m4
index 66cedb433..dd5780b63 100644
--- a/m4/strndup.m4
+++ b/m4/strndup.m4
@@ -1,18 +1,45 @@
-# strndup.m4 serial 5
-dnl Copyright (C) 2002, 2003, 2005 Free Software Foundation, Inc.
+# strndup.m4 serial 11
+dnl Copyright (C) 2002-2003, 2005-2006 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_STRNDUP],
 [
-  AC_LIBSOURCES([strndup.c, strndup.h])
-
   dnl Persuade glibc <string.h> to declare strndup().
   AC_REQUIRE([AC_GNU_SOURCE])
 
-  AC_REPLACE_FUNCS(strndup)
-  if test $ac_cv_func_strndup = no; then
+  AC_CHECK_DECLS_ONCE([strndup])
+
+  # AIX 4.3.3, AIX 5.1 have a function that fails to add the terminating '\0'.
+  AC_CACHE_CHECK([for working strndup], gl_cv_func_strndup,
+    [AC_RUN_IFELSE([
+       AC_LANG_PROGRAM([#include <string.h>
+		 	#include <stdlib.h>], [[
+#ifndef HAVE_DECL_STRNDUP
+  extern char *strndup (const char *, size_t);
+#endif
+  char *s;
+  s = strndup ("some longer string", 15);
+  free (s);
+  s = strndup ("shorter string", 13);
+  return s[13] != '\0';]])],
+       [gl_cv_func_strndup=yes],
+       [gl_cv_func_strndup=no],
+       [AC_CHECK_FUNC([strndup],
+          [AC_EGREP_CPP([too risky], [
+#ifdef _AIX
+               too risky
+#endif
+             ],
+             [gl_cv_func_strndup=no],
+             [gl_cv_func_strndup=yes])],
+          [gl_cv_func_strndup=no])])])
+  if test $gl_cv_func_strndup = yes; then
+    AC_DEFINE([HAVE_STRNDUP], 1,
+      [Define if you have the strndup() function and it works.])
+  else
+    AC_LIBOBJ([strndup])
     gl_PREREQ_STRNDUP
   fi
 ])