m4/ceill.m4

   1 # ceill.m4 serial 14
   2 dnl Copyright (C) 2007, 2009-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_CEILL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_ceill_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12
  13   dnl Persuade glibc <math.h> to declare ceill().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Test whether ceill() is declared.
  17   AC_CHECK_DECLS([ceill], , , [[#include <math.h>]])
  18   if test "$ac_cv_have_decl_ceill" = yes; then
  19     dnl Test whether ceill() can be used without libm.
  20     gl_FUNC_CEILL_LIBS
  21     if test "$CEILL_LIBM" = "?"; then
  22       dnl Sun C 5.0 on Solaris declares ceill() and has it in the system-wide
  23       dnl libm.so, but not in the libm.so that the compiler uses.
  24       REPLACE_CEILL=1
  25     fi
  26     m4_ifdef([gl_FUNC_CEILL_IEEE], [
  27       if test $gl_ceill_required = ieee && test $REPLACE_CEILL = 0; then
  28         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  29         AC_CACHE_CHECK([whether ceill works according to ISO C 99 with IEC 60559],
  30           [gl_cv_func_ceill_ieee],
  31           [
  32             save_LIBS="$LIBS"
  33             LIBS="$LIBS $CEILL_LIBM"
  34             AC_RUN_IFELSE(
  35               [AC_LANG_SOURCE([[
  36 #ifndef __NO_MATH_INLINES
  37 # define __NO_MATH_INLINES 1 /* for glibc */
  38 #endif
  39 #include <math.h>
  40 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  41 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  42 static long double dummy (long double f) { return 0; }
  43 int main (int argc, char *argv[])
  44 {
  45   long double (*my_ceill) (long double) = argc ? ceill : dummy;
  46   /* Test whether ceill (-0.3L) is -0.0L.  */
  47   if (signbitl (minus_zerol) && !signbitl (my_ceill (-0.3L)))
  48     return 1;
  49   return 0;
  50 }
  51               ]])],
  52               [gl_cv_func_ceill_ieee=yes],
  53               [gl_cv_func_ceill_ieee=no],
  54               [case "$host_os" in
  55                          # Guess yes on glibc systems.
  56                  *-gnu*) gl_cv_func_ceill_ieee="guessing yes" ;;
  57                          # If we don't know, assume the worst.
  58                  *)      gl_cv_func_ceill_ieee="guessing no" ;;
  59                esac
  60               ])
  61             LIBS="$save_LIBS"
  62           ])
  63         case "$gl_cv_func_ceill_ieee" in
  64           *yes) ;;
  65           *) REPLACE_CEILL=1 ;;
  66         esac
  67       fi
  68     ])
  69   else
  70     HAVE_DECL_CEILL=0
  71   fi
  72   if test $HAVE_DECL_CEILL = 0 || test $REPLACE_CEILL = 1; then
  73     dnl Find libraries needed to link lib/ceill.c.
  74     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  75       AC_REQUIRE([gl_FUNC_CEIL])
  76       CEILL_LIBM="$CEIL_LIBM"
  77     else
  78       CEILL_LIBM=
  79     fi
  80   fi
  81   AC_SUBST([CEILL_LIBM])
  82 ])
  83
  84 # Determines the libraries needed to get the ceill() function.
  85 # Sets CEILL_LIBM.
  86 AC_DEFUN([gl_FUNC_CEILL_LIBS],
  87 [
  88   gl_CACHE_VAL_SILENT([gl_cv_func_ceill_libm], [
  89     gl_cv_func_ceill_libm=?
  90     AC_LINK_IFELSE(
  91       [AC_LANG_PROGRAM(
  92          [[#ifndef __NO_MATH_INLINES
  93            # define __NO_MATH_INLINES 1 /* for glibc */
  94            #endif
  95            #include <math.h>
  96            long double (*funcptr) (long double) = ceill;
  97            long double x;]],
  98          [[x = funcptr(x) + ceill(x);]])],
  99       [gl_cv_func_ceill_libm=])
 100     if test "$gl_cv_func_ceill_libm" = "?"; then
 101       save_LIBS="$LIBS"
 102       LIBS="$LIBS -lm"
 103       AC_LINK_IFELSE(
 104         [AC_LANG_PROGRAM(
 105            [[#ifndef __NO_MATH_INLINES
 106              # define __NO_MATH_INLINES 1 /* for glibc */
 107              #endif
 108              #include <math.h>
 109              long double (*funcptr) (long double) = ceill;
 110              long double x;]],
 111            [[x = funcptr(x) + ceill(x);]])],
 112         [gl_cv_func_ceill_libm="-lm"])
 113       LIBS="$save_LIBS"
 114     fi
 115   ])
 116   CEILL_LIBM="$gl_cv_func_ceill_libm"
 117 ])