m4/ceilf.m4

   1 # ceilf.m4 serial 1
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_CEILF],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare ceilf().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   dnl Test whether ceilf() is declared.
  13   AC_CHECK_DECLS([ceilf], , , [#include <math.h>])
  14   if test "$ac_cv_have_decl_ceilf" = yes; then
  15     dnl Test whether ceilf() can be used without libm.
  16     CEILF_LIBM=?
  17     AC_TRY_LINK([
  18        #ifndef __NO_MATH_INLINES
  19        # define __NO_MATH_INLINES 1 /* for glibc */
  20        #endif
  21        #include <math.h>
  22        float x;],
  23       [x = ceilf(x);],
  24       [CEILF_LIBM=])
  25     if test "$CEILF_LIBM" = "?"; then
  26       save_LIBS="$LIBS"
  27       LIBS="$LIBS -lm"
  28       AC_TRY_LINK([
  29          #ifndef __NO_MATH_INLINES
  30          # define __NO_MATH_INLINES 1 /* for glibc */
  31          #endif
  32          #include <math.h>
  33          float x;],
  34         [x = ceilf(x);],
  35         [CEILF_LIBM="-lm"])
  36       LIBS="$save_LIBS"
  37     fi
  38     if test "$CEILF_LIBM" = "?"; then
  39       CEILF_LIBM=
  40     fi
  41   else
  42     HAVE_DECL_CEILF=0
  43     AC_LIBOBJ([ceilf])
  44     CEILF_LIBM=
  45   fi
  46   AC_SUBST([HAVE_DECL_CEILF])
  47   AC_SUBST([CEILF_LIBM])
  48 ])