X-Git-Url: https://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Flocale_h.m4;h=e77a3032eb8e355c10449d8b8e25afa34dc2ea5f;hb=c9ff025783e5374226ffbf7940f40ce7db6852ed;hp=913a2009bc432b747f6c7c2860148b637480326d;hpb=17d63e8427ebf2aaec12553ea3a58c582f564b90;p=gnulib.git

diff --git a/m4/locale_h.m4 b/m4/locale_h.m4
index 913a2009b..e77a3032e 100644
--- a/m4/locale_h.m4
+++ b/m4/locale_h.m4
@@ -1,11 +1,15 @@
-# locale_h.m4 serial 4
-dnl Copyright (C) 2007, 2009 Free Software Foundation, Inc.
+# locale_h.m4 serial 14
+dnl Copyright (C) 2007, 2009-2011 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_LOCALE_H],
 [
+  dnl Use AC_REQUIRE here, so that the default behavior below is expanded
+  dnl once only, before all statements that occur in other macros.
+  AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
+
   dnl Persuade glibc <locale.h> to define locale_t.
   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
 
@@ -14,8 +18,11 @@ AC_DEFUN([gl_LOCALE_H],
 
   AC_CACHE_CHECK([whether locale.h conforms to POSIX:2001],
     [gl_cv_header_locale_h_posix2001],
-    [AC_TRY_COMPILE([#include <locale.h>
-int x = LC_MESSAGES;], [],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM(
+          [[#include <locale.h>
+            int x = LC_MESSAGES;]],
+          [[]])],
        [gl_cv_header_locale_h_posix2001=yes],
        [gl_cv_header_locale_h_posix2001=no])])
 
@@ -28,8 +35,11 @@ int x = LC_MESSAGES;], [],
     dnl itself, we assume that <xlocale.h> will do so.
     AC_CACHE_CHECK([whether locale.h defines locale_t],
       [gl_cv_header_locale_has_locale_t],
-      [AC_TRY_COMPILE([#include <locale.h>
-locale_t x;], [],
+      [AC_COMPILE_IFELSE(
+         [AC_LANG_PROGRAM(
+            [[#include <locale.h>
+              locale_t x;]],
+            [[]])],
          [gl_cv_header_locale_has_locale_t=yes],
          [gl_cv_header_locale_has_locale_t=no])
       ])
@@ -44,13 +54,35 @@ locale_t x;], [],
   fi
   AC_SUBST([HAVE_XLOCALE_H])
 
-  if test -z "$STDDEF_H" \
-     && test $gl_cv_header_locale_h_posix2001 = yes \
-     && test $gl_cv_header_locale_h_needs_xlocale_h = no; then
-    LOCALE_H=
-  else
-    gl_CHECK_NEXT_HEADERS([locale.h])
-    LOCALE_H=locale.h
-  fi
-  AC_SUBST([LOCALE_H])
+  dnl <locale.h> is always overridden, because of GNULIB_POSIXCHECK.
+  gl_NEXT_HEADERS([locale.h])
+
+  dnl Check for declarations of anything we want to poison if the
+  dnl corresponding gnulib module is not in use.
+  gl_WARN_ON_USE_PREPARE([[#include <locale.h>
+/* Some systems provide declarations in a non-standard header.  */
+#if HAVE_XLOCALE_H
+# include <xlocale.h>
+#endif
+    ]],
+    [setlocale duplocale])
+])
+
+AC_DEFUN([gl_LOCALE_MODULE_INDICATOR],
+[
+  dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
+  AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
+  gl_MODULE_INDICATOR_SET_VARIABLE([$1])
+  dnl Define it also as a C macro, for the benefit of the unit tests.
+  gl_MODULE_INDICATOR_FOR_TESTS([$1])
+])
+
+AC_DEFUN([gl_LOCALE_H_DEFAULTS],
+[
+  GNULIB_SETLOCALE=0;  AC_SUBST([GNULIB_SETLOCALE])
+  GNULIB_DUPLOCALE=0;  AC_SUBST([GNULIB_DUPLOCALE])
+  dnl Assume proper GNU behavior unless another module says otherwise.
+  HAVE_DUPLOCALE=1;    AC_SUBST([HAVE_DUPLOCALE])
+  REPLACE_SETLOCALE=0; AC_SUBST([REPLACE_SETLOCALE])
+  REPLACE_DUPLOCALE=0; AC_SUBST([REPLACE_DUPLOCALE])
 ])