m4/copysignf.m4

   1 # copysignf.m4 serial 3
   2 dnl Copyright (C) 2011-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_COPYSIGNF],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10
  11   dnl Persuade glibc <math.h> to declare copysignf().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13
  14   dnl Determine COPYSIGNF_LIBM.
  15   gl_MATHFUNC([copysignf], [float], [(float, float)],
  16     [extern
  17      #ifdef __cplusplus
  18      "C"
  19      #endif
  20      float copysignf (float, float);
  21     ])
  22   if test $gl_cv_func_copysignf_no_libm = yes \
  23      || test $gl_cv_func_copysignf_in_libm = yes; then
  24     HAVE_COPYSIGNF=1
  25     dnl Also check whether it's declared.
  26     dnl IRIX 6.5 has copysignf() in libm but doesn't declare it in <math.h>.
  27     AC_CHECK_DECL([copysignf], , [HAVE_DECL_COPYSIGNF=0], [[#include <math.h>]])
  28   else
  29     HAVE_COPYSIGNF=0
  30     HAVE_DECL_COPYSIGNF=0
  31     COPYSIGNF_LIBM=
  32   fi
  33   AC_SUBST([COPYSIGNF_LIBM])
  34 ])