m4/cosl.m4

   1 # cosl.m4 serial 4
   2 dnl Copyright (C) 2010-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_COSL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare cosl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   COSL_LIBM=
  14   AC_CACHE_CHECK([whether cosl() can be used without linking with libm],
  15     [gl_cv_func_cosl_no_libm],
  16     [
  17       AC_LINK_IFELSE(
  18         [AC_LANG_PROGRAM(
  19            [[#ifndef __NO_MATH_INLINES
  20              # define __NO_MATH_INLINES 1 /* for glibc */
  21              #endif
  22              #include <math.h>
  23              long double x;]],
  24            [[return cosl (x) > 0.4;]])],
  25         [gl_cv_func_cosl_no_libm=yes],
  26         [gl_cv_func_cosl_no_libm=no])
  27     ])
  28   if test $gl_cv_func_cosl_no_libm = no; then
  29     AC_CACHE_CHECK([whether cosl() can be used with libm],
  30       [gl_cv_func_cosl_in_libm],
  31       [
  32         save_LIBS="$LIBS"
  33         LIBS="$LIBS -lm"
  34         AC_LINK_IFELSE(
  35           [AC_LANG_PROGRAM(
  36              [[#ifndef __NO_MATH_INLINES
  37                # define __NO_MATH_INLINES 1 /* for glibc */
  38                #endif
  39                #include <math.h>
  40                long double x;]],
  41              [[return cosl (x) > 0.4;]])],
  42           [gl_cv_func_cosl_in_libm=yes],
  43           [gl_cv_func_cosl_in_libm=no])
  44         LIBS="$save_LIBS"
  45       ])
  46     if test $gl_cv_func_cosl_in_libm = yes; then
  47       COSL_LIBM=-lm
  48     fi
  49   fi
  50   if test $gl_cv_func_cosl_no_libm = yes \
  51      || test $gl_cv_func_cosl_in_libm = yes; then
  52     dnl Also check whether it's declared.
  53     dnl MacOS X 10.3 has cosl() in libc but doesn't declare it in <math.h>.
  54     AC_CHECK_DECL([cosl], , [HAVE_DECL_COSL=0], [#include <math.h>])
  55   else
  56     HAVE_DECL_COSL=0
  57     HAVE_COSL=0
  58     dnl Find libraries needed to link lib/cosl.c, lib/sincosl.c, lib/trigl.c.
  59     AC_REQUIRE([gl_FUNC_ISNANL])
  60     AC_REQUIRE([gl_FUNC_FLOOR])
  61     AC_REQUIRE([gl_FUNC_FLOORL])
  62     dnl Append $ISNANL_LIBM to COSL_LIBM, avoiding gratuitous duplicates.
  63     case " $COSL_LIBM " in
  64       *" $ISNANL_LIBM "*) ;;
  65       *) COSL_LIBM="$COSL_LIBM $ISNANL_LIBM" ;;
  66     esac
  67     dnl Append $FLOOR_LIBM to COSL_LIBM, avoiding gratuitous duplicates.
  68     case " $COSL_LIBM " in
  69       *" $FLOOR_LIBM "*) ;;
  70       *) COSL_LIBM="$COSL_LIBM $FLOOR_LIBM" ;;
  71     esac
  72     dnl Append $FLOORL_LIBM to COSL_LIBM, avoiding gratuitous duplicates.
  73     case " $COSL_LIBM " in
  74       *" $FLOORL_LIBM "*) ;;
  75       *) COSL_LIBM="$COSL_LIBM $FLOORL_LIBM" ;;
  76     esac
  77   fi
  78   AC_SUBST([COSL_LIBM])
  79 ])