m4/expm1.m4

   1 # expm1.m4 serial 2
   2 dnl Copyright (C) 2010-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_EXPM1],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_expm1_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11
  12   dnl Persuade glibc <math.h> to declare expm1().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   EXPM1_LIBM=
  16   AC_CACHE_CHECK([whether expm1() can be used without linking with libm],
  17     [gl_cv_func_expm1_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              double (*funcptr) (double) = expm1;
  26              double x;]],
  27            [[return funcptr (x) > 0.5
  28                     || expm1 (x) > 0.5;]])],
  29         [gl_cv_func_expm1_no_libm=yes],
  30         [gl_cv_func_expm1_no_libm=no])
  31     ])
  32   if test $gl_cv_func_expm1_no_libm = no; then
  33     AC_CACHE_CHECK([whether expm1() can be used with libm],
  34       [gl_cv_func_expm1_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                double (*funcptr) (double) = expm1;
  45                double x;]],
  46              [[return funcptr (x) > 0.5
  47                       || expm1 (x) > 0.5;]])],
  48           [gl_cv_func_expm1_in_libm=yes],
  49           [gl_cv_func_expm1_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_expm1_in_libm = yes; then
  53       EXPM1_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_expm1_no_libm = yes \
  57      || test $gl_cv_func_expm1_in_libm = yes; then
  58     :
  59     m4_ifdef([gl_FUNC_EXPM1_IEEE], [
  60       if test $gl_expm1_required = ieee && test $REPLACE_EXPM1 = 0; then
  61         AC_CACHE_CHECK([whether expm1 works according to ISO C 99 with IEC 60559],
  62           [gl_cv_func_expm1_ieee],
  63           [
  64             save_LIBS="$LIBS"
  65             LIBS="$LIBS $EXPM1_LIBM"
  66             AC_RUN_IFELSE(
  67               [AC_LANG_SOURCE([[
  68 #ifndef __NO_MATH_INLINES
  69 # define __NO_MATH_INLINES 1 /* for glibc */
  70 #endif
  71 #include <math.h>
  72 ]gl_DOUBLE_MINUS_ZERO_CODE[
  73 ]gl_DOUBLE_SIGNBIT_CODE[
  74 static double dummy (double x) { return 0; }
  75 int main (int argc, char *argv[])
  76 {
  77   double (*my_expm1) (double) = argc ? expm1 : dummy;
  78   double y = my_expm1 (minus_zerod);
  79   if (!(y == 0.0) || (signbitd (minus_zerod) && !signbitd (y)))
  80     return 1;
  81   return 0;
  82 }
  83               ]])],
  84               [gl_cv_func_expm1_ieee=yes],
  85               [gl_cv_func_expm1_ieee=no],
  86               [gl_cv_func_expm1_ieee="guessing no"])
  87             LIBS="$save_LIBS"
  88           ])
  89         case "$gl_cv_func_expm1_ieee" in
  90           *yes) ;;
  91           *) REPLACE_EXPM1=1 ;;
  92         esac
  93       fi
  94     ])
  95   else
  96     HAVE_EXPM1=0
  97   fi
  98   if test $HAVE_EXPM1 = 0 || test $REPLACE_EXPM1 = 1; then
  99     dnl Find libraries needed to link lib/expm1.c.
 100     AC_REQUIRE([gl_FUNC_ISNAND])
 101     AC_REQUIRE([gl_FUNC_EXP])
 102     AC_REQUIRE([gl_FUNC_ROUND])
 103     AC_REQUIRE([gl_FUNC_LDEXP])
 104     EXPM1_LIBM=
 105     dnl Append $ISNAND_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 106     case " $EXPM1_LIBM " in
 107       *" $ISNAND_LIBM "*) ;;
 108       *) EXPM1_LIBM="$EXPM1_LIBM $ISNAND_LIBM" ;;
 109     esac
 110     dnl Append $EXP_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 111     case " $EXPM1_LIBM " in
 112       *" $EXP_LIBM "*) ;;
 113       *) EXPM1_LIBM="$EXPM1_LIBM $EXP_LIBM" ;;
 114     esac
 115     dnl Append $ROUND_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 116     case " $EXPM1_LIBM " in
 117       *" $ROUND_LIBM "*) ;;
 118       *) EXPM1_LIBM="$EXPM1_LIBM $ROUND_LIBM" ;;
 119     esac
 120     dnl Append $LDEXP_LIBM to EXPM1_LIBM, avoiding gratuitous duplicates.
 121     case " $EXPM1_LIBM " in
 122       *" $LDEXP_LIBM "*) ;;
 123       *) EXPM1_LIBM="$EXPM1_LIBM $LDEXP_LIBM" ;;
 124     esac
 125   fi
 126   AC_SUBST([EXPM1_LIBM])
 127 ])