From 18cae339ab6a07dd1a259839418fa51d804c26c6 Mon Sep 17 00:00:00 2001
From: Bruno Haible <bruno@clisp.org>
Date: Fri, 15 Jul 2005 10:34:31 +0000
Subject: [PATCH] Don't use poll() on MacOS X 10.4.

---
 m4/ChangeLog |  5 +++++
 m4/poll.m4   | 52 ++++++++++++++++++++++++++++++++++++++++++++++++----
 2 files changed, 53 insertions(+), 4 deletions(-)

diff --git a/m4/ChangeLog b/m4/ChangeLog
index 56ab1ccd8..11756981b 100644
--- a/m4/ChangeLog
+++ b/m4/ChangeLog
@@ -1,3 +1,8 @@
+2005-06-01  Bruno Haible  <bruno@clisp.org>
+
+	* poll.m4 (gl_FUNC_POLL): Check against MacOS X 10.4 poll() bug.
+	When using lib/poll.c, define poll as rpl_poll.
+
 2005-07-14  Bruno Haible  <bruno@clisp.org>
 
 	* argp.m4 (gl_ARGP): Remove invocation of gl_FUNC_GLIBC_UNLOCKED_IO.
diff --git a/m4/poll.m4 b/m4/poll.m4
index d56c9ffcb..aed57a050 100644
--- a/m4/poll.m4
+++ b/m4/poll.m4
@@ -1,5 +1,5 @@
-# poll.m4 serial 3
-dnl Copyright (c) 2003 Free Software Foundation, Inc.
+# poll.m4 serial 4
+dnl Copyright (c) 2003, 2005 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
@@ -14,8 +14,52 @@ AC_DEFUN([gl_FUNC_POLL],
   fi
   AC_SUBST([POLL_H])
 
-  AC_REPLACE_FUNCS(poll)
-  if test $ac_cv_func_poll = no; then
+  AC_CHECK_FUNC(poll,
+    [# Check whether poll() works on special files (like /dev/null) and
+     # and ttys (like /dev/tty). On MacOS X 10.4.0, it doesn't.
+     AC_TRY_RUN([
+#include <fcntl.h>
+#include <poll.h>
+       int main()
+       {
+         struct pollfd ufd;
+         /* Try /dev/null for reading.  */
+         ufd.fd = open ("/dev/null", O_RDONLY);
+         if (ufd.fd < 0) /* If /dev/null does not exist, it's not MacOS X. */
+           return 0;
+         ufd.events = POLLIN;
+         ufd.revents = 0;
+         if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLIN))
+           return 1;
+         /* Try /dev/null for writing.  */
+         ufd.fd = open ("/dev/null", O_WRONLY);
+         if (ufd.fd < 0) /* If /dev/null does not exist, it's not MacOS X. */
+           return 0;
+         ufd.events = POLLOUT;
+         ufd.revents = 0;
+         if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLOUT))
+           return 1;
+         /* Trying /dev/tty may be too environment dependent.  */
+         return 0;
+       }],
+       [gl_cv_func_poll=yes],
+       [gl_cv_func_poll=no],
+       [# When cross-compiling, assume that poll() works everywhere except on
+        # MacOS X, regardless of its version.
+        AC_EGREP_CPP([MacOSX], [
+#if defined(__APPLE__) && defined(__MACH__)
+This is MacOSX
+#endif
+], [gl_cv_func_poll=no], [gl_cv_func_poll=yes])])])
+  if test $gl_cv_func_poll = yes; then
+    AC_DEFINE([HAVE_POLL], 1,
+      [Define to 1 if you have the 'poll' function and it works.])
+  fi
+
+  if test $gl_cv_func_poll = no; then
+    AC_LIBOBJ(poll)
+    AC_DEFINE(poll, rpl_poll,
+      [Define to poll if the replacement function should be used.])
     gl_PREREQ_POLL
   fi
 ])
-- 
2.11.0