m4/sigaction.m4

   1 # sigaction.m4 serial 2
   2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # Determine if sigaction interface is present.
   8 AC_DEFUN([gl_SIGACTION],
   9 [
  10   dnl Due to autoconf conventions, we can't tell if HAVE_SIGACTION
  11   dnl means we have the type or means we have the function.  We assume
  12   dnl that all implementations either have both or neither.
  13   AC_REPLACE_FUNCS([sigaction])
  14   if test $ac_cv_func_sigaction = no ; then
  15     HAVE_SIGACTION=0
  16     AC_SUBST([HAVE_SIGACTION])
  17     gl_PREREQ_SIGACTION
  18   fi
  19 ])
  20
  21 # Prerequisites of the part of lib/signal.in.h and of lib/sigaction.c.
  22 AC_DEFUN([gl_PREREQ_SIGACTION],
  23 [
  24   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  25   AC_REQUIRE([AC_C_RESTRICT])
  26   AC_REQUIRE([AC_TYPE_UID_T])
  27   AC_CHECK_FUNCS_ONCE([sigaltstack siginterrupt])
  28   AC_CHECK_TYPES([siginfo_t], [], [], [[
  29 #include <signal.h>
  30   ]])
  31   if test $ac_cv_type_siginfo_t = no; then
  32     HAVE_SIGINFO_T=0
  33     AC_SUBST([HAVE_SIGINFO_T])
  34   fi
  35   gl_PREREQ_SIG_HANDLER_H
  36 ])