m4/argp.m4

   1 # argp.m4 serial 13
   2 dnl Copyright (C) 2003-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_ARGP],
   8 [
   9   AC_REQUIRE([AC_C_INLINE])
  10   AC_REQUIRE([AC_C_RESTRICT])
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   AC_CHECK_DECL([program_invocation_name],
  14                 [AC_DEFINE([HAVE_DECL_PROGRAM_INVOCATION_NAME], [1],
  15                            [Define if program_invocation_name is declared])],
  16                 [AC_DEFINE([GNULIB_PROGRAM_INVOCATION_NAME], [1],
  17                            [Define to 1 to add extern declaration of program_invocation_name to argp.h])],
  18                 [[#include <errno.h>]])
  19   AC_CHECK_DECL([program_invocation_short_name],
  20                 [AC_DEFINE([HAVE_DECL_PROGRAM_INVOCATION_SHORT_NAME], [1],
  21                            [Define if program_invocation_short_name is declared])],
  22                 [AC_DEFINE([GNULIB_PROGRAM_INVOCATION_SHORT_NAME], [1],
  23                            [Define to 1 to add extern declaration of program_invocation_short_name to argp.h])],
  24                 [[#include <errno.h>]])
  25
  26   # Check if program_invocation_name and program_invocation_short_name
  27   # are defined elsewhere. It is improbable that only one of them will
  28   # be defined and other not, I prefer to stay on the safe side and to
  29   # test each one separately.
  30   AC_MSG_CHECKING([whether program_invocation_name is defined])
  31   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <argp.h>]],
  32                                   [[program_invocation_name = "test";]])],
  33                  [AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
  34                             [Define if program_invocation_name is defined])
  35                   AC_MSG_RESULT([yes])],
  36                  [AC_MSG_RESULT([no])])
  37
  38   AC_MSG_CHECKING([whether program_invocation_short_name is defined])
  39   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <argp.h>]],
  40                                   [[program_invocation_short_name = "test";]])],
  41                  [AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
  42                             [Define if program_invocation_short_name is defined])
  43                   AC_MSG_RESULT([yes])],
  44                  [AC_MSG_RESULT([no])])
  45
  46   AC_CHECK_DECLS_ONCE([clearerr_unlocked])
  47   AC_CHECK_DECLS_ONCE([feof_unlocked])
  48   AC_CHECK_DECLS_ONCE([ferror_unlocked])
  49   AC_CHECK_DECLS_ONCE([fflush_unlocked])
  50   AC_CHECK_DECLS_ONCE([fgets_unlocked])
  51   AC_CHECK_DECLS_ONCE([fputc_unlocked])
  52   AC_CHECK_DECLS_ONCE([fputs_unlocked])
  53   AC_CHECK_DECLS_ONCE([fread_unlocked])
  54   AC_CHECK_DECLS_ONCE([fwrite_unlocked])
  55   AC_CHECK_DECLS_ONCE([getc_unlocked])
  56   AC_CHECK_DECLS_ONCE([getchar_unlocked])
  57   AC_CHECK_DECLS_ONCE([putc_unlocked])
  58   AC_CHECK_DECLS_ONCE([putchar_unlocked])
  59   AC_CHECK_FUNCS_ONCE([flockfile funlockfile])
  60   AC_CHECK_HEADERS_ONCE([features.h linewrap.h])
  61 ])
  62
  63 dnl argp-parse.c depends on GNU getopt internals, therefore use GNU getopt
  64 dnl always.
  65 AC_DEFUN([gl_REPLACE_GETOPT_ALWAYS], [])