m4/fstat.m4

   1 # fstat.m4 serial 2
   2 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSTAT],
   8 [
   9   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  10
  11   AC_REQUIRE([gl_MSVC_INVAL])
  12   if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
  13     REPLACE_FSTAT=1
  14   fi
  15
  16   AC_REQUIRE([gl_HEADER_SYS_STAT_H])
  17   if test $WINDOWS_64_BIT_ST_SIZE = 1; then
  18     REPLACE_FSTAT=1
  19   fi
  20
  21   dnl Replace fstat() for supporting the gnulib-defined open() on directories.
  22   m4_ifdef([gl_FUNC_FCHDIR], [
  23     gl_TEST_FCHDIR
  24     if test $HAVE_FCHDIR = 0 \
  25        && test "$gl_cv_func_open_directory_works" != yes; then
  26       REPLACE_FSTAT=1
  27     fi
  28   ])
  29 ])
  30
  31 # Prerequisites of lib/fstat.c.
  32 AC_DEFUN([gl_PREREQ_FSTAT],
  33 [
  34   AC_REQUIRE([AC_C_INLINE])
  35 ])