m4/calloc.m4

   1 # calloc.m4 serial 4
   2
   3 # Copyright (C) 2004 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Jim Meyering.
   9
  10 # Determine whether calloc (N, S) returns non-NULL when N*S is zero,
  11 # and returns NULL when N*S overflows.
  12 # If so, define HAVE_CALLOC.  Otherwise, define calloc to rpl_calloc
  13 # and arrange to use a calloc wrapper function that does work in that case.
  14
  15 # _AC_FUNC_CALLOC_IF(IF-WORKS, IF-NOT)
  16 # -------------------------------------
  17 # If `calloc (0, 0)' is properly handled, run IF-WORKS, otherwise, IF-NOT.
  18 AC_DEFUN([_AC_FUNC_CALLOC_IF],
  19 [AC_REQUIRE([AC_HEADER_STDC])dnl
  20 AC_REQUIRE([AC_TYPE_SIZE_T])dnl
  21 AC_CHECK_HEADERS(stdlib.h)
  22 AC_CACHE_CHECK([for GNU libc compatible calloc], ac_cv_func_calloc_0_nonnull,
  23 [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
  24                   [exit (!calloc (0, 0) || calloc ((size_t) -1 / 8 + 1, 8));])],
  25                [ac_cv_func_calloc_0_nonnull=yes],
  26                [ac_cv_func_calloc_0_nonnull=no],
  27                [ac_cv_func_calloc_0_nonnull=no])])
  28 AS_IF([test $ac_cv_func_calloc_0_nonnull = yes], [$1], [$2])
  29 ])# AC_FUNC_CALLOC
  30
  31
  32 # AC_FUNC_CALLOC
  33 # ---------------
  34 # Report whether `calloc (0, 0)' is properly handled, and replace calloc if
  35 # needed.
  36 AC_DEFUN([AC_FUNC_CALLOC],
  37 [_AC_FUNC_CALLOC_IF(
  38   [AC_DEFINE([HAVE_CALLOC], 1,
  39              [Define to 1 if your system has a GNU libc compatible `calloc'
  40               function, and to 0 otherwise.])],
  41   [AC_DEFINE([HAVE_CALLOC], 0)
  42    AC_LIBOBJ([calloc])
  43    AC_DEFINE([calloc], [rpl_calloc],
  44       [Define to rpl_calloc if the replacement function should be used.])])
  45 ])# AC_FUNC_CALLOC