m4/acosl.m4

   1 # acosl.m4 serial 1
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ACOSL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare acosl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   ACOSL_LIBM=
  14   AC_CACHE_CHECK([whether acosl() can be used without linking with libm],
  15     [gl_cv_func_acosl_no_libm],
  16     [
  17       AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  18                    # define __NO_MATH_INLINES 1 /* for glibc */
  19                    #endif
  20                    #include <math.h>
  21                    long double x;],
  22                   [return acosl (x) > 1;],
  23         [gl_cv_func_acosl_no_libm=yes],
  24         [gl_cv_func_acosl_no_libm=no])
  25     ])
  26   if test $gl_cv_func_acosl_no_libm = no; then
  27     AC_CACHE_CHECK([whether acosl() can be used with libm],
  28       [gl_cv_func_acosl_in_libm],
  29       [
  30         save_LIBS="$LIBS"
  31         LIBS="$LIBS -lm"
  32         AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  33                      # define __NO_MATH_INLINES 1 /* for glibc */
  34                      #endif
  35                      #include <math.h>
  36                      long double x;],
  37                     [return acosl (x) > 1;],
  38           [gl_cv_func_acosl_in_libm=yes],
  39           [gl_cv_func_acosl_in_libm=no])
  40         LIBS="$save_LIBS"
  41       ])
  42     if test $gl_cv_func_acosl_in_libm = yes; then
  43       ACOSL_LIBM=-lm
  44     fi
  45   fi
  46   if test $gl_cv_func_acosl_no_libm = yes \
  47      || test $gl_cv_func_acosl_in_libm = yes; then
  48     dnl Also check whether it's declared.
  49     dnl MacOS X 10.3 has acosl() in libc but doesn't declare it in <math.h>.
  50     AC_CHECK_DECL([acosl], , [HAVE_DECL_ACOSL=0], [#include <math.h>])
  51   else
  52     HAVE_DECL_ACOSL=0
  53     HAVE_ACOSL=0
  54     AC_LIBOBJ([acosl])
  55     AC_REQUIRE([gl_FUNC_ASINL])
  56     AC_REQUIRE([gl_FUNC_SQRTL])
  57     ACOSL_LIBM="$ASINL_LIBM $SQRTL_LIBM"
  58   fi
  59   AC_SUBST([ACOSL_LIBM])
  60 ])