X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fstrtod.m4;h=5d526177b435946e23634f2d4530ebc662ffe38f;hb=d8235a667024b123ff7e89be518a7049f658e9bd;hp=80a1d7dff5a1a2b6409acd25b82fe72577deb02e;hpb=4fde4952d5a3db51a122f96a31bfcd6879399fea;p=gnulib.git

diff --git a/m4/strtod.m4 b/m4/strtod.m4
index 80a1d7dff..5d526177b 100644
--- a/m4/strtod.m4
+++ b/m4/strtod.m4
@@ -1,16 +1,76 @@
-# strtod.m4 serial 5
-dnl Copyright (C) 2002, 2003, 2006 Free Software Foundation, Inc.
+# strtod.m4 serial 9
+dnl Copyright (C) 2002, 2003, 2006, 2007, 2008 Free Software
+dnl Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_STRTOD],
 [
-  AC_REQUIRE([AC_FUNC_STRTOD])
+  AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
+  AC_FUNC_STRTOD
+  dnl Note: AC_FUNC_STRTOD does AC_LIBOBJ(strtod).
   if test $ac_cv_func_strtod = no; then
-    AC_DEFINE(strtod, rpl_strtod,
-      [Define to rpl_strtod if the replacement function should be used.])
+    HAVE_STRTOD=0
+    REPLACE_STRTOD=1
     gl_PREREQ_STRTOD
+  else
+    AC_CACHE_CHECK([whether strtod obeys C99], [gl_cv_func_strtod_works],
+      [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
+#include <stdlib.h>
+#include <math.h>
+/* Compare two numbers with ==.
+   This is a separate function because IRIX 6.5 "cc -O" miscompiles an
+   'x == x' test.  */
+static int
+numeric_equal (double x, double y)
+{
+  return x == y;
+}
+]], [[
+  {
+    /* Older glibc and Cygwin mis-parse "-0x".  */
+    const char *string = "-0x";
+    char *term;
+    double value = strtod (string, &term);
+    double zero = 0.0;
+    if (1.0 / value != -1.0 / zero || term != (string + 2))
+      return 1;
+  }
+  {
+    /* Many platforms do not parse hex floats.  */
+    const char *string = "0XaP+1";
+    char *term;
+    double value = strtod (string, &term);
+    if (value != 20.0 || term != (string + 6))
+      return 1;
+  }
+  {
+    /* Many platforms do not parse infinities.  */
+    const char *string = "inf";
+    char *term;
+    double value = strtod (string, &term);
+    if (value != HUGE_VAL || term != (string + 3))
+      return 1;
+  }
+  {
+    /* glibc 2.7 and cygwin 1.5.24 misparse "nan()".  */
+    const char *string = "nan()";
+    char *term;
+    double value = strtod (string, &term);
+    if (numeric_equal (value, value) || term != (string + 5))
+      return 1;
+  }
+]])],
+	[gl_cv_func_strtod_works=yes],
+	[gl_cv_func_strtod_works=no],
+	[gl_cv_func_strtod_works="guessing no"])])
+    if test "$gl_cv_func_strtod_works" != yes; then
+      REPLACE_STRTOD=1
+      gl_PREREQ_STRTOD
+      dnl Use undocumented macro to set POW_LIB correctly.
+      _AC_LIBOBJ_STRTOD
+    fi
   fi
 ])