m4/fseeko.m4

   1 # fseeko.m4 serial 13
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSEEKO],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([gl_HAVE_FSEEKO])
  11   AC_REQUIRE([gl_STDIN_LARGE_OFFSET])
  12
  13   AC_CHECK_DECLS_ONCE([fseeko])
  14   if test $ac_cv_have_decl_fseeko = no; then
  15     HAVE_DECL_FSEEKO=0
  16   fi
  17
  18   if test $gl_cv_func_fseeko = no; then
  19     HAVE_FSEEKO=0
  20   else
  21     if test $gl_cv_var_stdin_large_offset = no; then
  22       REPLACE_FSEEKO=1
  23     fi
  24     m4_ifdef([gl_FUNC_FFLUSH_STDIN], [
  25       gl_FUNC_FFLUSH_STDIN
  26       if test $gl_cv_func_fflush_stdin = no; then
  27         REPLACE_FSEEKO=1
  28       fi
  29     ])
  30   fi
  31   if test $HAVE_FSEEKO = 0 || test $REPLACE_FSEEKO = 1; then
  32     dnl If we are also using the fseek module, then fseek needs replacing, too.
  33     m4_ifdef([gl_REPLACE_FSEEK], [gl_REPLACE_FSEEK])
  34   fi
  35 ])
  36
  37 dnl Tests whether fseeko is available.
  38 dnl Result is gl_cv_func_fseeko.
  39 AC_DEFUN([gl_HAVE_FSEEKO],
  40 [
  41   AC_REQUIRE([AC_PROG_CC])
  42
  43   dnl Persuade glibc <stdio.h> to declare fseeko().
  44   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  45
  46   AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
  47     [
  48       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  49 ]], [fseeko (stdin, 0, 0);])],
  50         [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
  51     ])
  52 ])
  53
  54 dnl Code shared by fseeko and ftello.  Determine if large files are supported,
  55 dnl but stdin does not start as a large file by default.
  56 AC_DEFUN([gl_STDIN_LARGE_OFFSET],
  57   [
  58     AC_CACHE_CHECK([whether stdin defaults to large file offsets],
  59       [gl_cv_var_stdin_large_offset],
  60       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]],
  61 [[#if defined __SL64 && defined __SCLE /* cygwin */
  62   /* Cygwin 1.5.24 and earlier fail to put stdin in 64-bit mode, making
  63      fseeko/ftello needlessly fail.  This bug was fixed in 1.5.25, and
  64      it is easier to do a version check than building a runtime test.  */
  65 # include <cygwin/version.h>
  66 # if CYGWIN_VERSION_DLL_COMBINED < CYGWIN_VERSION_DLL_MAKE_COMBINED (1005, 25)
  67   choke me
  68 # endif
  69 #endif]])],
  70         [gl_cv_var_stdin_large_offset=yes],
  71         [gl_cv_var_stdin_large_offset=no])])
  72 ])