m4/stdint.m4

   1 # stdint.m4 serial 25
   2 dnl Copyright (C) 2001-2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [
  12   AC_PREREQ(2.59)dnl
  13
  14   dnl Check for long long int and unsigned long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  23   if test $ac_cv_type_unsigned_long_long_int = yes; then
  24     HAVE_UNSIGNED_LONG_LONG_INT=1
  25   else
  26     HAVE_UNSIGNED_LONG_LONG_INT=0
  27   fi
  28   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  29
  30   dnl Check for <inttypes.h>.
  31   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  32   if test $ac_cv_header_inttypes_h = yes; then
  33     HAVE_INTTYPES_H=1
  34   else
  35     HAVE_INTTYPES_H=0
  36   fi
  37   AC_SUBST([HAVE_INTTYPES_H])
  38
  39   dnl Check for <sys/types.h>.
  40   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  41   if test $ac_cv_header_sys_types_h = yes; then
  42     HAVE_SYS_TYPES_H=1
  43   else
  44     HAVE_SYS_TYPES_H=0
  45   fi
  46   AC_SUBST([HAVE_SYS_TYPES_H])
  47
  48   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_stdint_h.
  49   if test $ac_cv_header_stdint_h = yes; then
  50     gl_ABSOLUTE_HEADER([stdint.h])
  51     ABSOLUTE_STDINT_H=\"$gl_cv_absolute_stdint_h\"
  52     HAVE_STDINT_H=1
  53   else
  54     ABSOLUTE_STDINT_H=\"no/such/file/stdint.h\"
  55     HAVE_STDINT_H=0
  56   fi
  57   AC_SUBST([ABSOLUTE_STDINT_H])
  58   AC_SUBST([HAVE_STDINT_H])
  59
  60   dnl Now see whether we need a substitute <stdint.h>.  Use
  61   dnl ABSOLUTE_STDINT_H, not <stdint.h>, so that it also works during
  62   dnl a "config.status --recheck" if a stdint.h has been
  63   dnl created in the build directory.
  64   if test $ac_cv_header_stdint_h = yes; then
  65     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  66       [gl_cv_header_working_stdint_h],
  67       [gl_cv_header_working_stdint_h=no
  68        AC_COMPILE_IFELSE([
  69          AC_LANG_PROGRAM([gl_STDINT_INCLUDES
  70          [
  71 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  72 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
  73 #include ABSOLUTE_STDINT_H
  74 #ifdef INT8_MAX
  75 int8_t a1 = INT8_MAX;
  76 int8_t a1min = INT8_MIN;
  77 #endif
  78 #ifdef INT16_MAX
  79 int16_t a2 = INT16_MAX;
  80 int16_t a2min = INT16_MIN;
  81 #endif
  82 #ifdef INT32_MAX
  83 int32_t a3 = INT32_MAX;
  84 int32_t a3min = INT32_MIN;
  85 #endif
  86 #ifdef INT64_MAX
  87 int64_t a4 = INT64_MAX;
  88 int64_t a4min = INT64_MIN;
  89 #endif
  90 #ifdef UINT8_MAX
  91 uint8_t b1 = UINT8_MAX;
  92 #else
  93 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
  94 #endif
  95 #ifdef UINT16_MAX
  96 uint16_t b2 = UINT16_MAX;
  97 #endif
  98 #ifdef UINT32_MAX
  99 uint32_t b3 = UINT32_MAX;
 100 #endif
 101 #ifdef UINT64_MAX
 102 uint64_t b4 = UINT64_MAX;
 103 #endif
 104 int_least8_t c1 = INT8_C (0x7f);
 105 int_least8_t c1max = INT_LEAST8_MAX;
 106 int_least8_t c1min = INT_LEAST8_MIN;
 107 int_least16_t c2 = INT16_C (0x7fff);
 108 int_least16_t c2max = INT_LEAST16_MAX;
 109 int_least16_t c2min = INT_LEAST16_MIN;
 110 int_least32_t c3 = INT32_C (0x7fffffff);
 111 int_least32_t c3max = INT_LEAST32_MAX;
 112 int_least32_t c3min = INT_LEAST32_MIN;
 113 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 114 int_least64_t c4max = INT_LEAST64_MAX;
 115 int_least64_t c4min = INT_LEAST64_MIN;
 116 uint_least8_t d1 = UINT8_C (0xff);
 117 uint_least8_t d1max = UINT_LEAST8_MAX;
 118 uint_least16_t d2 = UINT16_C (0xffff);
 119 uint_least16_t d2max = UINT_LEAST16_MAX;
 120 uint_least32_t d3 = UINT32_C (0xffffffff);
 121 uint_least32_t d3max = UINT_LEAST32_MAX;
 122 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 123 uint_least64_t d4max = UINT_LEAST64_MAX;
 124 int_fast8_t e1 = INT_FAST8_MAX;
 125 int_fast8_t e1min = INT_FAST8_MIN;
 126 int_fast16_t e2 = INT_FAST16_MAX;
 127 int_fast16_t e2min = INT_FAST16_MIN;
 128 int_fast32_t e3 = INT_FAST32_MAX;
 129 int_fast32_t e3min = INT_FAST32_MIN;
 130 int_fast64_t e4 = INT_FAST64_MAX;
 131 int_fast64_t e4min = INT_FAST64_MIN;
 132 uint_fast8_t f1 = UINT_FAST8_MAX;
 133 uint_fast16_t f2 = UINT_FAST16_MAX;
 134 uint_fast32_t f3 = UINT_FAST32_MAX;
 135 uint_fast64_t f4 = UINT_FAST64_MAX;
 136 #ifdef INTPTR_MAX
 137 intptr_t g = INTPTR_MAX;
 138 intptr_t gmin = INTPTR_MIN;
 139 #endif
 140 #ifdef UINTPTR_MAX
 141 uintptr_t h = UINTPTR_MAX;
 142 #endif
 143 intmax_t i = INTMAX_MAX;
 144 uintmax_t j = UINTMAX_MAX;
 145
 146 #include <limits.h> /* for CHAR_BIT */
 147 #define TYPE_MINIMUM(t) \
 148   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ (t) 0 << (sizeof (t) * CHAR_BIT - 1)))
 149 #define TYPE_MAXIMUM(t) \
 150   ((t) ((t) 0 < (t) -1 ? (t) -1 : ~ (~ (t) 0 << (sizeof (t) * CHAR_BIT - 1))))
 151 struct s {
 152   int check_PTRDIFF:
 153       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
 154       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
 155       ? 1 : -1;
 156   /* Detect bug in FreeBSD 6.0 / ia64.  */
 157   int check_SIG_ATOMIC:
 158       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
 159       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
 160       ? 1 : -1;
 161   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
 162   int check_WCHAR:
 163       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
 164       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
 165       ? 1 : -1;
 166   /* Detect bug in mingw.  */
 167   int check_WINT:
 168       WINT_MIN == TYPE_MINIMUM (wint_t)
 169       && WINT_MAX == TYPE_MAXIMUM (wint_t)
 170       ? 1 : -1;
 171
 172   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 173   int check_UINT8_C:
 174         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 175   int check_UINT16_C:
 176         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 177
 178   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 179 #ifdef UINT8_MAX
 180   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 181 #endif
 182 #ifdef UINT16_MAX
 183   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 184 #endif
 185 #ifdef UINT32_MAX
 186   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 187 #endif
 188 #ifdef UINT64_MAX
 189   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 190 #endif
 191   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 192   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 193   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 194   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 195   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 196   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 197   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 198   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 199   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 200   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 201   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 202 };
 203          ]])],
 204          [gl_cv_header_working_stdint_h=yes])])
 205   fi
 206   if test "$gl_cv_header_working_stdint_h" = yes; then
 207     STDINT_H=
 208   else
 209     dnl Check for <sys/inttypes.h>, and for
 210     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 211     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 212     if test $ac_cv_header_sys_inttypes_h = yes; then
 213       HAVE_SYS_INTTYPES_H=1
 214     else
 215       HAVE_SYS_INTTYPES_H=0
 216     fi
 217     AC_SUBST([HAVE_SYS_INTTYPES_H])
 218     if test $ac_cv_header_sys_bitypes_h = yes; then
 219       HAVE_SYS_BITYPES_H=1
 220     else
 221       HAVE_SYS_BITYPES_H=0
 222     fi
 223     AC_SUBST([HAVE_SYS_BITYPES_H])
 224
 225     gl_STDINT_TYPE_PROPERTIES
 226     STDINT_H=stdint.h
 227   fi
 228   AC_SUBST(STDINT_H)
 229 ])
 230
 231 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 232 dnl Determine the size of each of the given types in bits.
 233 AC_DEFUN([gl_STDINT_BITSIZEOF],
 234 [
 235   dnl Use a shell loop, to avoid bloating configure, and
 236   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 237   dnl   config.h.in,
 238   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 239   AC_FOREACH([gltype], [$1],
 240     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 241        [Define to the number of bits in type ']gltype['.])])
 242   for gltype in $1 ; do
 243     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 244       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 245          [$2
 246 #include <limits.h>], [result=unknown])
 247        eval gl_cv_bitsizeof_${gltype}=\$result
 248       ])
 249     eval result=\$gl_cv_bitsizeof_${gltype}
 250     if test $result = unknown; then
 251       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 252       dnl do a syntax check even on unused #if conditions and give an error
 253       dnl on valid C code like this:
 254       dnl   #if 0
 255       dnl   # if  > 32
 256       dnl   # endif
 257       dnl   #endif
 258       result=0
 259     fi
 260     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 261     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 262     eval BITSIZEOF_${GLTYPE}=\$result
 263   done
 264   AC_FOREACH([gltype], [$1],
 265     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 266 ])
 267
 268 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 269 dnl Determine the signedness of each of the given types.
 270 dnl Define HAVE_SIGNED_TYPE if type is signed.
 271 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 272 [
 273   dnl Use a shell loop, to avoid bloating configure, and
 274   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 275   dnl   config.h.in,
 276   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 277   AC_FOREACH([gltype], [$1],
 278     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 279        [Define to 1 if ']gltype[' is a signed integer type.])])
 280   for gltype in $1 ; do
 281     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 282       [AC_COMPILE_IFELSE(
 283          [AC_LANG_PROGRAM([$2[
 284             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 285          result=yes, result=no)
 286        eval gl_cv_type_${gltype}_signed=\$result
 287       ])
 288     eval result=\$gl_cv_type_${gltype}_signed
 289     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 290     if test "$result" = yes; then
 291       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], 1)
 292       eval HAVE_SIGNED_${GLTYPE}=1
 293     else
 294       eval HAVE_SIGNED_${GLTYPE}=0
 295     fi
 296   done
 297   AC_FOREACH([gltype], [$1],
 298     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 299 ])
 300
 301 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 302 dnl Determine the suffix to use for integer constants of the given types.
 303 dnl Define t_SUFFIX for each such type.
 304 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 305 [
 306   dnl Use a shell loop, to avoid bloating configure, and
 307   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 308   dnl   config.h.in,
 309   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 310   AC_FOREACH([gltype], [$1],
 311     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 312        [Define to l, ll, u, ul, ull, etc., as suitable for
 313         constants of type ']gltype['.])])
 314   for gltype in $1 ; do
 315     AC_CACHE_CHECK([for $gltype integer literal suffix],
 316       [gl_cv_type_${gltype}_suffix],
 317       [eval gl_cv_type_${gltype}_suffix=no
 318        eval result=\$gl_cv_type_${gltype}_signed
 319        if test "$result" = yes; then
 320          glsufu=
 321        else
 322          glsufu=u
 323        fi
 324        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 325          case $glsuf in
 326            '')  gltype1='int';;
 327            l)   gltype1='long int';;
 328            ll)  gltype1='long long int';;
 329            i64) gltype1='__int64';;
 330            u)   gltype1='unsigned int';;
 331            ul)  gltype1='unsigned long int';;
 332            ull) gltype1='unsigned long long int';;
 333            ui64)gltype1='unsigned __int64';;
 334          esac
 335          AC_COMPILE_IFELSE(
 336            [AC_LANG_PROGRAM([$2
 337               extern $gltype foo;
 338               extern $gltype1 foo;])],
 339            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 340          eval result=\$gl_cv_type_${gltype}_suffix
 341          test "$result" != no && break
 342        done])
 343     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 344     eval result=\$gl_cv_type_${gltype}_suffix
 345     test "$result" = no && result=
 346     eval ${GLTYPE}_SUFFIX=\$result
 347     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], $result)
 348   done
 349   AC_FOREACH([gltype], [$1],
 350     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 351 ])
 352
 353 dnl gl_STDINT_INCLUDES
 354 AC_DEFUN([gl_STDINT_INCLUDES],
 355 [[
 356   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 357      included before <wchar.h>.  */
 358   #include <stddef.h>
 359   #include <signal.h>
 360   #include <stdio.h>
 361   #include <time.h>
 362   #include <wchar.h>
 363 ]])
 364
 365 dnl gl_STDINT_TYPE_PROPERTIES
 366 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 367 dnl of interest to stdint_.h.
 368 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 369 [
 370   gl_STDINT_BITSIZEOF([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 371     [gl_STDINT_INCLUDES])
 372   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 373     [gl_STDINT_INCLUDES])
 374   gl_cv_type_ptrdiff_t_signed=yes
 375   gl_cv_type_size_t_signed=no
 376   gl_INTEGER_TYPE_SUFFIX([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 377     [gl_STDINT_INCLUDES])
 378 ])
 379
 380 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 381 dnl Remove this when we can assume autoconf >= 2.61.
 382 m4_ifdef([AC_COMPUTE_INT], [], [
 383   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 384 ])
 385
 386 # Hey Emacs!
 387 # Local Variables:
 388 # indent-tabs-mode: nil
 389 # End: