m4/arpa_inet_h.m4

   1 # arpa_inet_h.m4 serial 6
   2 dnl Copyright (C) 2006, 2008, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Simon Josefsson and Bruno Haible
   8
   9 AC_DEFUN([gl_HEADER_ARPA_INET],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_ARPA_INET_H_DEFAULTS])
  14
  15   AC_CHECK_HEADERS_ONCE([arpa/inet.h])
  16   if test $ac_cv_header_arpa_inet_h = yes; then
  17     HAVE_ARPA_INET_H=1
  18   else
  19     HAVE_ARPA_INET_H=0
  20   fi
  21   AC_SUBST([HAVE_ARPA_INET_H])
  22   dnl <arpa/inet.h> is always overridden, because of GNULIB_POSIXCHECK.
  23   gl_CHECK_NEXT_HEADERS([arpa/inet.h])
  24 ])
  25
  26 dnl Unconditionally enables the replacement of <arpa/inet.h>.
  27 AC_DEFUN([gl_REPLACE_ARPA_INET_H],
  28 [
  29   dnl This is a no-op, because <arpa/inet.h> is always overridden.
  30   :
  31 ])
  32
  33 AC_DEFUN([gl_ARPA_INET_MODULE_INDICATOR],
  34 [
  35   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  36   AC_REQUIRE([gl_ARPA_INET_H_DEFAULTS])
  37   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  38 ])
  39
  40 AC_DEFUN([gl_ARPA_INET_H_DEFAULTS],
  41 [
  42   GNULIB_INET_NTOP=0;     AC_SUBST([GNULIB_INET_NTOP])
  43   GNULIB_INET_PTON=0;     AC_SUBST([GNULIB_INET_PTON])
  44   dnl Assume proper GNU behavior unless another module says otherwise.
  45   HAVE_DECL_INET_NTOP=1;  AC_SUBST([HAVE_DECL_INET_NTOP])
  46   HAVE_DECL_INET_PTON=1;  AC_SUBST([HAVE_DECL_INET_PTON])
  47 ])