m4/ceilf.m4

   1 # ceilf.m4 serial 10
   2 dnl Copyright (C) 2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_CEILF],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_ceilf_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare ceilf().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   dnl Test whether ceilf() is declared.
  14   AC_CHECK_DECLS([ceilf], , , [#include <math.h>])
  15   if test "$ac_cv_have_decl_ceilf" = yes; then
  16     dnl Test whether ceilf() can be used without libm.
  17     gl_FUNC_CEILF_LIBS
  18     if test "$CEILF_LIBM" = "?"; then
  19       dnl Sun C 5.0 on Solaris declares ceilf() and has it in the system-wide
  20       dnl libm.so, but not in the libm.so that the compiler uses.
  21       REPLACE_CEILF=1
  22     fi
  23     m4_ifdef([gl_FUNC_CEILF_IEEE], [
  24       if test $gl_ceilf_required = ieee && test $REPLACE_CEILF = 0; then
  25         AC_CACHE_CHECK([whether ceilf works according to ISO C 99 with IEC 60559],
  26           [gl_cv_func_ceilf_ieee],
  27           [
  28             save_LIBS="$LIBS"
  29             LIBS="$LIBS $CEILF_LIBM"
  30             AC_RUN_IFELSE(
  31               [AC_LANG_SOURCE([[
  32 #ifndef __NO_MATH_INLINES
  33 # define __NO_MATH_INLINES 1 /* for glibc */
  34 #endif
  35 #include <math.h>
  36 ]gl_FLOAT_MINUS_ZERO_CODE[
  37 ]gl_FLOAT_SIGNBIT_CODE[
  38 int main()
  39 {
  40   int result = 0;
  41   /* Test whether ceilf (-0.0f) is -0.0f.  */
  42   if (signbitf (minus_zerof) && !signbitf (ceilf (minus_zerof)))
  43     result |= 1;
  44   /* Test whether ceilf (-0.3f) is -0.0f.  */
  45   if (signbitf (-0.3f) && !signbitf (ceilf (-0.3f)))
  46     result |= 2;
  47   return result;
  48 }
  49               ]])],
  50               [gl_cv_func_ceilf_ieee=yes],
  51               [gl_cv_func_ceilf_ieee=no],
  52               [gl_cv_func_ceilf_ieee="guessing no"])
  53             LIBS="$save_LIBS"
  54           ])
  55         case "$gl_cv_func_ceilf_ieee" in
  56           *yes) ;;
  57           *) REPLACE_CEILF=1 ;;
  58         esac
  59       fi
  60     ])
  61   else
  62     HAVE_DECL_CEILF=0
  63   fi
  64   if test $HAVE_DECL_CEILF = 0 || test $REPLACE_CEILF = 1; then
  65     dnl No libraries are needed to link lib/ceilf.c.
  66     CEILF_LIBM=
  67   fi
  68   AC_SUBST([CEILF_LIBM])
  69 ])
  70
  71 # Determines the libraries needed to get the ceilf() function.
  72 # Sets CEILF_LIBM.
  73 AC_DEFUN([gl_FUNC_CEILF_LIBS],
  74 [
  75   gl_CACHE_VAL_SILENT([gl_cv_func_ceilf_libm], [
  76     gl_cv_func_ceilf_libm=?
  77     AC_LINK_IFELSE(
  78       [AC_LANG_PROGRAM(
  79          [[#ifndef __NO_MATH_INLINES
  80            # define __NO_MATH_INLINES 1 /* for glibc */
  81            #endif
  82            #include <math.h>
  83            float x;]],
  84          [[x = ceilf(x);]])],
  85       [gl_cv_func_ceilf_libm=])
  86     if test "$gl_cv_func_ceilf_libm" = "?"; then
  87       save_LIBS="$LIBS"
  88       LIBS="$LIBS -lm"
  89       AC_LINK_IFELSE(
  90         [AC_LANG_PROGRAM(
  91            [[#ifndef __NO_MATH_INLINES
  92              # define __NO_MATH_INLINES 1 /* for glibc */
  93              #endif
  94              #include <math.h>
  95              float x;]],
  96            [[x = ceilf(x);]])],
  97         [gl_cv_func_ceilf_libm="-lm"])
  98       LIBS="$save_LIBS"
  99     fi
 100   ])
 101   CEILF_LIBM="$gl_cv_func_ceilf_libm"
 102 ])