X-Git-Url: https://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fstrtoimax.m4;h=bee93b21e8b368c6f1fd598ffcb06f3945c026ac;hb=da8054d48dc22e1c051db54049e005d51a006e69;hp=9957637a65c8425ec7081e8eebee297c7180c696;hpb=82ff49b55425e14156a89f4d2ab4267409665f54;p=gnulib.git

diff --git a/m4/strtoimax.m4 b/m4/strtoimax.m4
index 9957637a6..bee93b21e 100644
--- a/m4/strtoimax.m4
+++ b/m4/strtoimax.m4
@@ -1,34 +1,83 @@
-# strtoimax.m4 serial 6
-dnl Copyright (C) 2002, 2003, 2004, 2006 Free Software Foundation, Inc.
+# strtoimax.m4 serial 13
+dnl Copyright (C) 2002-2004, 2006, 2009-2013 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_STRTOIMAX],
 [
-  dnl Work around a bug of AC_EGREP_CPP in autoconf-2.57.
-  AC_REQUIRE([AC_PROG_CPP])
-  AC_REQUIRE([AC_PROG_EGREP])
+  AC_REQUIRE([gl_INTTYPES_H_DEFAULTS])
 
-  AC_CACHE_CHECK([whether <inttypes.h> defines strtoimax as a macro],
-    jm_cv_func_strtoimax_macro,
-    [AC_EGREP_CPP([inttypes_h_defines_strtoimax], [#include <inttypes.h>
-#ifdef strtoimax
- inttypes_h_defines_strtoimax
-#endif],
-       jm_cv_func_strtoimax_macro=yes,
-       jm_cv_func_strtoimax_macro=no)])
+  dnl On OSF/1 5.1 with cc, this function is declared but not defined.
+  AC_CHECK_FUNCS_ONCE([strtoimax])
+  AC_CHECK_DECLS_ONCE([strtoimax])
+  if test "$ac_cv_have_decl_strtoimax" != yes; then
+    HAVE_DECL_STRTOIMAX=0
+  fi
 
-  if test "$jm_cv_func_strtoimax_macro" != yes; then
-    AC_REPLACE_FUNCS(strtoimax)
-    if test $ac_cv_func_strtoimax = no; then
-      gl_PREREQ_STRTOIMAX
-    fi
+  if test $ac_cv_func_strtoimax = yes; then
+    HAVE_STRTOIMAX=1
+    dnl On AIX 5.1, strtoimax() fails for values outside the 'int' range.
+    AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+    AC_CACHE_CHECK([whether strtoimax works], [gl_cv_func_strtoimax],
+      [AC_RUN_IFELSE(
+         [AC_LANG_SOURCE([[
+#include <errno.h>
+#include <string.h>
+#include <inttypes.h>
+int main ()
+{
+  if (sizeof (intmax_t) > sizeof (int))
+    {
+      const char *s = "4294967295";
+      char *p;
+      intmax_t res;
+      errno = 0;
+      res = strtoimax (s, &p, 10);
+      if (p != s + strlen (s))
+        return 1;
+      if (errno != 0)
+        return 2;
+      if (res != (intmax_t) 65535 * (intmax_t) 65537)
+        return 3;
+    }
+  else
+    {
+      const char *s = "2147483647";
+      char *p;
+      intmax_t res;
+      errno = 0;
+      res = strtoimax (s, &p, 10);
+      if (p != s + strlen (s))
+        return 1;
+      if (errno != 0)
+        return 2;
+      if (res != 2147483647)
+        return 3;
+    }
+  return 0;
+}
+]])],
+         [gl_cv_func_strtoimax=yes],
+         [gl_cv_func_strtoimax=no],
+         [case "$host_os" in
+                   # Guess no on AIX 5.
+            aix5*) gl_cv_func_strtoimax="guessing no" ;;
+                   # Guess yes otherwise.
+            *)     gl_cv_func_strtoimax="guessing yes" ;;
+          esac
+         ])
+      ])
+    case "$gl_cv_func_strtoimax" in
+      *no) REPLACE_STRTOIMAX=1 ;;
+    esac
+  else
+    HAVE_STRTOIMAX=0
   fi
 ])
 
 # Prerequisites of lib/strtoimax.c.
 AC_DEFUN([gl_PREREQ_STRTOIMAX], [
-  AC_CHECK_DECLS(strtoll)
+  AC_CHECK_DECLS([strtoll])
   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
 ])