m4/calloc.m4

   1 # calloc.m4 serial 10
   2
   3 # Copyright (C) 2004-2010 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Jim Meyering.
   9
  10 # Determine whether calloc (N, S) returns non-NULL when N*S is zero,
  11 # and returns NULL when N*S overflows.
  12 # If so, define HAVE_CALLOC.  Otherwise, define calloc to rpl_calloc
  13 # and arrange to use a calloc wrapper function that does work in that case.
  14
  15 # _AC_FUNC_CALLOC_IF([IF-WORKS], [IF-NOT])
  16 # -------------------------------------
  17 # If `calloc (0, 0)' is properly handled, run IF-WORKS, otherwise, IF-NOT.
  18 AC_DEFUN([_AC_FUNC_CALLOC_IF],
  19 [AC_REQUIRE([AC_TYPE_SIZE_T])dnl
  20 AC_CACHE_CHECK([for GNU libc compatible calloc], [ac_cv_func_calloc_0_nonnull],
  21 [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
  22                   [[exit (!calloc (0, 0) || calloc ((size_t) -1 / 8 + 1, 8));]])],
  23                [ac_cv_func_calloc_0_nonnull=yes],
  24                [ac_cv_func_calloc_0_nonnull=no],
  25                [ac_cv_func_calloc_0_nonnull=no])])
  26 AS_IF([test $ac_cv_func_calloc_0_nonnull = yes], [$1], [$2])
  27 ])# AC_FUNC_CALLOC
  28
  29
  30 # gl_FUNC_CALLOC_GNU
  31 # ------------------
  32 # Report whether `calloc (0, 0)' is properly handled, and replace calloc if
  33 # needed.
  34 AC_DEFUN([gl_FUNC_CALLOC_GNU],
  35 [
  36   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  37   _AC_FUNC_CALLOC_IF(
  38     [AC_DEFINE([HAVE_CALLOC], [1],
  39                [Define to 1 if your system has a GNU libc compatible `calloc'
  40                 function, and to 0 otherwise.])],
  41     [AC_DEFINE([HAVE_CALLOC], [0])
  42      gl_REPLACE_CALLOC
  43     ])
  44 ])# gl_FUNC_CALLOC_GNU
  45
  46
  47 # gl_FUNC_CALLOC_POSIX
  48 # --------------------
  49 # Test whether 'calloc' is POSIX compliant (sets errno to ENOMEM when it
  50 # fails), and replace calloc if it is not.
  51 AC_DEFUN([gl_FUNC_CALLOC_POSIX],
  52 [
  53   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  54   AC_REQUIRE([gl_CHECK_MALLOC_POSIX])
  55   if test $gl_cv_func_malloc_posix = yes; then
  56     AC_DEFINE([HAVE_CALLOC_POSIX], [1],
  57       [Define if the 'calloc' function is POSIX compliant.])
  58   else
  59     gl_REPLACE_CALLOC
  60   fi
  61 ])
  62
  63 AC_DEFUN([gl_REPLACE_CALLOC],
  64 [
  65   AC_LIBOBJ([calloc])
  66   REPLACE_CALLOC=1
  67 ])