m4/canonicalize.m4

   1 # canonicalize.m4 serial 21
   2
   3 dnl Copyright (C) 2003-2007, 2009-2011 Free Software Foundation, Inc.
   4
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Provides canonicalize_file_name and canonicalize_filename_mode, but does
  10 # not provide or fix realpath.
  11 AC_DEFUN([gl_FUNC_CANONICALIZE_FILENAME_MODE],
  12 [
  13   AC_LIBOBJ([canonicalize])
  14
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16   AC_CHECK_FUNCS_ONCE([canonicalize_file_name])
  17   AC_REQUIRE([gl_DOUBLE_SLASH_ROOT])
  18   AC_REQUIRE([gl_FUNC_REALPATH_WORKS])
  19   if test $ac_cv_func_canonicalize_file_name = no; then
  20     HAVE_CANONICALIZE_FILE_NAME=0
  21   elif test "$gl_cv_func_realpath_works" != yes; then
  22     REPLACE_CANONICALIZE_FILE_NAME=1
  23   fi
  24 ])
  25
  26 # Provides canonicalize_file_name and realpath.
  27 AC_DEFUN([gl_CANONICALIZE_LGPL],
  28 [
  29   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  30   AC_REQUIRE([gl_CANONICALIZE_LGPL_SEPARATE])
  31   if test $ac_cv_func_canonicalize_file_name = no; then
  32     HAVE_CANONICALIZE_FILE_NAME=0
  33     AC_LIBOBJ([canonicalize-lgpl])
  34     if test $ac_cv_func_realpath = no; then
  35       HAVE_REALPATH=0
  36     elif test "$gl_cv_func_realpath_works" != yes; then
  37       REPLACE_REALPATH=1
  38     fi
  39   elif test "$gl_cv_func_realpath_works" != yes; then
  40     AC_LIBOBJ([canonicalize-lgpl])
  41     REPLACE_REALPATH=1
  42     REPLACE_CANONICALIZE_FILE_NAME=1
  43   fi
  44 ])
  45
  46 # Like gl_CANONICALIZE_LGPL, except prepare for separate compilation
  47 # (no REPLACE_CANONICALIZE_FILE_NAME, no REPLACE_REALPATH, no AC_LIBOBJ).
  48 AC_DEFUN([gl_CANONICALIZE_LGPL_SEPARATE],
  49 [
  50   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  51   AC_CHECK_FUNCS_ONCE([canonicalize_file_name getcwd readlink])
  52   AC_REQUIRE([gl_DOUBLE_SLASH_ROOT])
  53   AC_REQUIRE([gl_FUNC_REALPATH_WORKS])
  54   AC_CHECK_HEADERS_ONCE([sys/param.h])
  55 ])
  56
  57 # Check whether realpath works.  Assume that if a platform has both
  58 # realpath and canonicalize_file_name, but the former is broken, then
  59 # so is the latter.
  60 AC_DEFUN([gl_FUNC_REALPATH_WORKS],
  61 [
  62   AC_CHECK_FUNCS_ONCE([realpath])
  63   AC_CACHE_CHECK([whether realpath works], [gl_cv_func_realpath_works], [
  64     touch conftest.a
  65     mkdir conftest.d
  66     AC_RUN_IFELSE([
  67       AC_LANG_PROGRAM([[
  68         ]GL_NOCRASH[
  69         #include <stdlib.h>
  70         #include <string.h>
  71       ]], [[
  72         int result = 0;
  73         {
  74           char *name = realpath ("conftest.a", NULL);
  75           if (!(name && *name == '/'))
  76             result |= 1;
  77         }
  78         {
  79           char *name = realpath ("conftest.b/../conftest.a", NULL);
  80           if (name != NULL)
  81             result |= 2;
  82         }
  83         {
  84           char *name = realpath ("conftest.a/", NULL);
  85           if (name != NULL)
  86             result |= 4;
  87         }
  88         {
  89           char *name1 = realpath (".", NULL);
  90           char *name2 = realpath ("conftest.d//./..", NULL);
  91           if (strcmp (name1, name2) != 0)
  92             result |= 8;
  93         }
  94         return result;
  95       ]])
  96     ], [gl_cv_func_realpath_works=yes], [gl_cv_func_realpath_works=no],
  97        [gl_cv_func_realpath_works="guessing no"])
  98     rm -rf conftest.a conftest.d
  99   ])
 100   if test "$gl_cv_func_realpath_works" = yes; then
 101     AC_DEFINE([FUNC_REALPATH_WORKS], [1], [Define to 1 if realpath()
 102       can malloc memory, always gives an absolute path, and handles
 103       trailing slash correctly.])
 104   fi
 105 ])