m4/expm1.m4

   1 # expm1.m4 serial 3
   2 dnl Copyright (C) 2010-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_EXPM1],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_expm1_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11
  12   dnl Persuade glibc <math.h> to declare expm1().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   EXPM1_LIBM=
  16   AC_CACHE_CHECK([whether expm1() can be used without linking with libm],
  17     [gl_cv_func_expm1_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              double (*funcptr) (double) = expm1;
  26              double x;]],
  27            [[return funcptr (x) > 0.5
  28                     || expm1 (x) > 0.5;]])],
  29         [gl_cv_func_expm1_no_libm=yes],
  30         [gl_cv_func_expm1_no_libm=no])
  31     ])
  32   if test $gl_cv_func_expm1_no_libm = no; then
  33     AC_CACHE_CHECK([whether expm1() can be used with libm],
  34       [gl_cv_func_expm1_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                double (*funcptr) (double) = expm1;
  45                double x;]],
  46              [[return funcptr (x) > 0.5
  47                       || expm1 (x) > 0.5;]])],
  48           [gl_cv_func_expm1_in_libm=yes],
  49           [gl_cv_func_expm1_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_expm1_in_libm = yes; then
  53       EXPM1_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_expm1_no_libm = yes \
  57      || test $gl_cv_func_expm1_in_libm = yes; then
  58     :
  59     m4_ifdef([gl_FUNC_EXPM1_IEEE], [
  60       if test $gl_expm1_required = ieee && test $REPLACE_EXPM1 = 0; then
  61         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  62         AC_CACHE_CHECK([whether expm1 works according to ISO C 99 with IEC 60559],
  63           [gl_cv_func_expm1_ieee],
  64           [
  65             save_LIBS="$LIBS"
  66             LIBS="$LIBS $EXPM1_LIBM"
  67             AC_RUN_IFELSE(
  68               [AC_LANG_SOURCE([[
  69 #ifndef __NO_MATH_INLINES
  70 # define __NO_MATH_INLINES 1 /* for glibc */
  71 #endif
  72 #include <math.h>
  73 ]gl_DOUBLE_MINUS_ZERO_CODE[
  74 ]gl_DOUBLE_SIGNBIT_CODE[
  75 static double dummy (double x) { return 0; }
  76 int main (int argc, char *argv[])
  77 {
  78   double (*my_expm1) (double) = argc ? expm1 : dummy;
  79   double y = my_expm1 (minus_zerod);
  80   if (!(y == 0.0) || (signbitd (minus_zerod) && !signbitd (y)))
  81     return 1;
  82   return 0;
  83 }
  84               ]])],
  85               [gl_cv_func_expm1_ieee=yes],
  86               [gl_cv_func_expm1_ieee=no],
  87               [case "$host_os" in
  88                          # Guess yes on glibc systems.
  89                  *-gnu*) gl_cv_func_expm1_ieee="guessing yes" ;;
  90                          # If we don't know, assume the worst.
  91                  *)      gl_cv_func_expm1_ieee="guessing no" ;;
  92                esac
  93               ])
  94             LIBS="$save_LIBS"
  95           ])
  96         case "$gl_cv_func_expm1_ieee" in
  97           *yes) ;;
  98           *) REPLACE_EXPM1=1 ;;
  99         esac
 100       fi
 101     ])
 102   else
 103     HAVE_EXPM1=0
 104   fi
 105   if test $HAVE_EXPM1 = 0 || test $REPLACE_EXPM1 = 1; then
 106     dnl Find libraries needed to link lib/expm1.c.
 107     AC_REQUIRE([gl_FUNC_ISNAND])
 108     AC_REQUIRE([gl_FUNC_EXP])
 109     AC_REQUIRE([gl_FUNC_ROUND])
 110     AC_REQUIRE([gl_FUNC_LDEXP])
 111     EXPM1_LIBM=
 112     dnl Append $ISNAND_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 113     case " $EXPM1_LIBM " in
 114       *" $ISNAND_LIBM "*) ;;
 115       *) EXPM1_LIBM="$EXPM1_LIBM $ISNAND_LIBM" ;;
 116     esac
 117     dnl Append $EXP_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 118     case " $EXPM1_LIBM " in
 119       *" $EXP_LIBM "*) ;;
 120       *) EXPM1_LIBM="$EXPM1_LIBM $EXP_LIBM" ;;
 121     esac
 122     dnl Append $ROUND_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 123     case " $EXPM1_LIBM " in
 124       *" $ROUND_LIBM "*) ;;
 125       *) EXPM1_LIBM="$EXPM1_LIBM $ROUND_LIBM" ;;
 126     esac
 127     dnl Append $LDEXP_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 128     case " $EXPM1_LIBM " in
 129       *" $LDEXP_LIBM "*) ;;
 130       *) EXPM1_LIBM="$EXPM1_LIBM $LDEXP_LIBM" ;;
 131     esac
 132   fi
 133   AC_SUBST([EXPM1_LIBM])
 134 ])