m4/floorf.m4

   1 # floorf.m4 serial 13
   2 dnl Copyright (C) 2007, 2009-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FLOORF],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_floorf_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare floorf().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   dnl Test whether floorf() is declared.
  14   AC_CHECK_DECLS([floorf], , , [[#include <math.h>]])
  15   if test "$ac_cv_have_decl_floorf" = yes; then
  16     dnl Test whether floorf() can be used without libm.
  17     gl_FUNC_FLOORF_LIBS
  18     if test "$FLOORF_LIBM" = "?"; then
  19       dnl Sun C 5.0 on Solaris declares floorf() and has it in the system-wide
  20       dnl libm.so, but not in the libm.so that the compiler uses.
  21       REPLACE_FLOORF=1
  22     fi
  23     m4_ifdef([gl_FUNC_FLOORF_IEEE], [
  24       if test $gl_floorf_required = ieee && test $REPLACE_FLOORF = 0; then
  25         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  26         AC_CACHE_CHECK([whether floorf works according to ISO C 99 with IEC 60559],
  27           [gl_cv_func_floorf_ieee],
  28           [
  29             save_LIBS="$LIBS"
  30             LIBS="$LIBS $FLOORF_LIBM"
  31             AC_RUN_IFELSE(
  32               [AC_LANG_SOURCE([[
  33 #ifndef __NO_MATH_INLINES
  34 # define __NO_MATH_INLINES 1 /* for glibc */
  35 #endif
  36 #include <math.h>
  37 ]gl_FLOAT_MINUS_ZERO_CODE[
  38 ]gl_FLOAT_SIGNBIT_CODE[
  39 static float dummy (float f) { return 0; }
  40 int main (int argc, char *argv[])
  41 {
  42   float (*my_floorf) (float) = argc ? floorf : dummy;
  43   /* Test whether floorf (-0.0f) is -0.0f.  */
  44   if (signbitf (minus_zerof) && !signbitf (my_floorf (minus_zerof)))
  45     return 1;
  46   return 0;
  47 }
  48               ]])],
  49               [gl_cv_func_floorf_ieee=yes],
  50               [gl_cv_func_floorf_ieee=no],
  51               [case "$host_os" in
  52                          # Guess yes on glibc systems.
  53                  *-gnu*) gl_cv_func_floorf_ieee="guessing yes" ;;
  54                          # If we don't know, assume the worst.
  55                  *)      gl_cv_func_floorf_ieee="guessing no" ;;
  56                esac
  57               ])
  58             LIBS="$save_LIBS"
  59           ])
  60         case "$gl_cv_func_floorf_ieee" in
  61           *yes) ;;
  62           *) REPLACE_FLOORF=1 ;;
  63         esac
  64       fi
  65     ])
  66   else
  67     HAVE_DECL_FLOORF=0
  68   fi
  69   if test $HAVE_DECL_FLOORF = 0 || test $REPLACE_FLOORF = 1; then
  70     dnl No libraries are needed to link lib/floorf.c.
  71     FLOORF_LIBM=
  72   fi
  73   AC_SUBST([FLOORF_LIBM])
  74 ])
  75
  76 # Determines the libraries needed to get the floorf() function.
  77 # Sets FLOORF_LIBM.
  78 AC_DEFUN([gl_FUNC_FLOORF_LIBS],
  79 [
  80   gl_CACHE_VAL_SILENT([gl_cv_func_floorf_libm], [
  81     gl_cv_func_floorf_libm=?
  82     AC_LINK_IFELSE(
  83       [AC_LANG_PROGRAM(
  84          [[#ifndef __NO_MATH_INLINES
  85            # define __NO_MATH_INLINES 1 /* for glibc */
  86            #endif
  87            #include <math.h>
  88            float (*funcptr) (float) = floorf;
  89            float x;]],
  90          [[x = funcptr(x) + floorf(x);]])],
  91       [gl_cv_func_floorf_libm=])
  92     if test "$gl_cv_func_floorf_libm" = "?"; then
  93       save_LIBS="$LIBS"
  94       LIBS="$LIBS -lm"
  95       AC_LINK_IFELSE(
  96         [AC_LANG_PROGRAM(
  97            [[#ifndef __NO_MATH_INLINES
  98              # define __NO_MATH_INLINES 1 /* for glibc */
  99              #endif
 100              #include <math.h>
 101              float (*funcptr) (float) = floorf;
 102              float x;]],
 103            [[x = funcptr(x) + floorf(x);]])],
 104         [gl_cv_func_floorf_libm="-lm"])
 105       LIBS="$save_LIBS"
 106     fi
 107   ])
 108   FLOORF_LIBM="$gl_cv_func_floorf_libm"
 109 ])