X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Futimbuf.m4;h=3c9df414a3c95880c79bf2bab63b2049f346cb3c;hb=23eecb48e39afd0d267d64d40ba6bf97aa865e13;hp=1e36f39e42eae9a80b6d26135a6b08e646e8c277;hpb=af932c117a55509466bde2ba79f2d9c4e6b74ae2;p=gnulib.git

diff --git a/m4/utimbuf.m4 b/m4/utimbuf.m4
index 1e36f39e4..3c9df414a 100644
--- a/m4/utimbuf.m4
+++ b/m4/utimbuf.m4
@@ -1,40 +1,39 @@
-#serial 3
+# serial 9
+
+# Copyright (C) 1998-2001, 2003-2004, 2007, 2009-2013 Free Software Foundation,
+# Inc.
+#
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
 
 dnl From Jim Meyering
 
-dnl Define HAVE_STRUCT_UTIMBUF if `struct utimbuf' is declared --
+dnl Define HAVE_STRUCT_UTIMBUF if 'struct utimbuf' is declared --
 dnl usually in <utime.h>.
 dnl Some systems have utime.h but don't declare the struct anywhere.
 
-AC_DEFUN(jm_CHECK_TYPE_STRUCT_UTIMBUF,
+AC_DEFUN([gl_CHECK_TYPE_STRUCT_UTIMBUF],
 [
-  AC_CHECK_HEADERS(utime.h)
-  AC_REQUIRE([AC_HEADER_TIME])
-  AC_CACHE_CHECK([for struct utimbuf], fu_cv_sys_struct_utimbuf,
-    [AC_TRY_COMPILE(
-      [
-#ifdef TIME_WITH_SYS_TIME
-# include <sys/time.h>
-# include <time.h>
-#else
-# ifdef HAVE_SYS_TIME_H
-#  include <sys/time.h>
-# else
-#  include <time.h>
-# endif
-#endif
-#ifdef HAVE_UTIME_H
-# include <utime.h>
-#endif
-      ],
-      [static struct utimbuf x; x.actime = x.modtime;],
-      fu_cv_sys_struct_utimbuf=yes,
-      fu_cv_sys_struct_utimbuf=no)
-    ])
+  AC_CHECK_HEADERS_ONCE([sys/time.h utime.h])
+  AC_CACHE_CHECK([for struct utimbuf], [gl_cv_sys_struct_utimbuf],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM(
+          [[#if HAVE_SYS_TIME_H
+             #include <sys/time.h>
+            #endif
+            #include <time.h>
+            #ifdef HAVE_UTIME_H
+             #include <utime.h>
+            #endif
+          ]],
+          [[static struct utimbuf x; x.actime = x.modtime;]])],
+       [gl_cv_sys_struct_utimbuf=yes],
+       [gl_cv_sys_struct_utimbuf=no])])
 
-  if test $fu_cv_sys_struct_utimbuf = yes; then
-    AC_DEFINE_UNQUOTED(HAVE_STRUCT_UTIMBUF, 1,
-[Define if struct utimbuf is declared -- usually in <utime.h>.
-   Some systems have utime.h but don't declare the struct anywhere. ])
+  if test $gl_cv_sys_struct_utimbuf = yes; then
+    AC_DEFINE([HAVE_STRUCT_UTIMBUF], [1],
+      [Define if struct utimbuf is declared -- usually in <utime.h>.
+       Some systems have utime.h but don't declare the struct anywhere. ])
   fi
 ])