m4/calloc.m4

   1 # calloc.m4 serial 15
   2
   3 # Copyright (C) 2004-2013 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Jim Meyering.
   9
  10 # Determine whether calloc (N, S) returns non-NULL when N*S is zero,
  11 # and returns NULL when N*S overflows.
  12 # If so, define HAVE_CALLOC.  Otherwise, define calloc to rpl_calloc
  13 # and arrange to use a calloc wrapper function that does work in that case.
  14
  15 # _AC_FUNC_CALLOC_IF([IF-WORKS], [IF-NOT])
  16 # -------------------------------------
  17 # If 'calloc (0, 0)' is properly handled, run IF-WORKS, otherwise, IF-NOT.
  18 AC_DEFUN([_AC_FUNC_CALLOC_IF],
  19 [
  20   AC_REQUIRE([AC_TYPE_SIZE_T])dnl
  21   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  22   AC_CACHE_CHECK([for GNU libc compatible calloc],
  23     [ac_cv_func_calloc_0_nonnull],
  24     [AC_RUN_IFELSE(
  25        [AC_LANG_PROGRAM(
  26           [AC_INCLUDES_DEFAULT],
  27           [[int result = 0;
  28             if (!calloc (0, 0))
  29               result |= 1;
  30             if (calloc ((size_t) -1 / 8 + 1, 8))
  31               result |= 2;
  32             return result;
  33           ]])],
  34        [ac_cv_func_calloc_0_nonnull=yes],
  35        [ac_cv_func_calloc_0_nonnull=no],
  36        [case "$host_os" in
  37                   # Guess yes on glibc systems.
  38           *-gnu*) ac_cv_func_calloc_0_nonnull="guessing yes" ;;
  39                   # If we don't know, assume the worst.
  40           *)      ac_cv_func_calloc_0_nonnull="guessing no" ;;
  41         esac
  42        ])])
  43   case "$ac_cv_func_calloc_0_nonnull" in
  44     *yes)
  45       $1
  46       ;;
  47     *)
  48       $2
  49       ;;
  50   esac
  51 ])# AC_FUNC_CALLOC
  52
  53
  54 # gl_FUNC_CALLOC_GNU
  55 # ------------------
  56 # Report whether 'calloc (0, 0)' is properly handled, and replace calloc if
  57 # needed.
  58 AC_DEFUN([gl_FUNC_CALLOC_GNU],
  59 [
  60   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  61   _AC_FUNC_CALLOC_IF(
  62     [AC_DEFINE([HAVE_CALLOC_GNU], [1],
  63                [Define to 1 if your system has a GNU libc compatible 'calloc'
  64                 function, and to 0 otherwise.])],
  65     [AC_DEFINE([HAVE_CALLOC_GNU], [0])
  66      REPLACE_CALLOC=1
  67     ])
  68 ])# gl_FUNC_CALLOC_GNU
  69
  70
  71 # gl_FUNC_CALLOC_POSIX
  72 # --------------------
  73 # Test whether 'calloc' is POSIX compliant (sets errno to ENOMEM when it
  74 # fails), and replace calloc if it is not.
  75 AC_DEFUN([gl_FUNC_CALLOC_POSIX],
  76 [
  77   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  78   AC_REQUIRE([gl_CHECK_MALLOC_POSIX])
  79   if test $gl_cv_func_malloc_posix = yes; then
  80     AC_DEFINE([HAVE_CALLOC_POSIX], [1],
  81       [Define if the 'calloc' function is POSIX compliant.])
  82   else
  83     REPLACE_CALLOC=1
  84   fi
  85 ])