m4/memmem.m4

   1 # memmem.m4 serial 16
   2 dnl Copyright (C) 2002, 2003, 2004, 2007, 2008, 2009, 2010 Free Software
   3 dnl Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl Check that memmem is present.
   9 AC_DEFUN([gl_FUNC_MEMMEM_SIMPLE],
  10 [
  11   dnl Persuade glibc <string.h> to declare memmem().
  12   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  13
  14   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  15   AC_REPLACE_FUNCS([memmem])
  16   AC_CHECK_DECLS_ONCE([memmem])
  17   if test $ac_cv_have_decl_memmem = no; then
  18     HAVE_DECL_MEMMEM=0
  19   else
  20     dnl Detect http://sourceware.org/bugzilla/show_bug.cgi?id=12092.
  21     AC_CACHE_CHECK([whether memmem works],
  22       [gl_cv_func_memmem_works_always],
  23       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  24 #include <string.h> /* for memmem */
  25 #define P "_EF_BF_BD"
  26 #define HAYSTACK "F_BD_CE_BD" P P P P "_C3_88_20" P P P "_C3_A7_20" P
  27 #define NEEDLE P P P P P
  28 ]], [[return !!memmem (HAYSTACK, strlen (HAYSTACK), NEEDLE, strlen (NEEDLE));
  29     ]])],
  30         [gl_cv_func_memmem_works_always=yes],
  31         [gl_cv_func_memmem_works_always=no],
  32         [dnl glibc 2.12 and cygwin 1.7.7 have a known bug.  Assume that it
  33          dnl works on all other platforms, even if it is not linear.
  34          AC_EGREP_CPP([Lucky user],
  35            [
  36 #ifdef __GNU_LIBRARY__
  37  #include <features.h>
  38  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ > 12) || (__GLIBC__ > 2)
  39   Lucky user
  40  #endif
  41 #elif defined __CYGWIN__
  42  #include <cygwin/version.h>
  43  #if CYGWIN_VERSION_DLL_MAJOR >= 1007 && CYGWIN_VERSION_DLL_MINOR > 7
  44   Lucky user
  45  #endif
  46 #else
  47   Lucky user
  48 #endif
  49            ],
  50            [gl_cv_func_memmem_works_always=yes],
  51            [gl_cv_func_memmem_works_always="guessing no"])
  52         ])
  53       ])
  54     if test "$gl_cv_func_memmem_works_always" != yes; then
  55       REPLACE_MEMMEM=1
  56       AC_LIBOBJ([memmem])
  57     fi
  58   fi
  59   gl_PREREQ_MEMMEM
  60 ]) # gl_FUNC_MEMMEM_SIMPLE
  61
  62 dnl Additionally, check that memmem is efficient and handles empty needles.
  63 AC_DEFUN([gl_FUNC_MEMMEM],
  64 [
  65   AC_REQUIRE([gl_FUNC_MEMMEM_SIMPLE])
  66   if test $HAVE_MEMMEM = 1 && test $REPLACE_MEMMEM = 0; then
  67     AC_CACHE_CHECK([whether memmem works in linear time],
  68       [gl_cv_func_memmem_works_fast],
  69       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  70 #include <signal.h> /* for signal */
  71 #include <string.h> /* for memmem */
  72 #include <stdlib.h> /* for malloc */
  73 #include <unistd.h> /* for alarm */
  74 static void quit (int sig) { exit (sig + 128); }
  75 ]], [[size_t m = 1000000;
  76     char *haystack = (char *) malloc (2 * m + 1);
  77     char *needle = (char *) malloc (m + 1);
  78     void *result = 0;
  79     /* Failure to compile this test due to missing alarm is okay,
  80        since all such platforms (mingw) also lack memmem.  */
  81     signal (SIGALRM, quit);
  82     alarm (5);
  83     /* Check for quadratic performance.  */
  84     if (haystack && needle)
  85       {
  86         memset (haystack, 'A', 2 * m);
  87         haystack[2 * m] = 'B';
  88         memset (needle, 'A', m);
  89         needle[m] = 'B';
  90         result = memmem (haystack, 2 * m + 1, needle, m + 1);
  91       }
  92     /* Check for empty needle behavior.  */
  93     return !result || !memmem ("a", 1, 0, 0);]])],
  94         [gl_cv_func_memmem_works_fast=yes], [gl_cv_func_memmem_works_fast=no],
  95         [dnl Only glibc > 2.12 and cygwin > 1.7.7 are known to have a
  96          dnl bug-free memmem that works in linear time.
  97          AC_EGREP_CPP([Lucky user],
  98            [
  99 #include <features.h>
 100 #ifdef __GNU_LIBRARY__
 101  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ > 12) || (__GLIBC__ > 2)
 102   Lucky user
 103  #endif
 104 #endif
 105 #ifdef __CYGWIN__
 106  #include <cygwin/version.h>
 107  #if CYGWIN_VERSION_DLL_MAJOR >= 1007 && CYGWIN_VERSION_DLL_MINOR > 7
 108   Lucky user
 109  #endif
 110 #endif
 111            ],
 112            [gl_cv_func_memmem_works_fast=yes],
 113            [gl_cv_func_memmem_works_fast="guessing no"])
 114         ])
 115       ])
 116     if test "$gl_cv_func_memmem_works_fast" != yes; then
 117       REPLACE_MEMMEM=1
 118       AC_LIBOBJ([memmem])
 119     fi
 120   fi
 121 ]) # gl_FUNC_MEMMEM
 122
 123 # Prerequisites of lib/memmem.c.
 124 AC_DEFUN([gl_PREREQ_MEMMEM], [:])