m4/argp.m4

   1 # argp.m4 serial 5
   2 dnl Copyright (C) 2003-2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_ARGP],
   8 [
   9   AC_REQUIRE([AC_C_INLINE])
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11   AC_REQUIRE([gl_GETOPT_SUBSTITUTE])
  12
  13   AC_CHECK_DECL([program_invocation_name],
  14                 :,
  15                 [AC_DEFINE(GNULIB_PROGRAM_INVOCATION_NAME, 1,
  16                            [Define to 1 to add extern declaration of program_invocation_name to argp-namefrob.h])],
  17                 [#include <errno.h>])
  18   AC_CHECK_DECL([program_invocation_short_name],
  19                 :,
  20                 [AC_DEFINE(GNULIB_PROGRAM_INVOCATION_SHORT_NAME, 1,
  21                            [Define to 1 to add extern declaration of program_invocation_short_name to argp-namefrob.h])],
  22                 [#include <errno.h>])
  23
  24   # Check if program_invocation_name and program_invocation_short_name
  25   # are defined elsewhere. It is improbable that only one of them will
  26   # be defined and other not, I prefer to stay on the safe side and to
  27   # test each one separately.
  28   AC_MSG_CHECKING(whether program_invocation_name is defined)
  29   AC_TRY_COMPILE([#include <argp.h>],
  30                  [ program_invocation_name = "test"; ],
  31                  [ AC_DEFINE(HAVE_PROGRAM_INVOCATION_NAME,1,
  32                    [Define if program_invocation_name is defined])
  33                    AC_MSG_RESULT(yes)],
  34                  [ AC_MSG_RESULT(no)] )
  35
  36   AC_MSG_CHECKING(whether program_invocation_short_name is defined)
  37   AC_TRY_COMPILE([#include <argp.h>],
  38                  [ program_invocation_short_name = "test"; ],
  39                  [ AC_DEFINE(HAVE_PROGRAM_INVOCATION_SHORT_NAME,1,
  40                    [Define if program_invocation_short_name is defined])
  41                    AC_MSG_RESULT(yes)],
  42                  [ AC_MSG_RESULT(no)] )
  43
  44   AC_CHECK_DECLS_ONCE(
  45      [clearerr_unlocked feof_unlocked ferror_unlocked
  46       fflush_unlocked fgets_unlocked fputc_unlocked fputs_unlocked
  47       fread_unlocked fwrite_unlocked getc_unlocked
  48       getchar_unlocked putc_unlocked putchar_unlocked])
  49   AC_CHECK_FUNCS_ONCE([flockfile funlockfile])
  50   AC_CHECK_HEADERS_ONCE([features.h linewrap.h])
  51 ])