m4/acl.m4

   1 # acl.m4 - check for access control list (ACL) primitives
   2
   3 # Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Paul Eggert and Jim Meyering.
   9
  10 AC_DEFUN([gl_FUNC_ACL],
  11 [
  12   AC_LIBOBJ([acl])
  13   AC_LIBOBJ([file-has-acl])
  14
  15   dnl Prerequisites of lib/acl.c.
  16   LIB_ACL=
  17   use_acl=0
  18   AC_CHECK_HEADERS(sys/acl.h)
  19   if test $ac_cv_header_sys_acl_h = yes; then
  20     ac_save_LIBS=$LIBS
  21     AC_CHECK_FUNCS([acl])
  22     use_acl=1
  23     AC_SEARCH_LIBS([acl_trivial], [sec],
  24       [test "$ac_cv_search_acl_trivial" = "none required" ||
  25        LIB_ACL=$ac_cv_search_acl_trivial
  26        AC_CHECK_FUNCS([acl_trivial])],
  27       [if test $ac_cv_func_acl_trivial != yes; then
  28          AC_SEARCH_LIBS([acl_get_file], [acl],
  29            [test "$ac_cv_search_acl_get_file" = "none required" ||
  30             LIB_ACL=$ac_cv_search_acl_get_file
  31             AC_CHECK_FUNCS(
  32               [acl_get_file acl_get_fd acl_set_file acl_set_fd \
  33                acl_free acl_from_mode acl_from_text \
  34                acl_delete_def_file acl_extended_file])
  35             if test $ac_cv_func_acl_get_file = yes; then
  36               # If the acl_get_file bug is detected, disable all ACL support.
  37               gl_ACL_GET_FILE( , [use_acl=0])
  38             fi
  39             if test $use_acl = 1; then
  40               AC_CHECK_HEADERS([acl/libacl.h])
  41               if test $ac_cv_func_acl_get_file = yes &&
  42                  test $ac_cv_func_acl_free = yes; then
  43                 AC_REPLACE_FUNCS([acl_entries])
  44               fi
  45             else
  46               LIB_ACL=
  47             fi])
  48        fi])
  49     LIBS=$ac_save_LIBS
  50   fi
  51   AC_SUBST([LIB_ACL])
  52   AC_DEFINE_UNQUOTED([USE_ACL], [$use_acl],
  53     [Define to nonzero if you want access control list support.])
  54
  55   # This is for backwards compatibility; remove this by the end of 2007.
  56   LIB_ACL_TRIVIAL=
  57   AC_SUBST([LIB_ACL_TRIVIAL])
  58 ])
  59
  60 # gl_ACL_GET_FILE(IF-WORKS, IF-NOT)
  61 # -------------------------------------
  62 # If `acl_get_file' works (does not have a particular bug),
  63 # run IF-WORKS, otherwise, IF-NOT.
  64 # This tests for a Darwin 8.7.0 bug, whereby acl_get_file returns NULL,
  65 # but sets errno = ENOENT for an existing file or directory.
  66 AC_DEFUN([gl_ACL_GET_FILE],
  67 [
  68   AC_CACHE_CHECK([for working acl_get_file], gl_cv_func_working_acl_get_file,
  69     [AC_RUN_IFELSE(
  70        [AC_LANG_PROGRAM(
  71           [[#include <sys/types.h>
  72            #include <sys/acl.h>
  73            #include <errno.h>
  74           ]],
  75           [[return !! (!acl_get_file (".", ACL_TYPE_ACCESS)
  76                        && errno == ENOENT);]])],
  77        [gl_cv_func_working_acl_get_file=yes],
  78        [gl_cv_func_working_acl_get_file=no],
  79        [gl_cv_func_working_acl_get_file=cross-compiling])])
  80
  81   AS_IF([test $gl_cv_func_working_acl_get_file = yes], [$1], [$2])
  82 ])