m4/free.m4

   1 # Check whether free (NULL) is supposed to work.
   2
   3 # Copyright (C) 2003-2005, 2009-2014 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Paul Eggert.
   9
  10 # We can't test for free (NULL) even at runtime, since it might
  11 # happen to "work" for our test program, but not in general.  So, be
  12 # conservative and use feature tests for relatively modern hosts,
  13 # where free (NULL) is known to work.  This costs a bit of
  14 # performance on some older hosts, but we can fix that later if
  15 # needed.
  16
  17 AC_DEFUN([gl_FUNC_FREE],
  18 [
  19   AC_REQUIRE([AC_CANONICAL_HOST])
  20   AC_CACHE_CHECK([whether free (NULL) is known to work],
  21     [gl_cv_func_free],
  22     [case "$host_os" in
  23        mingw*) gl_cv_func_free=yes ;;
  24        *)
  25          AC_COMPILE_IFELSE(
  26            [AC_LANG_PROGRAM(
  27               [[@%:@include <unistd.h>]],
  28               [[@%:@if _POSIX_VERSION < 199009L && \
  29                     (defined unix || defined _unix || defined _unix_ \
  30                      || defined __unix || defined __unix__)
  31                   @%:@error "'free (NULL)' is not known to work"
  32                 @%:@endif]])],
  33            [gl_cv_func_free=yes],
  34            [gl_cv_func_free=no])
  35      esac
  36     ])
  37
  38   if test $gl_cv_func_free = no; then
  39     AC_DEFINE([free], [rpl_free],
  40       [Define to rpl_free if the replacement function should be used.])
  41   fi
  42 ])
  43
  44 # Prerequisites of lib/free.c.
  45 AC_DEFUN([gl_PREREQ_FREE], [:])