m4/dup2.m4

   1 #serial 7
   2 dnl Copyright (C) 2002, 2005, 2007, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_DUP2],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11   AC_CHECK_FUNCS_ONCE([dup2])
  12   if test $ac_cv_func_dup2 = no; then
  13     HAVE_DUP2=0
  14     AC_LIBOBJ([dup2])
  15   else
  16     AC_CACHE_CHECK([whether dup2 works], [gl_cv_func_dup2_works],
  17       [AC_RUN_IFELSE([
  18          AC_LANG_PROGRAM([[#include <unistd.h>]],
  19            [if (dup2 (1, 1) == 0)
  20               return 1;
  21             close (0);
  22             if (dup2 (0, 0) != -1)
  23               return 1;
  24             return 0;
  25            ])
  26         ],
  27         [gl_cv_func_dup2_works=yes], [gl_cv_func_dup2_works=no],
  28         [case "$host_os" in
  29            mingw*) # on this platform, dup2 always returns 0 for success
  30              gl_cv_func_dup2_works=no;;
  31            cygwin*) # on cygwin 1.5.x, dup2(1,1) returns 0
  32              gl_cv_func_dup2_works=no;;
  33            linux*) # On linux between 2008-07-27 and 2009-05-11, dup2 of a
  34                    # closed fd may yield -EBADF instead of -1 / errno=EBADF.
  35              gl_cv_func_dup2_works=no;;
  36            *) gl_cv_func_dup2_works=yes;;
  37          esac])
  38       ])
  39     if test "$gl_cv_func_dup2_works" = no; then
  40       REPLACE_DUP2=1
  41       AC_LIBOBJ([dup2])
  42     fi
  43   fi
  44   AC_DEFINE_UNQUOTED([REPLACE_DUP2], [$REPLACE_DUP2],
  45     [Define to 1 if dup2 returns 0 instead of the target fd.])
  46 ])