m4/getopt.m4

   1 # getopt.m4 serial 24
   2 dnl Copyright (C) 2002-2006, 2008-2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # Request a POSIX compliant getopt function.
   8 AC_DEFUN([gl_FUNC_GETOPT_POSIX],
   9 [
  10   m4_divert_text([DEFAULTS], [gl_getopt_required=POSIX])
  11   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  12   gl_GETOPT_IFELSE([
  13     gl_REPLACE_GETOPT
  14   ],
  15   [])
  16 ])
  17
  18 # Request a POSIX compliant getopt function with GNU extensions (such as
  19 # options with optional arguments) and the functions getopt_long,
  20 # getopt_long_only.
  21 AC_DEFUN([gl_FUNC_GETOPT_GNU],
  22 [
  23   m4_divert_text([INIT_PREPARE], [gl_getopt_required=GNU])
  24
  25   AC_REQUIRE([gl_FUNC_GETOPT_POSIX])
  26 ])
  27
  28 # Request the gnulib implementation of the getopt functions unconditionally.
  29 # argp.m4 uses this.
  30 AC_DEFUN([gl_REPLACE_GETOPT],
  31 [
  32   dnl Arrange for getopt.h to be created.
  33   gl_GETOPT_SUBSTITUTE_HEADER
  34   dnl Arrange for unistd.h to include getopt.h.
  35   GNULIB_UNISTD_H_GETOPT=1
  36   dnl Arrange to compile the getopt implementation.
  37   AC_LIBOBJ([getopt])
  38   AC_LIBOBJ([getopt1])
  39   gl_PREREQ_GETOPT
  40 ])
  41
  42 # emacs' configure.in uses this.
  43 AC_DEFUN([gl_GETOPT_IFELSE],
  44 [
  45   AC_REQUIRE([gl_GETOPT_CHECK_HEADERS])
  46   AS_IF([test -n "$gl_replace_getopt"], [$1], [$2])
  47 ])
  48
  49 # Determine whether to replace the entire getopt facility.
  50 AC_DEFUN([gl_GETOPT_CHECK_HEADERS],
  51 [
  52   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  53
  54   dnl Persuade Solaris <unistd.h> to declare optarg, optind, opterr, optopt.
  55   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  56
  57   gl_CHECK_NEXT_HEADERS([getopt.h])
  58   AC_CHECK_HEADERS_ONCE([getopt.h])
  59   if test $ac_cv_header_getopt_h = yes; then
  60     HAVE_GETOPT_H=1
  61   else
  62     HAVE_GETOPT_H=0
  63   fi
  64   AC_SUBST([HAVE_GETOPT_H])
  65
  66   gl_replace_getopt=
  67
  68   dnl Test whether <getopt.h> is available.
  69   if test -z "$gl_replace_getopt" && test $gl_getopt_required = GNU; then
  70     AC_CHECK_HEADERS([getopt.h], [], [gl_replace_getopt=yes])
  71   fi
  72
  73   dnl Test whether the function getopt_long is available.
  74   if test -z "$gl_replace_getopt" && test $gl_getopt_required = GNU; then
  75     AC_CHECK_FUNCS([getopt_long_only], [], [gl_replace_getopt=yes])
  76   fi
  77
  78   dnl BSD getopt_long uses an incompatible method to reset option processing.
  79   dnl Existence of the variable, in and of itself, is not a reason to replace
  80   dnl getopt, but knowledge of the variable is needed to determine how to
  81   dnl reset and whether a reset reparses the environment.
  82   if test -z "$gl_replace_getopt" && test $gl_getopt_required = GNU; then
  83     AC_CHECK_DECLS([optreset], [], [],
  84       [[#include <getopt.h>]])
  85   fi
  86
  87   dnl mingw's getopt (in libmingwex.a) does weird things when the options
  88   dnl strings starts with '+' and it's not the first call.  Some internal state
  89   dnl is left over from earlier calls, and neither setting optind = 0 nor
  90   dnl setting optreset = 1 get rid of this internal state.
  91   if test -z "$gl_replace_getopt"; then
  92     AC_CACHE_CHECK([whether getopt is POSIX compatible],
  93       [gl_cv_func_getopt_posix],
  94       [
  95         dnl This test fails on mingw and succeeds on all other platforms.
  96         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  97 #include <unistd.h>
  98 #include <stdlib.h>
  99 #include <string.h>
 100
 101 #if !HAVE_DECL_OPTRESET
 102 # define OPTIND_MIN 0
 103 #else
 104 # define OPTIND_MIN 1
 105 #endif
 106
 107 int
 108 main ()
 109 {
 110   {
 111     int argc = 0;
 112     char *argv[10];
 113     int c;
 114
 115     argv[argc++] = "program";
 116     argv[argc++] = "-a";
 117     argv[argc++] = "foo";
 118     argv[argc++] = "bar";
 119     argv[argc] = NULL;
 120     optind = OPTIND_MIN;
 121     opterr = 0;
 122
 123     c = getopt (argc, argv, "ab");
 124     if (!(c == 'a'))
 125       return 1;
 126     c = getopt (argc, argv, "ab");
 127     if (!(c == -1))
 128       return 2;
 129     if (!(optind == 2))
 130       return 3;
 131   }
 132   /* Some internal state exists at this point.  */
 133   {
 134     int argc = 0;
 135     char *argv[10];
 136     int c;
 137
 138     argv[argc++] = "program";
 139     argv[argc++] = "donald";
 140     argv[argc++] = "-p";
 141     argv[argc++] = "billy";
 142     argv[argc++] = "duck";
 143     argv[argc++] = "-a";
 144     argv[argc++] = "bar";
 145     argv[argc] = NULL;
 146     optind = OPTIND_MIN;
 147     opterr = 0;
 148
 149     c = getopt (argc, argv, "+abp:q:");
 150     if (!(c == -1))
 151       return 4;
 152     if (!(strcmp (argv[0], "program") == 0))
 153       return 5;
 154     if (!(strcmp (argv[1], "donald") == 0))
 155       return 6;
 156     if (!(strcmp (argv[2], "-p") == 0))
 157       return 7;
 158     if (!(strcmp (argv[3], "billy") == 0))
 159       return 8;
 160     if (!(strcmp (argv[4], "duck") == 0))
 161       return 9;
 162     if (!(strcmp (argv[5], "-a") == 0))
 163       return 10;
 164     if (!(strcmp (argv[6], "bar") == 0))
 165       return 11;
 166     if (!(optind == 1))
 167       return 12;
 168   }
 169
 170   return 0;
 171 }
 172 ]])],
 173           [gl_cv_func_getopt_posix=yes], [gl_cv_func_getopt_posix=no],
 174           [case "$host_os" in
 175              mingw*) gl_cv_func_getopt_posix="guessing no";;
 176              *)      gl_cv_func_getopt_posix="guessing yes";;
 177            esac
 178           ])
 179       ])
 180     case "$gl_cv_func_getopt_posix" in
 181       *no) gl_replace_getopt=yes ;;
 182     esac
 183   fi
 184
 185   if test -z "$gl_replace_getopt" && test $gl_getopt_required = GNU; then
 186     AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_getopt_gnu],
 187       [# Even with POSIXLY_CORRECT, the GNU extension of leading '-' in the
 188        # optstring is necessary for programs like m4 that have POSIX-mandated
 189        # semantics for supporting options interspersed with files.
 190        gl_had_POSIXLY_CORRECT=${POSIXLY_CORRECT:+yes}
 191        POSIXLY_CORRECT=1
 192        export POSIXLY_CORRECT
 193        AC_RUN_IFELSE(
 194         [AC_LANG_PROGRAM([[#include <getopt.h>
 195                            #include <stddef.h>
 196                            #include <string.h>
 197 #if !HAVE_DECL_OPTRESET
 198 # define OPTIND_MIN 0
 199 #else
 200 # define OPTIND_MIN (optreset = 1)
 201 #endif
 202            ]], [[
 203              /* This code succeeds on glibc 2.8, OpenBSD 4.0, Cygwin, mingw,
 204                 and fails on MacOS X 10.5, AIX 5.2, HP-UX 11, IRIX 6.5,
 205                 OSF/1 5.1, Solaris 10.  */
 206              {
 207                char *myargv[3];
 208                myargv[0] = "conftest";
 209                myargv[1] = "-+";
 210                myargv[2] = 0;
 211                opterr = 0;
 212                if (getopt (2, myargv, "+a") != '?')
 213                  return 1;
 214              }
 215              /* This code succeeds on glibc 2.8, mingw,
 216                 and fails on MacOS X 10.5, OpenBSD 4.0, AIX 5.2, HP-UX 11,
 217                 IRIX 6.5, OSF/1 5.1, Solaris 10, Cygwin 1.5.x.  */
 218              {
 219                char *argv[] = { "program", "-p", "foo", "bar", NULL };
 220
 221                optind = 1;
 222                if (getopt (4, argv, "p::") != 'p')
 223                  return 2;
 224                if (optarg != NULL)
 225                  return 3;
 226                if (getopt (4, argv, "p::") != -1)
 227                  return 4;
 228                if (optind != 2)
 229                  return 5;
 230              }
 231              /* This code succeeds on glibc 2.8 and fails on Cygwin 1.7.0.  */
 232              {
 233                char *argv[] = { "program", "foo", "-p", NULL };
 234                optind = OPTIND_MIN;
 235                if (getopt (3, argv, "-p") != 1)
 236                  return 6;
 237                if (getopt (3, argv, "-p") != 'p')
 238                  return 7;
 239              }
 240              return 0;
 241            ]])],
 242         [gl_cv_func_getopt_gnu=yes],
 243         [gl_cv_func_getopt_gnu=no],
 244         [dnl Cross compiling. Guess based on host and declarations.
 245          case $host_os:$ac_cv_have_decl_optreset in
 246            *-gnu*:* | mingw*:*) gl_cv_func_getopt_gnu=no;;
 247            *:yes)               gl_cv_func_getopt_gnu=no;;
 248            *)                   gl_cv_func_getopt_gnu=yes;;
 249          esac
 250         ])
 251        if test "$gl_had_POSIXLY_CORRECT" != yes; then
 252          AS_UNSET([POSIXLY_CORRECT])
 253        fi
 254       ])
 255     if test "$gl_cv_func_getopt_gnu" = "no"; then
 256       gl_replace_getopt=yes
 257     fi
 258   fi
 259 ])
 260
 261 # emacs' configure.in uses this.
 262 AC_DEFUN([gl_GETOPT_SUBSTITUTE_HEADER],
 263 [
 264   GETOPT_H=getopt.h
 265   AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
 266     [Define to rpl_ if the getopt replacement functions and variables
 267      should be used.])
 268   AC_SUBST([GETOPT_H])
 269 ])
 270
 271 # Prerequisites of lib/getopt*.
 272 # emacs' configure.in uses this.
 273 AC_DEFUN([gl_PREREQ_GETOPT],
 274 [
 275   AC_CHECK_DECLS_ONCE([getenv])
 276 ])