m4/arpa_inet_h.m4

   1 # arpa_inet_h.m4 serial 4
   2 dnl Copyright (C) 2006, 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Simon Josefsson and Bruno Haible
   8
   9 AC_DEFUN([gl_HEADER_ARPA_INET],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_ARPA_INET_H_DEFAULTS])
  14
  15   AC_CHECK_HEADERS_ONCE([arpa/inet.h])
  16   if test $ac_cv_header_arpa_inet_h = yes; then
  17     HAVE_ARPA_INET_H=1
  18   else
  19     ARPA_INET_H='arpa/inet.h'
  20     HAVE_ARPA_INET_H=0
  21   fi
  22   AC_SUBST([HAVE_ARPA_INET_H])
  23   dnl Execute this unconditionally, because ARPA_INET_H may be set by other
  24   dnl modules, after this code is executed.
  25   gl_CHECK_NEXT_HEADERS([arpa/inet.h])
  26 ])
  27
  28 AC_DEFUN([gl_ARPA_INET_MODULE_INDICATOR],
  29 [
  30   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  31   AC_REQUIRE([gl_ARPA_INET_H_DEFAULTS])
  32   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  33 ])
  34
  35 AC_DEFUN([gl_ARPA_INET_H_DEFAULTS],
  36 [
  37   GNULIB_INET_NTOP=0;     AC_SUBST([GNULIB_INET_NTOP])
  38   GNULIB_INET_PTON=0;     AC_SUBST([GNULIB_INET_PTON])
  39   dnl Assume proper GNU behavior unless another module says otherwise.
  40   HAVE_DECL_INET_NTOP=1;  AC_SUBST([HAVE_DECL_INET_NTOP])
  41   HAVE_DECL_INET_PTON=1;  AC_SUBST([HAVE_DECL_INET_PTON])
  42   ARPA_INET_H='';         AC_SUBST([ARPA_INET_H])
  43 ])