m4/fchdir.m4

   1 # fchdir.m4 serial 17
   2 dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  12
  13   AC_CHECK_DECLS_ONCE([fchdir])
  14   if test $ac_cv_have_decl_fchdir = no; then
  15     HAVE_DECL_FCHDIR=0
  16   fi
  17
  18   AC_REQUIRE([gl_TEST_FCHDIR])
  19   if test $HAVE_FCHDIR = 0; then
  20     AC_LIBOBJ([fchdir])
  21     gl_PREREQ_FCHDIR
  22     AC_DEFINE([REPLACE_FCHDIR], [1],
  23       [Define to 1 if gnulib's fchdir() replacement is used.])
  24     dnl We must also replace anything that can manipulate a directory fd,
  25     dnl to keep our bookkeeping up-to-date.  We don't have to replace
  26     dnl fstatat, since no platform has fstatat but lacks fchdir.
  27     REPLACE_OPENDIR=1
  28     REPLACE_CLOSEDIR=1
  29     REPLACE_DUP=1
  30     gl_REPLACE_FCNTL
  31     AC_CACHE_CHECK([whether open can visit directories],
  32       [gl_cv_func_open_directory_works],
  33       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
  34 ]], [return open(".", O_RDONLY) < 0;])],
  35         [gl_cv_func_open_directory_works=yes],
  36         [gl_cv_func_open_directory_works=no],
  37         [gl_cv_func_open_directory_works="guessing no"])])
  38     if test "$gl_cv_func_open_directory_works" != yes; then
  39       AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  40 work around the inability to open a directory.])
  41       REPLACE_FSTAT=1
  42     fi
  43   fi
  44 ])
  45
  46 # Determine whether to use the overrides in lib/fchdir.c.
  47 AC_DEFUN([gl_TEST_FCHDIR],
  48 [
  49   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  50   AC_CHECK_FUNCS_ONCE([fchdir])
  51   if test $ac_cv_func_fchdir = no; then
  52     HAVE_FCHDIR=0
  53   fi
  54 ])
  55
  56 # Prerequisites of lib/fchdir.c.
  57 AC_DEFUN([gl_PREREQ_FCHDIR], [:])