m4/fcntl_h.m4

   1 # serial 4
   2 # Configure fcntl.h.
   3 dnl Copyright (C) 2006, 2007, 2009 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl Written by Paul Eggert.
   9
  10 AC_DEFUN([gl_FCNTL_H],
  11 [
  12   AC_REQUIRE([gl_FCNTL_H_DEFAULTS])
  13   dnl Persuade glibc <fcntl.h> to define O_NOATIME and O_NOFOLLOW.
  14   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  15   AC_CACHE_CHECK([for working fcntl.h], [gl_cv_header_working_fcntl_h],
  16     [AC_RUN_IFELSE(
  17        [AC_LANG_PROGRAM(
  18           [[#include <sys/types.h>
  19            #include <sys/stat.h>
  20            #include <unistd.h>
  21            #include <fcntl.h>
  22            #ifndef O_NOATIME
  23             #define O_NOATIME 0
  24            #endif
  25            #ifndef O_NOFOLLOW
  26             #define O_NOFOLLOW 0
  27            #endif
  28            static int const constants[] =
  29             {
  30               O_CREAT, O_EXCL, O_NOCTTY, O_TRUNC, O_APPEND,
  31               O_NONBLOCK, O_SYNC, O_ACCMODE, O_RDONLY, O_RDWR, O_WRONLY
  32             };
  33           ]],
  34           [[
  35             int status = !constants;
  36             {
  37               static char const sym[] = "conftest.sym";
  38               if (symlink (".", sym) != 0
  39                   || close (open (sym, O_RDONLY | O_NOFOLLOW)) == 0)
  40                 status |= 32;
  41             }
  42             {
  43               static char const file[] = "confdefs.h";
  44               int fd = open (file, O_RDONLY | O_NOATIME);
  45               char c;
  46               struct stat st0, st1;
  47               if (fd < 0
  48                   || fstat (fd, &st0) != 0
  49                   || sleep (1) != 0
  50                   || read (fd, &c, 1) != 1
  51                   || close (fd) != 0
  52                   || stat (file, &st1) != 0
  53                   || st0.st_atime != st1.st_atime)
  54                 status |= 64;
  55             }
  56             return status;]])],
  57        [gl_cv_header_working_fcntl_h=yes],
  58        [case $? in #(
  59         32) gl_cv_header_working_fcntl_h='no (bad O_NOFOLLOW)';; #(
  60         64) gl_cv_header_working_fcntl_h='no (bad O_NOATIME)';; #(
  61         96) gl_cv_header_working_fcntl_h='no (bad O_NOATIME, O_NOFOLLOW)';; #(
  62          *) gl_cv_header_working_fcntl_h='no';;
  63         esac],
  64        [gl_cv_header_working_fcntl_h=cross-compiling])])
  65
  66   case $gl_cv_header_working_fcntl_h in #(
  67   *O_NOATIME* | no | cross-compiling) ac_val=0;; #(
  68   *) ac_val=1;;
  69   esac
  70   AC_DEFINE_UNQUOTED([HAVE_WORKING_O_NOATIME], [$ac_val],
  71     [Define to 1 if O_NOATIME works.])
  72
  73   case $gl_cv_header_working_fcntl_h in #(
  74   *O_NOFOLLOW* | no | cross-compiling) ac_val=0;; #(
  75   *) ac_val=1;;
  76   esac
  77   AC_DEFINE_UNQUOTED([HAVE_WORKING_O_NOFOLLOW], [$ac_val],
  78     [Define to 1 if O_NOFOLLOW works.])
  79
  80   gl_CHECK_NEXT_HEADERS([fcntl.h])
  81   FCNTL_H='fcntl.h'
  82   AC_SUBST([FCNTL_H])
  83 ])
  84
  85 AC_DEFUN([gl_FCNTL_MODULE_INDICATOR],
  86 [
  87   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  88   AC_REQUIRE([gl_FCNTL_H_DEFAULTS])
  89   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  90 ])
  91
  92 AC_DEFUN([gl_FCNTL_H_DEFAULTS],
  93 [
  94   GNULIB_OPEN=0;    AC_SUBST([GNULIB_OPEN])
  95   GNULIB_OPENAT=0;  AC_SUBST([GNULIB_OPENAT])
  96   dnl Assume proper GNU behavior unless another module says otherwise.
  97   HAVE_OPENAT=1;    AC_SUBST([HAVE_OPENAT])
  98   REPLACE_OPEN=0;   AC_SUBST([REPLACE_OPEN])
  99   REPLACE_OPENAT=0; AC_SUBST([REPLACE_OPENAT])
 100 ])