X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fstrstr.m4;h=f48bebb6dd143cec4d890caa28bb05b0d2d5fa0f;hb=dbf8ca54bfdeaef894c8d0912df6e05b4c1a7302;hp=0fe0f73cde6334f028e04169832c079dd04cbcf0;hpb=52aceb00a8ce321a73680b2d5890de75be23f29f;p=gnulib.git

diff --git a/m4/strstr.m4 b/m4/strstr.m4
index 0fe0f73cd..f48bebb6d 100644
--- a/m4/strstr.m4
+++ b/m4/strstr.m4
@@ -1,16 +1,64 @@
-# strstr.m4 serial 2
-dnl Copyright (C) 2002-2003 Free Software Foundation, Inc.
+# strstr.m4 serial 5
+dnl Copyright (C) 2008 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
+dnl Check that strstr is efficient.
 AC_DEFUN([gl_FUNC_STRSTR],
 [
-  AC_REPLACE_FUNCS(strstr)
-  if test $ac_cv_func_strstr = no; then
-    gl_PREREQ_STRSTR
+  AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
+  AC_CACHE_CHECK([whether strstr works in linear time],
+    [gl_cv_func_strstr_linear],
+    [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
+#include <signal.h> /* for signal */
+#include <string.h> /* for memmem */
+#include <stdlib.h> /* for malloc */
+#include <unistd.h> /* for alarm */
+]], [[size_t m = 1000000;
+    char *haystack = (char *) malloc (2 * m + 2);
+    char *needle = (char *) malloc (m + 2);
+    void *result = 0;
+    /* Failure to compile this test due to missing alarm is okay,
+       since all such platforms (mingw) also have quadratic strstr.  */
+    signal (SIGALRM, SIG_DFL);
+    alarm (5);
+    /* Check for quadratic performance.  */
+    if (haystack && needle)
+      {
+	memset (haystack, 'A', 2 * m);
+	haystack[2 * m] = 'B';
+	haystack[2 * m + 1] = 0;
+	memset (needle, 'A', m);
+	needle[m] = 'B';
+	needle[m + 1] = 0;
+	result = strstr (haystack, needle);
+      }
+    return !result;]])],
+      [gl_cv_func_strstr_linear=yes], [gl_cv_func_strstr_linear=no],
+      [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
+       dnl strstr that works in linear time.
+       AC_EGREP_CPP([Lucky user],
+	 [
+#include <features.h>
+#ifdef __GNU_LIBRARY__
+ #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
+  Lucky user
+ #endif
+#endif
+#ifdef __CYGWIN__
+ #include <cygwin/version.h>
+ #if CYGWIN_VERSION_DLL_MAJOR >= 1007
+  Lucky user
+ #endif
+#endif
+	 ],
+	 [gl_cv_func_strstr_linear=yes],
+	 [gl_cv_func_strstr_linear="guessing no"])
+      ])
+    ])
+  if test "$gl_cv_func_strstr_linear" != yes; then
+    REPLACE_STRSTR=1
+    AC_LIBOBJ([strstr])
   fi
-])
-
-# Prerequisites of lib/strstr.c.
-AC_DEFUN([gl_PREREQ_STRSTR], [:])
+]) # gl_FUNC_STRSTR