m4/stdint.m4

   1 # stdint.m4 serial 43
   2 dnl Copyright (C) 2001-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN_ONCE([gl_STDINT_H],
  11 [
  12   AC_PREREQ([2.59])dnl
  13
  14   dnl Check for long long int and unsigned long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  23   if test $ac_cv_type_unsigned_long_long_int = yes; then
  24     HAVE_UNSIGNED_LONG_LONG_INT=1
  25   else
  26     HAVE_UNSIGNED_LONG_LONG_INT=0
  27   fi
  28   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  29
  30   dnl Check for <wchar.h>, in the same way as gl_WCHAR_H does.
  31   AC_CHECK_HEADERS_ONCE([wchar.h])
  32   if test $ac_cv_header_wchar_h = yes; then
  33     HAVE_WCHAR_H=1
  34   else
  35     HAVE_WCHAR_H=0
  36   fi
  37   AC_SUBST([HAVE_WCHAR_H])
  38
  39   dnl Check for <inttypes.h>.
  40   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  41   if test $ac_cv_header_inttypes_h = yes; then
  42     HAVE_INTTYPES_H=1
  43   else
  44     HAVE_INTTYPES_H=0
  45   fi
  46   AC_SUBST([HAVE_INTTYPES_H])
  47
  48   dnl Check for <sys/types.h>.
  49   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  50   if test $ac_cv_header_sys_types_h = yes; then
  51     HAVE_SYS_TYPES_H=1
  52   else
  53     HAVE_SYS_TYPES_H=0
  54   fi
  55   AC_SUBST([HAVE_SYS_TYPES_H])
  56
  57   gl_CHECK_NEXT_HEADERS([stdint.h])
  58   if test $ac_cv_header_stdint_h = yes; then
  59     HAVE_STDINT_H=1
  60   else
  61     HAVE_STDINT_H=0
  62   fi
  63   AC_SUBST([HAVE_STDINT_H])
  64
  65   dnl Now see whether we need a substitute <stdint.h>.
  66   if test $ac_cv_header_stdint_h = yes; then
  67     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  68       [gl_cv_header_working_stdint_h],
  69       [gl_cv_header_working_stdint_h=no
  70        AC_COMPILE_IFELSE([
  71          AC_LANG_PROGRAM([[
  72 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
  73 #include <stdint.h>
  74 /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>.  */
  75 #if !(defined WCHAR_MIN && defined WCHAR_MAX)
  76 #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>"
  77 #endif
  78 ]
  79 gl_STDINT_INCLUDES
  80 [
  81 #ifdef INT8_MAX
  82 int8_t a1 = INT8_MAX;
  83 int8_t a1min = INT8_MIN;
  84 #endif
  85 #ifdef INT16_MAX
  86 int16_t a2 = INT16_MAX;
  87 int16_t a2min = INT16_MIN;
  88 #endif
  89 #ifdef INT32_MAX
  90 int32_t a3 = INT32_MAX;
  91 int32_t a3min = INT32_MIN;
  92 #endif
  93 #ifdef INT64_MAX
  94 int64_t a4 = INT64_MAX;
  95 int64_t a4min = INT64_MIN;
  96 #endif
  97 #ifdef UINT8_MAX
  98 uint8_t b1 = UINT8_MAX;
  99 #else
 100 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
 101 #endif
 102 #ifdef UINT16_MAX
 103 uint16_t b2 = UINT16_MAX;
 104 #endif
 105 #ifdef UINT32_MAX
 106 uint32_t b3 = UINT32_MAX;
 107 #endif
 108 #ifdef UINT64_MAX
 109 uint64_t b4 = UINT64_MAX;
 110 #endif
 111 int_least8_t c1 = INT8_C (0x7f);
 112 int_least8_t c1max = INT_LEAST8_MAX;
 113 int_least8_t c1min = INT_LEAST8_MIN;
 114 int_least16_t c2 = INT16_C (0x7fff);
 115 int_least16_t c2max = INT_LEAST16_MAX;
 116 int_least16_t c2min = INT_LEAST16_MIN;
 117 int_least32_t c3 = INT32_C (0x7fffffff);
 118 int_least32_t c3max = INT_LEAST32_MAX;
 119 int_least32_t c3min = INT_LEAST32_MIN;
 120 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 121 int_least64_t c4max = INT_LEAST64_MAX;
 122 int_least64_t c4min = INT_LEAST64_MIN;
 123 uint_least8_t d1 = UINT8_C (0xff);
 124 uint_least8_t d1max = UINT_LEAST8_MAX;
 125 uint_least16_t d2 = UINT16_C (0xffff);
 126 uint_least16_t d2max = UINT_LEAST16_MAX;
 127 uint_least32_t d3 = UINT32_C (0xffffffff);
 128 uint_least32_t d3max = UINT_LEAST32_MAX;
 129 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 130 uint_least64_t d4max = UINT_LEAST64_MAX;
 131 int_fast8_t e1 = INT_FAST8_MAX;
 132 int_fast8_t e1min = INT_FAST8_MIN;
 133 int_fast16_t e2 = INT_FAST16_MAX;
 134 int_fast16_t e2min = INT_FAST16_MIN;
 135 int_fast32_t e3 = INT_FAST32_MAX;
 136 int_fast32_t e3min = INT_FAST32_MIN;
 137 int_fast64_t e4 = INT_FAST64_MAX;
 138 int_fast64_t e4min = INT_FAST64_MIN;
 139 uint_fast8_t f1 = UINT_FAST8_MAX;
 140 uint_fast16_t f2 = UINT_FAST16_MAX;
 141 uint_fast32_t f3 = UINT_FAST32_MAX;
 142 uint_fast64_t f4 = UINT_FAST64_MAX;
 143 #ifdef INTPTR_MAX
 144 intptr_t g = INTPTR_MAX;
 145 intptr_t gmin = INTPTR_MIN;
 146 #endif
 147 #ifdef UINTPTR_MAX
 148 uintptr_t h = UINTPTR_MAX;
 149 #endif
 150 intmax_t i = INTMAX_MAX;
 151 uintmax_t j = UINTMAX_MAX;
 152
 153 #include <limits.h> /* for CHAR_BIT */
 154 #define TYPE_MINIMUM(t) \
 155   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ TYPE_MAXIMUM (t)))
 156 #define TYPE_MAXIMUM(t) \
 157   ((t) ((t) 0 < (t) -1 \
 158         ? (t) -1 \
 159         : ((((t) 1 << (sizeof (t) * CHAR_BIT - 2)) - 1) * 2 + 1)))
 160 struct s {
 161   int check_PTRDIFF:
 162       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
 163       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
 164       ? 1 : -1;
 165   /* Detect bug in FreeBSD 6.0 / ia64.  */
 166   int check_SIG_ATOMIC:
 167       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
 168       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
 169       ? 1 : -1;
 170   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
 171   int check_WCHAR:
 172       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
 173       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
 174       ? 1 : -1;
 175   /* Detect bug in mingw.  */
 176   int check_WINT:
 177       WINT_MIN == TYPE_MINIMUM (wint_t)
 178       && WINT_MAX == TYPE_MAXIMUM (wint_t)
 179       ? 1 : -1;
 180
 181   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 182   int check_UINT8_C:
 183         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 184   int check_UINT16_C:
 185         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 186
 187   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 188 #ifdef UINT8_MAX
 189   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 190 #endif
 191 #ifdef UINT16_MAX
 192   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 193 #endif
 194 #ifdef UINT32_MAX
 195   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 196 #endif
 197 #ifdef UINT64_MAX
 198   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 199 #endif
 200   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 201   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 202   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 203   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 204   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 205   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 206   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 207   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 208   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 209   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 210   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 211 };
 212          ]])],
 213          [dnl Determine whether the various *_MIN, *_MAX macros are usable
 214           dnl in preprocessor expression. We could do it by compiling a test
 215           dnl program for each of these macros. It is faster to run a program
 216           dnl that inspects the macro expansion.
 217           dnl This detects a bug on HP-UX 11.23/ia64.
 218           AC_RUN_IFELSE([
 219             AC_LANG_PROGRAM([[
 220 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ before C++11 */
 221 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ before C++11 */
 222 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 223 #include <stdint.h>
 224 ]
 225 gl_STDINT_INCLUDES
 226 [
 227 #include <stdio.h>
 228 #include <string.h>
 229 #define MVAL(macro) MVAL1(macro)
 230 #define MVAL1(expression) #expression
 231 static const char *macro_values[] =
 232   {
 233 #ifdef INT8_MAX
 234     MVAL (INT8_MAX),
 235 #endif
 236 #ifdef INT16_MAX
 237     MVAL (INT16_MAX),
 238 #endif
 239 #ifdef INT32_MAX
 240     MVAL (INT32_MAX),
 241 #endif
 242 #ifdef INT64_MAX
 243     MVAL (INT64_MAX),
 244 #endif
 245 #ifdef UINT8_MAX
 246     MVAL (UINT8_MAX),
 247 #endif
 248 #ifdef UINT16_MAX
 249     MVAL (UINT16_MAX),
 250 #endif
 251 #ifdef UINT32_MAX
 252     MVAL (UINT32_MAX),
 253 #endif
 254 #ifdef UINT64_MAX
 255     MVAL (UINT64_MAX),
 256 #endif
 257     NULL
 258   };
 259 ]], [[
 260   const char **mv;
 261   for (mv = macro_values; *mv != NULL; mv++)
 262     {
 263       const char *value = *mv;
 264       /* Test whether it looks like a cast expression.  */
 265       if (strncmp (value, "((unsigned int)"/*)*/, 15) == 0
 266           || strncmp (value, "((unsigned short)"/*)*/, 17) == 0
 267           || strncmp (value, "((unsigned char)"/*)*/, 16) == 0
 268           || strncmp (value, "((int)"/*)*/, 6) == 0
 269           || strncmp (value, "((signed short)"/*)*/, 15) == 0
 270           || strncmp (value, "((signed char)"/*)*/, 14) == 0)
 271         return mv - macro_values + 1;
 272     }
 273   return 0;
 274 ]])],
 275               [gl_cv_header_working_stdint_h=yes],
 276               [],
 277               [dnl When cross-compiling, assume it works.
 278                gl_cv_header_working_stdint_h=yes
 279               ])
 280          ])
 281       ])
 282   fi
 283   if test "$gl_cv_header_working_stdint_h" = yes; then
 284     STDINT_H=
 285   else
 286     dnl Check for <sys/inttypes.h>, and for
 287     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 288     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 289     if test $ac_cv_header_sys_inttypes_h = yes; then
 290       HAVE_SYS_INTTYPES_H=1
 291     else
 292       HAVE_SYS_INTTYPES_H=0
 293     fi
 294     AC_SUBST([HAVE_SYS_INTTYPES_H])
 295     if test $ac_cv_header_sys_bitypes_h = yes; then
 296       HAVE_SYS_BITYPES_H=1
 297     else
 298       HAVE_SYS_BITYPES_H=0
 299     fi
 300     AC_SUBST([HAVE_SYS_BITYPES_H])
 301
 302     gl_STDINT_TYPE_PROPERTIES
 303     STDINT_H=stdint.h
 304   fi
 305   AC_SUBST([STDINT_H])
 306   AM_CONDITIONAL([GL_GENERATE_STDINT_H], [test -n "$STDINT_H"])
 307 ])
 308
 309 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 310 dnl Determine the size of each of the given types in bits.
 311 AC_DEFUN([gl_STDINT_BITSIZEOF],
 312 [
 313   dnl Use a shell loop, to avoid bloating configure, and
 314   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 315   dnl   config.h.in,
 316   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 317   m4_foreach_w([gltype], [$1],
 318     [AH_TEMPLATE([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 319        [Define to the number of bits in type ']gltype['.])])
 320   for gltype in $1 ; do
 321     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 322       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 323          [$2
 324 #include <limits.h>], [result=unknown])
 325        eval gl_cv_bitsizeof_${gltype}=\$result
 326       ])
 327     eval result=\$gl_cv_bitsizeof_${gltype}
 328     if test $result = unknown; then
 329       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 330       dnl do a syntax check even on unused #if conditions and give an error
 331       dnl on valid C code like this:
 332       dnl   #if 0
 333       dnl   # if  > 32
 334       dnl   # endif
 335       dnl   #endif
 336       result=0
 337     fi
 338     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 339     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 340     eval BITSIZEOF_${GLTYPE}=\$result
 341   done
 342   m4_foreach_w([gltype], [$1],
 343     [AC_SUBST([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 344 ])
 345
 346 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 347 dnl Determine the signedness of each of the given types.
 348 dnl Define HAVE_SIGNED_TYPE if type is signed.
 349 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 350 [
 351   dnl Use a shell loop, to avoid bloating configure, and
 352   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 353   dnl   config.h.in,
 354   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 355   m4_foreach_w([gltype], [$1],
 356     [AH_TEMPLATE([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 357        [Define to 1 if ']gltype[' is a signed integer type.])])
 358   for gltype in $1 ; do
 359     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 360       [AC_COMPILE_IFELSE(
 361          [AC_LANG_PROGRAM([$2[
 362             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 363          result=yes, result=no)
 364        eval gl_cv_type_${gltype}_signed=\$result
 365       ])
 366     eval result=\$gl_cv_type_${gltype}_signed
 367     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 368     if test "$result" = yes; then
 369       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], [1])
 370       eval HAVE_SIGNED_${GLTYPE}=1
 371     else
 372       eval HAVE_SIGNED_${GLTYPE}=0
 373     fi
 374   done
 375   m4_foreach_w([gltype], [$1],
 376     [AC_SUBST([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 377 ])
 378
 379 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 380 dnl Determine the suffix to use for integer constants of the given types.
 381 dnl Define t_SUFFIX for each such type.
 382 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 383 [
 384   dnl Use a shell loop, to avoid bloating configure, and
 385   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 386   dnl   config.h.in,
 387   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 388   m4_foreach_w([gltype], [$1],
 389     [AH_TEMPLATE(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 390        [Define to l, ll, u, ul, ull, etc., as suitable for
 391         constants of type ']gltype['.])])
 392   for gltype in $1 ; do
 393     AC_CACHE_CHECK([for $gltype integer literal suffix],
 394       [gl_cv_type_${gltype}_suffix],
 395       [eval gl_cv_type_${gltype}_suffix=no
 396        eval result=\$gl_cv_type_${gltype}_signed
 397        if test "$result" = yes; then
 398          glsufu=
 399        else
 400          glsufu=u
 401        fi
 402        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 403          case $glsuf in
 404            '')  gltype1='int';;
 405            l)   gltype1='long int';;
 406            ll)  gltype1='long long int';;
 407            i64) gltype1='__int64';;
 408            u)   gltype1='unsigned int';;
 409            ul)  gltype1='unsigned long int';;
 410            ull) gltype1='unsigned long long int';;
 411            ui64)gltype1='unsigned __int64';;
 412          esac
 413          AC_COMPILE_IFELSE(
 414            [AC_LANG_PROGRAM([$2[
 415               extern $gltype foo;
 416               extern $gltype1 foo;]])],
 417            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 418          eval result=\$gl_cv_type_${gltype}_suffix
 419          test "$result" != no && break
 420        done])
 421     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 422     eval result=\$gl_cv_type_${gltype}_suffix
 423     test "$result" = no && result=
 424     eval ${GLTYPE}_SUFFIX=\$result
 425     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], [$result])
 426   done
 427   m4_foreach_w([gltype], [$1],
 428     [AC_SUBST(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 429 ])
 430
 431 dnl gl_STDINT_INCLUDES
 432 AC_DEFUN([gl_STDINT_INCLUDES],
 433 [[
 434   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 435      included before <wchar.h>.  */
 436   #include <stddef.h>
 437   #include <signal.h>
 438   #if HAVE_WCHAR_H
 439   # include <stdio.h>
 440   # include <time.h>
 441   # include <wchar.h>
 442   #endif
 443 ]])
 444
 445 dnl gl_STDINT_TYPE_PROPERTIES
 446 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 447 dnl of interest to stdint.in.h.
 448 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 449 [
 450   AC_REQUIRE([gl_MULTIARCH])
 451   if test $APPLE_UNIVERSAL_BUILD = 0; then
 452     gl_STDINT_BITSIZEOF([ptrdiff_t size_t],
 453       [gl_STDINT_INCLUDES])
 454   fi
 455   gl_STDINT_BITSIZEOF([sig_atomic_t wchar_t wint_t],
 456     [gl_STDINT_INCLUDES])
 457   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 458     [gl_STDINT_INCLUDES])
 459   gl_cv_type_ptrdiff_t_signed=yes
 460   gl_cv_type_size_t_signed=no
 461   if test $APPLE_UNIVERSAL_BUILD = 0; then
 462     gl_INTEGER_TYPE_SUFFIX([ptrdiff_t size_t],
 463       [gl_STDINT_INCLUDES])
 464   fi
 465   gl_INTEGER_TYPE_SUFFIX([sig_atomic_t wchar_t wint_t],
 466     [gl_STDINT_INCLUDES])
 467
 468   dnl If wint_t is smaller than 'int', it cannot satisfy the ISO C 99
 469   dnl requirement that wint_t is "unchanged by default argument promotions".
 470   dnl In this case gnulib's <wchar.h> and <wctype.h> override wint_t.
 471   dnl Set the variable BITSIZEOF_WINT_T accordingly.
 472   if test $BITSIZEOF_WINT_T -lt 32; then
 473     BITSIZEOF_WINT_T=32
 474   fi
 475 ])
 476
 477 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 478 dnl Remove this when we can assume autoconf >= 2.61.
 479 m4_ifdef([AC_COMPUTE_INT], [], [
 480   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 481 ])
 482
 483 # Hey Emacs!
 484 # Local Variables:
 485 # indent-tabs-mode: nil
 486 # End: