X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Futimes.m4;h=e6d6f776499329fe76839f655ad97b1378320406;hb=22f68bbd9f0cb9b39eddb5228e14fe2367b8c811;hp=ddb3aeaee47e98f33c6f38e3d18fdd556d8c89cf;hpb=c3bf1cd31fba6b06427f4fb2b339afa17077e5e9;p=gnulib.git

diff --git a/m4/utimes.m4 b/m4/utimes.m4
index ddb3aeaee..e6d6f7764 100644
--- a/m4/utimes.m4
+++ b/m4/utimes.m4
@@ -1,34 +1,84 @@
-#serial 1
+# Detect some bugs in glibc's implementation of utimes.
+# serial 2
 
-dnl Shamelessly cloned from acspecific.m4's AC_FUNC_UTIME_NULL.
+dnl Copyright (C) 2003-2005, 2009-2010 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
 
-AC_DEFUN(jm_FUNC_UTIMES_NULL,
-[AC_CACHE_CHECK(whether utimes accepts a null argument, ac_cv_func_utimes_null,
-[rm -f conftestdata; > conftestdata
-AC_TRY_RUN([#include <sys/types.h>
+# See if we need to work around bugs in glibc's implementation of
+# utimes from 2003-07-12 to 2003-09-17.
+# First, there was a bug that would make utimes set mtime
+# and atime to zero (1970-01-01) unconditionally.
+# Then, there was code to round rather than truncate.
+# Then, there was an implementation (sparc64, Linux-2.4.28, glibc-2.3.3)
+# that didn't honor the NULL-means-set-to-current-time semantics.
+# Finally, there was also a version of utimes that failed on read-only
+# files, while utime worked fine (linux-2.2.20, glibc-2.2.5).
+#
+# From Jim Meyering, with suggestions from Paul Eggert.
+
+AC_DEFUN([gl_FUNC_UTIMES],
+[
+  AC_CACHE_CHECK([whether the utimes function works],
+                 [gl_cv_func_working_utimes],
+  [
+  AC_RUN_IFELSE([AC_LANG_SOURCE([[
+#include <sys/types.h>
 #include <sys/stat.h>
-main() {
-struct stat s, t;
-exit(!(stat ("conftestdata", &s) == 0 && utimes("conftestdata", (long *)0) == 0
-&& stat("conftestdata", &t) == 0 && t.st_mtime >= s.st_mtime
-&& t.st_mtime - s.st_mtime < 120));
-}], ac_cv_func_utimes_null=yes, ac_cv_func_utimes_null=no,
-  ac_cv_func_utimes_null=no)
-rm -f core core.* *.core])
-
-    if test $ac_cv_func_utimes_null = yes; then
-      if test x = y; then
-	# This code is deliberately never run via ./configure.
-	# FIXME: this is a hack to make autoheader put the corresponding
-	# HAVE_* undef for this symbol in config.h.in.  This saves me the
-	# trouble of having to maintain the #undef in acconfig.h manually.
-	AC_CHECK_FUNCS(UTIMES_NULL)
-      fi
-      # Defining it this way (rather than via AC_DEFINE) short-circuits the
-      # autoheader check -- autoheader doesn't know it's already been taken
-      # care of by the hack above.
-      ac_kludge=HAVE_UTIMES_NULL
-      AC_DEFINE_UNQUOTED($ac_kludge)
-    fi
-  ]
-)
+#include <fcntl.h>
+#include <sys/time.h>
+#include <time.h>
+#include <unistd.h>
+#include <stdlib.h>
+#include <stdio.h>
+#include <utime.h>
+
+int
+main ()
+{
+  static struct timeval timeval[2] = {{9, 10}, {999999, 999999}};
+  struct stat sbuf;
+  char const *file = "conftest.utimes";
+  FILE *f;
+  time_t now;
+  int fd;
+
+  int ok = ((f = fopen (file, "w"))
+            && fclose (f) == 0
+            && utimes (file, timeval) == 0
+            && lstat (file, &sbuf) == 0
+            && sbuf.st_atime == timeval[0].tv_sec
+            && sbuf.st_mtime == timeval[1].tv_sec);
+  unlink (file);
+  if (!ok)
+    exit (1);
+
+  ok =
+    ((f = fopen (file, "w"))
+     && fclose (f) == 0
+     && time (&now) != (time_t)-1
+     && utimes (file, NULL) == 0
+     && lstat (file, &sbuf) == 0
+     && now - sbuf.st_atime <= 2
+     && now - sbuf.st_mtime <= 2);
+  unlink (file);
+  if (!ok)
+    exit (1);
+
+  ok = (0 <= (fd = open (file, O_WRONLY|O_CREAT, 0444))
+              && close (fd) == 0
+              && utimes (file, NULL) == 0);
+  unlink (file);
+
+  exit (!ok);
+}
+  ]])],
+       [gl_cv_func_working_utimes=yes],
+       [gl_cv_func_working_utimes=no],
+       [gl_cv_func_working_utimes=no])])
+
+  if test $gl_cv_func_working_utimes = yes; then
+    AC_DEFINE([HAVE_WORKING_UTIMES], [1], [Define if utimes works properly. ])
+  fi
+])