m4/expl.m4

   1 # expl.m4 serial 8
   2 dnl Copyright (C) 2010-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_EXPL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11
  12   dnl Persuade glibc <math.h> to declare expl().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   EXPL_LIBM=
  16   AC_CACHE_CHECK([whether expl() can be used without linking with libm],
  17     [gl_cv_func_expl_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              long double (*funcptr) (long double) = expl;
  26              long double x;]],
  27            [[return funcptr (x) > 1.5
  28                     || expl (x) > 1.5;]])],
  29         [gl_cv_func_expl_no_libm=yes],
  30         [gl_cv_func_expl_no_libm=no])
  31     ])
  32   if test $gl_cv_func_expl_no_libm = no; then
  33     AC_CACHE_CHECK([whether expl() can be used with libm],
  34       [gl_cv_func_expl_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                long double (*funcptr) (long double) = expl;
  45                long double x;]],
  46              [[return funcptr (x) > 1.5
  47                       || expl (x) > 1.5;]])],
  48           [gl_cv_func_expl_in_libm=yes],
  49           [gl_cv_func_expl_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_expl_in_libm = yes; then
  53       EXPL_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_expl_no_libm = yes \
  57      || test $gl_cv_func_expl_in_libm = yes; then
  58     dnl Also check whether it's declared.
  59     dnl Mac OS X 10.3 has expl() in libc but doesn't declare it in <math.h>.
  60     AC_CHECK_DECL([expl], , [HAVE_DECL_EXPL=0], [[#include <math.h>]])
  61   else
  62     HAVE_DECL_EXPL=0
  63     HAVE_EXPL=0
  64     dnl Find libraries needed to link lib/expl.c.
  65     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  66       AC_REQUIRE([gl_FUNC_EXP])
  67       EXPL_LIBM="$EXP_LIBM"
  68     else
  69       AC_REQUIRE([gl_FUNC_ISNANL])
  70       AC_REQUIRE([gl_FUNC_ROUNDL])
  71       AC_REQUIRE([gl_FUNC_LDEXPL])
  72       EXPL_LIBM=
  73       dnl Append $ISNANL_LIBM to EXPL_LIBM, avoiding gratuitous duplicates.
  74       case " $EXPL_LIBM " in
  75         *" $ISNANL_LIBM "*) ;;
  76         *) EXPL_LIBM="$EXPL_LIBM $ISNANL_LIBM" ;;
  77       esac
  78       dnl Append $ROUNDL_LIBM to EXPL_LIBM, avoiding gratuitous duplicates.
  79       case " $EXPL_LIBM " in
  80         *" $ROUNDL_LIBM "*) ;;
  81         *) EXPL_LIBM="$EXPL_LIBM $ROUNDL_LIBM" ;;
  82       esac
  83       dnl Append $LDEXPL_LIBM to EXPL_LIBM, avoiding gratuitous duplicates.
  84       case " $EXPL_LIBM " in
  85         *" $LDEXPL_LIBM "*) ;;
  86         *) EXPL_LIBM="$EXPL_LIBM $LDEXPL_LIBM" ;;
  87       esac
  88     fi
  89   fi
  90   AC_SUBST([EXPL_LIBM])
  91 ])