lib/ID3FS/DB.pm

   1 # id3fs - a FUSE-based filesystem for browsing audio metadata
   2 # Copyright (C) 2010  Ian Beckwith <ianb@erislabs.net>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package ID3FS::DB;
  18
  19 use strict;
  20 use warnings;
  21 use DBI;
  22 use ID3FS::AudioFile;
  23 use Cwd;
  24
  25 our $SCHEMA_VERSION=1;
  26 my $dbfile=".id3fs"; # default
  27
  28 sub new
  29 {
  30     my $proto=shift;
  31     my $class=ref($proto) || $proto;
  32     my $self={};
  33     bless($self,$class);
  34
  35     $self->{me}=shift;
  36     $self->{verbose}=shift;
  37     my $init=shift;
  38     $self->{base}=shift;
  39     $self->{dbpath}=shift || ($self->{base} . "/" . $dbfile);
  40     $self->{dbpath}=Cwd::abs_path($self->{dbpath});
  41     $self->{absbase}=Cwd::abs_path($self->{base});
  42
  43     my $connectstr="dbi:SQLite:dbname=$self->{dbpath}";
  44     my $exists=-f $self->{dbpath};
  45     $self->{dbh}=DBI->connect($connectstr, undef, undef,
  46                               { AutoCommit=>1 } );
  47     unless(defined($self->{dbh}))
  48     {
  49         die("$self->{me}: DB Error: " . $DBI::errstr . "\n");
  50     }
  51
  52     if($exists)
  53     {
  54         $self->checkschema();
  55     }
  56     else
  57     {
  58         $self->create();
  59     }
  60     $self->enable_foreign_keys();
  61     return $self;
  62 }
  63
  64 # search parent directories for db
  65 sub find_db
  66 {
  67     # class method
  68     shift if(ref($_[0]) eq "ID3FS::DB");
  69
  70     my($me, $init, @dirs)=@_;
  71     my $base=undef;
  72     for my $dir (@dirs)
  73     {
  74         my $path=Cwd::abs_path($dir);
  75         do
  76         {
  77             $base=$path;
  78             $path=~s/(.*)\/.*/$1/;
  79         }
  80         while(! -f "$base/$dbfile" && length($path) && -d $path);
  81         if(-f "$base/$dbfile")
  82         {
  83             return $base;
  84         }
  85     }
  86     if(!-f "$base/$dbfile")
  87     {
  88         unless($init)
  89         {
  90             print "$me: db not found at $base/$dbfile\n";
  91             return undef;
  92         }
  93         $base=$dirs[0];
  94
  95     }
  96     return $base;
  97 }
  98
  99 sub base_dir { return shift->{base}; }
 100
 101 sub create
 102 {
 103     my($self,$name)=@_;
 104     my @schema=split(/\n\n/,join("", <DATA>));
 105     close(DATA);
 106     for my $cmd (@schema)
 107     {
 108         $self->{dbh}->do($cmd);
 109     }
 110     $self->cmd("INSERT INTO id3fs (schema_version, last_update) VALUES (?, ?)",
 111                $SCHEMA_VERSION, time());
 112 }
 113
 114 sub checkschema
 115 {
 116     my $self=shift;
 117     my ($version)=$self->cmd_onerow("SELECT schema_version from id3fs");
 118     if(!defined($version) || $version != $SCHEMA_VERSION)
 119     {
 120         die("$self->{me}: id3fs database version " .
 121             defined($version) ? $version : '""' .
 122             "not known, current version is $SCHEMA_VERSION.\n");
 123     }
 124 }
 125
 126 sub analyze
 127 {
 128     my $self=shift;
 129     $self->cmd("ANALYZE");
 130 }
 131
 132 sub enable_foreign_keys
 133 {
 134     my $self=shift;
 135     $self->cmd("PRAGMA foreign_keys = ON");
 136 }
 137
 138 sub last_update
 139 {
 140     my($self, $newval)=@_;
 141     if(defined($newval))
 142     {
 143         $self->cmd("UPDATE id3fs SET last_update=?", $newval);
 144     }
 145     else
 146     {
 147         ($newval)=$self->cmd_onerow("SELECT last_update from id3fs");
 148     }
 149     return $newval;
 150 }
 151
 152 sub bare_tags
 153 {
 154     my($self)=@_;
 155     my $sql=("SELECT tags.name FROM tags\n" .
 156              "WHERE tags.parents_id=''\n" .
 157              "GROUP BY tags.name\n");
 158     my @names=$self->cmd_firstcol($sql);
 159     return (@names);
 160 }
 161
 162 sub tags_with_values
 163 {
 164     my($self)=@_;
 165     my $sql=("SELECT p.name, t.name  FROM tags t\n" .
 166              "INNER JOIN tags p ON t.parents_id=p.id\n" .
 167              "GROUP BY p.name, t.name\n");
 168     my $result=$self->cmd_rows($sql);
 169     my $tags={};
 170     for my $pair (@$result)
 171     {
 172         push(@{$tags->{$pair->[0]}}, $pair->[1]);
 173     }
 174     return $tags;
 175 }
 176
 177 sub tag_has_values
 178 {
 179     my($self, $id)=@_;
 180     my $sql=("SELECT COUNT(*) FROM tags\n\t" .
 181              "WHERE tags.parents_id=?\n");
 182     my ($rows)=$self->cmd_onerow($sql, $id);
 183     return $rows;
 184 }
 185
 186 sub relativise
 187 {
 188     my($self, $path, $name, $mountpoint, $querypath)=@_;
 189     my $rpath="$self->{absbase}/$path";
 190     my $vpath=$mountpoint . $querypath;
 191     my @path=split(/\//,$rpath);
 192     my @rel=split(/\//,$vpath);
 193     # drop filename from rel
 194     pop @rel;
 195     # absolute paths have empty first element due to leading /
 196     shift(@path) if($path[0] eq "");
 197     shift(@rel)  if($rel[0]  eq "");
 198     # f: /home/foo/bar/baz.mp3
 199     # r: /home/ianb/music/albums
 200     while(@path && @rel && ($path[0] eq $rel[0]))
 201     {
 202         shift(@path);
 203         shift(@rel);
 204     }
 205     my $upcount=scalar(@rel);
 206     my $result="../" x $upcount;
 207     $result .= join("/",@path);
 208     $result .= "/$name";
 209     return $result;
 210 }
 211
 212 sub add
 213 {
 214     my($self,$path)=@_;
 215     my $relpath=Cwd::abs_path($path);
 216     $relpath =~ s/^\Q$self->{absbase}\E\/?//;
 217     my($filepart,$pathpart);
 218     if($relpath !~ /\//)
 219     {
 220         $pathpart='';
 221         $filepart=$relpath;
 222     }
 223     else
 224     {
 225         ($pathpart, $filepart) = ($relpath =~ /(.*)\/(.*)/);
 226     }
 227     my $file=ID3FS::AudioFile->new($path, $self->{me});
 228     return unless(defined($file));
 229     my $artist=$file->artist();
 230     my $album=$file->album();
 231     my $v1genre=$file->v1genre();
 232     my $year=$file->year();
 233     my $audiotype=$file->audiotype();
 234     my @tags=$file->tags();
 235     my $haspic=$file->haspic();
 236     my $channels=$file->channels();
 237     my $bitrate=$file->bitrate();
 238     my $samplerate=$file->samplerate();
 239
 240     $artist=undef unless($self->ok($artist));
 241     print "$self->{me}: $path: no artist tag defined\n" unless(defined($artist));
 242     my $artist_id=$self->add_to_table("artists",  $artist);
 243     my $path_id=$self->add_to_table("paths", $pathpart);
 244     $album=undef unless($self->ok($album));
 245 #    if($self->{verbose} && !defined($album)) FIXME
 246     if(!defined($album))
 247     {
 248         print "$self->{me}: $path: no album tag defined\n";
 249     }
 250
 251     my $albums_id=$self->add_to_table("albums", $album);
 252     my $file_id=$self->add_to_table("files", $filepart,
 253                                     { "artists_id" => $artist_id,
 254                                       "albums_id"  => $albums_id,
 255                                       "paths_id"   => $path_id });
 256     if(@tags)
 257     {
 258         for my $tag (@tags)
 259         {
 260             $self->add_tag($file_id, @$tag);
 261         }
 262     }
 263     else
 264     {
 265         $self->add_tag($file_id, "UNTAGGED");
 266     }
 267
 268     $year="UNKNOWN" if(!$self->ok($year) || $year =~ /^0+$/);
 269     $self->add_tag($file_id, "year", $year);
 270     if($year=~/^(\d\d\d)\d$/)
 271     {
 272         $self->add_tag($file_id, "decade", "${1}0s");
 273     }
 274     else
 275     {
 276         $self->add_tag($file_id, "decade", "UNKNOWN");
 277     }
 278
 279     if($self->ok($v1genre))
 280     {
 281         $self->add_tag($file_id, "v1genre", $v1genre);
 282     }
 283
 284     if($haspic)
 285     {
 286         $self->add_tag($file_id, "haspic", undef);
 287     }
 288
 289     if($self->ok($audiotype))
 290     {
 291         $self->add_tag($file_id, "audiotype", $audiotype);
 292     }
 293     else
 294     {
 295         # should never happen
 296         $self->add_tag($file_id, "audiotype", "UNKNOWN");
 297     }
 298
 299     if($self->ok($channels))
 300     {
 301         if    ($channels eq "2") { $channels="stereo";  }
 302         elsif ($channels eq "1") { $channels="mono";    }
 303         elsif ($channels eq "0") { $channels="UNKNOWN"; }
 304         $self->add_tag($file_id, "channels", $channels);
 305     }
 306
 307     if($self->ok($bitrate))
 308     {
 309         $bitrate="UNKNOWN" if($bitrate=~/^0+$/);
 310         $self->add_tag($file_id, "bitrate", $bitrate);
 311     }
 312
 313     if($self->ok($samplerate))
 314     {
 315         $samplerate="UNKNOWN" if($samplerate=~/^0+$/);
 316         $self->add_tag($file_id, "samplerate", $samplerate);
 317     }
 318
 319 }
 320
 321 sub add_tag
 322 {
 323     my($self, $file_id, $tag, $value)=@_;
 324     my $tag_id=$self->add_to_table("tags",  $tag,
 325                                    { "parents_id" => undef });
 326     $self->add_relation("files_x_tags",
 327                         { "files_id" => $file_id,
 328                           "tags_id"  => $tag_id });
 329     if(defined($value) && length($value))
 330     {
 331         my $val_id=$self->add_to_table("tags",  $value,
 332                                        { "parents_id" => $tag_id });
 333         $self->add_relation("files_x_tags",
 334                             { "files_id" => $file_id,
 335                               "tags_id"  => $val_id });
 336     }
 337 }
 338
 339 sub add_to_table
 340 {
 341     my($self, $table, $name, $extradata)=@_;
 342     my $parent=undef;
 343     if($extradata && $extradata->{parents_id})
 344     {
 345         $parent=$extradata->{parents_id};
 346     }
 347     my $id=$self->lookup_id($table, $name, $parent);
 348     unless(defined($id))
 349     {
 350         my $sql="INSERT INTO $table (";
 351         my @fields=qw(name);
 352         if(defined($extradata))
 353         {
 354             push(@fields, sort keys(%$extradata));
 355         }
 356         $sql .= join(", ", @fields);
 357         $sql .=") VALUES (";
 358         $sql .= join(", ", map { "?"; } @fields);
 359         $sql .= ");";
 360         $id=$self->cmd_id($sql, $name, map { $extradata->{$_} || ""; } sort keys %$extradata);
 361     }
 362     return $id;
 363 }
 364
 365 sub add_relation
 366 {
 367     my ($self, $relname, $fields)=@_;
 368     return if($self->relation_exists($relname, $fields));
 369     my $sql="INSERT INTO $relname (";
 370     $sql .= join(", ", sort keys(%$fields));
 371     $sql .= ") VALUES (";
 372     $sql .= join(", ", map { "?"; } sort keys(%$fields));
 373     $sql .= ");";
 374     $self->cmd($sql, map { $fields->{$_}; } sort keys(%$fields));
 375 }
 376
 377 sub files_in
 378 {
 379     my ($self, $dir)=@_;
 380     my $sql=("SELECT files.name FROM files\n" .
 381              "INNER JOIN paths ON files.paths_id=paths.id\n" .
 382              "WHERE paths.name=?\n");
 383     return($self->cmd_firstcol($sql, $dir));
 384 }
 385
 386 sub unindex
 387 {
 388     my($self, $path, $file)=@_;
 389     my $sql=("DELETE FROM files WHERE id IN (" .
 390              "\tSELECT files.id FROM files\n" .
 391              "\tINNER JOIN paths ON paths.id=files.paths_id\n" .
 392              "\tWHERE paths.name=? and files.name=? )\n");
 393     $self->cmd_rows($sql, $path, $file);
 394 }
 395
 396
 397 sub prune_directories
 398 {
 399     my($self)=@_;
 400     my $sql=("SELECT name, id FROM paths\n");
 401     my $pathsref=$self->cmd_rows($sql);
 402     my @ids=();
 403     for my $pathpair (@$pathsref)
 404     {
 405         my($path, $id)=@$pathpair;
 406         my $fullpath="$self->{absbase}/$path";
 407         unless(-d $fullpath)
 408         {
 409             push(@ids, $id)
 410         }
 411     }
 412     $self->prune_paths(@ids);
 413     return scalar(@ids);
 414 }
 415
 416 sub prune_paths
 417 {
 418     my($self, @ids)=@_;
 419     return unless(@ids);
 420     my $sql=("DELETE FROM files WHERE paths_id IN (\n\t" .
 421              join(', ', map { "\"$_\""; } @ids). "\n\t)");
 422     $self->cmd($sql);
 423 }
 424
 425 sub remove_unused
 426 {
 427     my($self)=@_;
 428     my $sql=<<'EOT';
 429    DELETE FROM artists WHERE id IN (
 430        SELECT artists.id FROM artists
 431        LEFT JOIN files ON files.artists_id=artists.id
 432        WHERE files.id IS NULL);
 433
 434    DELETE FROM albums WHERE id IN (
 435        SELECT albums.id FROM albums
 436        LEFT JOIN files ON files.albums_id=albums.id
 437        WHERE files.id IS NULL);
 438
 439    DELETE FROM paths WHERE id IN (
 440        SELECT paths.id FROM paths
 441        LEFT JOIN files ON files.paths_id=paths.id
 442        WHERE files.id IS NULL);
 443
 444    DELETE FROM files_x_tags WHERE files_id IN (
 445        SELECT files_x_tags.files_id FROM files_x_tags
 446        LEFT JOIN files ON files.id=files_x_tags.files_id
 447        WHERE files.id IS NULL);
 448
 449    DELETE FROM tags WHERE id IN (
 450        SELECT tags.id FROM tags
 451        LEFT JOIN files_x_tags ON files_x_tags.tags_id=tags.id
 452        WHERE files_x_tags.files_id IS NULL);
 453
 454     VACUUM
 455 EOT
 456 #    print "SQL: $sql\n";
 457     my @sql=split(/\n\n/, $sql);
 458     $self->cmd($_) for (@sql);
 459 }
 460
 461 sub relation_exists
 462 {
 463     my ($self, $relname, $fields)=@_;
 464     my $sql="SELECT count(1) FROM $relname WHERE ";
 465     my @exprs=();
 466     my @vals=();
 467     for my $field (keys %$fields)
 468     {
 469         push(@exprs,$field);
 470         push(@vals,$fields->{$field});
 471     }
 472     $sql .= join(' AND ', map { "$_=?"; } @exprs);
 473     my ($ret)=$self->cmd_onerow($sql, @vals);
 474     return $ret;
 475 }
 476
 477 sub ok
 478 {
 479     my($self, $thing)=@_;
 480     return(defined($thing) && length($thing) && $thing =~ /\S+/);
 481 }
 482
 483 # actually call the database
 484 sub cmd_sth
 485 {
 486     my($self, $sql, @params)=@_;
 487     my $sth=$self->{dbh}->prepare($sql);
 488     my $idx=1;
 489     for my $param (@params)
 490     {
 491         $param="" unless(defined($param));
 492         $sth->bind_param($idx++, $param);
 493     }
 494     $sth->execute();
 495     return $sth;
 496 }
 497
 498 # pass cmd to db, ignore response
 499 sub cmd
 500 {
 501     my ($self, @args)=@_;
 502     # don't care about retcode
 503     $self->cmd_sth(@args);
 504 }
 505
 506 # return one row
 507 sub cmd_onerow
 508 {
 509     my ($self, @args)=@_;
 510     my $sth=$self->cmd_sth(@args);
 511     return($sth->fetchrow_array());
 512 }
 513
 514 # returns all rows
 515 sub cmd_rows
 516 {
 517     my ($self, @args)=@_;
 518     my $sth=$self->cmd_sth(@args);
 519     return $sth->fetchall_arrayref();
 520 }
 521
 522 # returns just the first column
 523 sub cmd_firstcol
 524 {
 525     my ($self, @args)=@_;
 526     return(map { $_->[0] } @{$self->cmd_rows(@args)});
 527 }
 528
 529 # runs cmd, returns id of last insert
 530 sub cmd_id
 531 {
 532     my ($self, @args)=@_;
 533     $self->cmd_sth(@args);
 534     return($self->last_insert_id());
 535 }
 536
 537 sub last_insert_id
 538 {
 539     my $self=shift;
 540     return $self->{dbh}->last_insert_id("","","","");
 541 }
 542
 543 # lookup id of $name in $table, also matching on $parent if needed
 544 sub lookup_id
 545 {
 546     my($self, $table, $name, $parent)=@_;
 547     my $sql="SELECT id FROM $table where name=?";
 548     my @args=($name);
 549     if($parent)
 550     {
 551         $sql .= " AND parents_id=?";
 552         push(@args, $parent);
 553     }
 554     my($id)=$self->cmd_onerow($sql, @args);
 555     return $id;
 556 }
 557
 558 __DATA__
 559
 560 CREATE TABLE id3fs (
 561     schema_version INTEGER,
 562     last_update
 563 );
 564
 565 CREATE TABLE paths (
 566     id INTEGER,
 567     name text,
 568     PRIMARY KEY(id ASC)
 569 );
 570
 571 CREATE TABLE artists (
 572     id INTEGER,
 573     name text,
 574     PRIMARY KEY(id ASC)
 575 );
 576
 577 CREATE TABLE albums (
 578     id INTEGER,
 579     name text,
 580     PRIMARY KEY(id ASC)
 581 );
 582
 583 CREATE TABLE files (
 584     id INTEGER,
 585     name text,
 586     artists_id,
 587     albums_id,
 588     paths_id,
 589     PRIMARY KEY(id ASC),
 590     FOREIGN KEY(artists_id) REFERENCES artists(id) ON DELETE CASCADE ON UPDATE CASCADE,
 591     FOREIGN KEY(albums_id)  REFERENCES albums(id)  ON DELETE CASCADE ON UPDATE CASCADE,
 592     FOREIGN KEY(paths_id)   REFERENCES paths(id)   ON DELETE CASCADE ON UPDATE CASCADE
 593 );
 594
 595 CREATE TABLE tags (
 596     id INTEGER,
 597     parents_id INTEGER,
 598     name text,
 599     PRIMARY KEY(id ASC)
 600 );
 601
 602 CREATE TABLE files_x_tags (
 603     files_id INTEGER,
 604     tags_id INTEGER,
 605     FOREIGN KEY(files_id) REFERENCES files(id) ON DELETE CASCADE ON UPDATE CASCADE,
 606     FOREIGN KEY(tags_id)  REFERENCES tags(id)  ON DELETE CASCADE ON UPDATE CASCADE
 607 );
 608
 609 CREATE INDEX idx_fxt_both ON files_x_tags (files_id, tags_id)
 610
 611 CREATE INDEX idx_fxt_tags ON files_x_tags (tags_id)
 612
 613 CREATE INDEX idx_files_id_name ON files (id, name)
 614
 615 CREATE INDEX idx_files_name_id ON files (name, id)
 616
 617 CREATE INDEX idx_tags_id_parent_name ON tags (id, parents_id, name)
 618
 619 CREATE INDEX idx_tags_parent_id_name ON tags (parents_id, id, name)
 620
 621 CREATE INDEX idx_tags_name ON tags (name)