build-aux/update-copyright

   1 #!/usr/bin/perl -0777 -pi
   2 # Update an FSF copyright year list to include the current year.
   3
   4 my $VERSION = '2009-08-05.20:47'; # UTC
   5
   6 # Copyright (C) 2009 Free Software Foundation, Inc.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3, or (at your option)
  11 # any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # Written by Jim Meyering and Joel E. Denny
  22
  23 # The arguments to this script should be names of files that contain FSF
  24 # copyright statements to be updated.  For example, you may wish to
  25 # place a target like the following in the top-level makefile in your
  26 # project:
  27 #
  28 #   .PHONY: update-copyright
  29 #   update-copyright:
  30 #       if test -d .git; then                                   \
  31 #         git grep -l -w Copyright                              \
  32 #           | grep -v -E '(^|/)(COPYING|ChangeLog)'             \
  33 #           | xargs $(srcdir)/build-aux/$@;                     \
  34 #       fi
  35 #
  36 # In the second grep, you can build a list of files to skip within your
  37 # project.
  38 #
  39 # Iff an FSF copyright statement is discovered in a file and the final
  40 # year is not the current year, the statement is updated for the new
  41 # year and reformatted to fit within 72 columns.  A warning is printed
  42 # for every file for which no FSF copyright statement is discovered.
  43 #
  44 # Each file's FSF copyright statement must be formated correctly in
  45 # order to be recognized.  For example, each of these is fine:
  46 #
  47 #   Copyright @copyright{} 1990-2005, 2007-2009 Free Software
  48 #   Foundation, Inc.
  49 #
  50 #   # Copyright (C) 1990-2005, 2007-2009 Free Software
  51 #   # Foundation, Inc.
  52 #
  53 #   /*
  54 #    * Copyright &copy; 90,2005,2007-2009
  55 #    * Free Software Foundation, Inc.
  56 #    */
  57 #
  58 # However, the following format is not recognized because the line
  59 # prefix changes after the first line:
  60 #
  61 #   /* Copyright (C) 1990-2005, 2007-2009 Free Software
  62 #    * Foundation, Inc.  */
  63 #
  64 # The following copyright statement is not recognized because the
  65 # copyright holder is not the FSF:
  66 #
  67 #   Copyright (C) 1990-2005, 2007-2009 Acme, Inc.
  68 #
  69 # However, any correctly formatted FSF copyright statement following
  70 # either of the previous two copyright statements would be recognized.
  71 #
  72 # The exact conditions that a file's FSF copyright statement must meet
  73 # to be recognized are:
  74 #
  75 #   1. The format is "Copyright (C)" (where "(C)" can also be "(c)",
  76 #      "@copyright{}", or "&copy;"), then a list of copyright years, and
  77 #      then the name of the copyright holder, which is "Free Software
  78 #      Foundation, Inc.".
  79 #   2. The "Copyright (C)" appears at the beginning of a line except
  80 #      that it may be prefixed by any sequence (e.g., a comment) of no
  81 #      more than 5 characters.
  82 #   3. Iff such a prefix is present, the same prefix appears at the
  83 #      beginning of each remaining line within the FSF copyright
  84 #      statement.
  85 #   4. Blank lines, even if preceded by the prefix, do not appear
  86 #      within the FSF copyright statement.
  87 #   5. Each copyright year is 2 or 4 digits, and years are separated by
  88 #      commas or dashes.  Whitespace may occur after commas.
  89 #   6. It is the first FSF copyright statement that meets all of the
  90 #      above conditions.  Subsequent FSF copyright statements are
  91 #      ignored.
  92
  93 use strict;
  94 use warnings;
  95
  96 my $copyright_re = 'Copyright (?:\([cC]\)|@copyright{}|&copy;)';
  97 my $holder = 'Free Software Foundation, Inc.';
  98 my $prefix_max = 5;
  99 my $margin = 72;
 100 my $tab_width = 8;
 101
 102 my $this_year = $ENV{UPDATE_COPYRIGHT_YEAR};
 103 if (!$this_year || $this_year !~ m/^\d{4}$/)
 104   {
 105     my ($sec, $min, $hour, $mday, $month, $year) = localtime (time ());
 106     $this_year = $year + 1900;
 107   }
 108
 109 # Unless the file consistently uses "\r\n" as the EOL, use "\n" instead.
 110 my $eol = /(?:^|[^\r])\n/ ? "\n" : "\r\n";
 111
 112 my $leading;
 113 my $prefix;
 114 my $ws_re;
 115 my $stmt_re;
 116 while (/(^|\n)(.{0,$prefix_max})$copyright_re/g)
 117   {
 118     $leading = $1;
 119     $prefix = $2;
 120     $ws_re = '[ \t\r\f]'; # \s without \n
 121     $ws_re =
 122       "(?:$ws_re*(?:$ws_re|\\n" . quotemeta($prefix) . ")$ws_re*)";
 123     my $holder_re = $holder;
 124     $holder_re =~ s/\s/$ws_re/g;
 125     my $stmt_remainder_re =
 126       "$ws_re(?:(?:\\d\\d)?\\d\\d(,$ws_re?|-))*"
 127       . "((?:\\d\\d)?\\d\\d)$ws_re$holder_re";
 128     if (/\G$stmt_remainder_re/)
 129       {
 130         $stmt_re =
 131            quotemeta("$leading$prefix")
 132            . "($copyright_re$stmt_remainder_re)";
 133         last;
 134       }
 135   }
 136 if (defined $stmt_re)
 137   {
 138     /$stmt_re/ or die; # Should never die.
 139     my $stmt = $1;
 140     my $sep = $2 ? $2 : "";
 141     my $final_year_orig = $3;
 142
 143     # Handle two-digit year numbers like "98" and "99".
 144     my $final_year = $final_year_orig;
 145     $final_year <= 99
 146       and $final_year += 1900;
 147
 148     if ($final_year != $this_year)
 149       {
 150         # Update the year.
 151         if ($sep eq '-' && $final_year + 1 == $this_year)
 152           {
 153             $stmt =~ s/$final_year_orig/$this_year/;
 154           }
 155         elsif ($sep ne '-' && $final_year + 1 == $this_year)
 156           {
 157             $stmt =~ s/$final_year_orig/$final_year-$this_year/;
 158           }
 159         else
 160           {
 161             $stmt =~ s/$final_year_orig/$final_year, $this_year/;
 162           }
 163
 164         # Normalize all whitespace including newline-prefix sequences.
 165         $stmt =~ s/$ws_re/ /g;
 166
 167         # Put spaces after commas.
 168         $stmt =~ s/, ?/, /g;
 169
 170         # Format within margin.
 171         my $stmt_wrapped;
 172         my $text_margin = $margin - length($prefix);
 173         if ($prefix =~ /^(\t+)/)
 174           {
 175             $text_margin -= length($1) * ($tab_width - 1);
 176           }
 177         while (length $stmt)
 178           {
 179             if (($stmt =~ s/^(.{1,$text_margin})(?: |$)//)
 180                 || ($stmt =~ s/^([\S]+)(?: |$)//))
 181               {
 182                 my $line = $1;
 183                 $stmt_wrapped .= $stmt_wrapped ? $eol : $leading;
 184                 $stmt_wrapped .= "$prefix$line";
 185               }
 186             else
 187               {
 188                 # Should be unreachable, but we don't want an infinite
 189                 # loop if it can be reached.
 190                 die;
 191               }
 192           }
 193
 194         # Replace the old copyright statement.
 195         s/$stmt_re/$stmt_wrapped/;
 196       }
 197   }
 198 else
 199   {
 200     print STDERR "$ARGV: warning: FSF copyright statement not found\n";
 201   }
 202
 203 # Local variables:
 204 # indent-tabs-mode: nil
 205 # eval: (add-hook 'write-file-hooks 'time-stamp)
 206 # time-stamp-start: "my $VERSION = '"
 207 # time-stamp-format: "%:y-%02m-%02d.%02H:%02M"
 208 # time-stamp-time-zone: "UTC"
 209 # time-stamp-end: "'; # UTC"
 210 # End: