m4/gettimeofday.m4

   1 # serial 18
   2
   3 # Copyright (C) 2001-2003, 2005, 2007, 2009-2012 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Jim Meyering.
   9
  10 AC_DEFUN([gl_FUNC_GETTIMEOFDAY],
  11 [
  12   AC_REQUIRE([AC_C_RESTRICT])
  13   AC_REQUIRE([gl_HEADER_SYS_TIME_H])
  14   AC_REQUIRE([gl_HEADER_SYS_TIME_H_DEFAULTS])
  15   AC_CHECK_FUNCS_ONCE([gettimeofday])
  16
  17   gl_gettimeofday_timezone=void
  18   if test $ac_cv_func_gettimeofday != yes; then
  19     HAVE_GETTIMEOFDAY=0
  20   else
  21     gl_FUNC_GETTIMEOFDAY_CLOBBER
  22     AC_CACHE_CHECK([for gettimeofday with POSIX signature],
  23       [gl_cv_func_gettimeofday_posix_signature],
  24       [AC_COMPILE_IFELSE(
  25          [AC_LANG_PROGRAM(
  26             [[#include <sys/time.h>
  27               struct timeval c;
  28               int gettimeofday (struct timeval *restrict, void *restrict);
  29             ]],
  30             [[/* glibc uses struct timezone * rather than the POSIX void *
  31                  if _GNU_SOURCE is defined.  However, since the only portable
  32                  use of gettimeofday uses NULL as the second parameter, and
  33                  since the glibc definition is actually more typesafe, it is
  34                  not worth wrapping this to get a compliant signature.  */
  35               int (*f) (struct timeval *restrict, void *restrict)
  36                 = gettimeofday;
  37               int x = f (&c, 0);
  38               return !(x | c.tv_sec | c.tv_usec);
  39             ]])],
  40           [gl_cv_func_gettimeofday_posix_signature=yes],
  41           [AC_COMPILE_IFELSE(
  42             [AC_LANG_PROGRAM(
  43               [[#include <sys/time.h>
  44 int gettimeofday (struct timeval *restrict, struct timezone *restrict);
  45               ]])],
  46             [gl_cv_func_gettimeofday_posix_signature=almost],
  47             [gl_cv_func_gettimeofday_posix_signature=no])])])
  48     if test $gl_cv_func_gettimeofday_posix_signature = almost; then
  49       gl_gettimeofday_timezone='struct timezone'
  50     elif test $gl_cv_func_gettimeofday_posix_signature != yes; then
  51       REPLACE_GETTIMEOFDAY=1
  52     fi
  53     dnl If we override 'struct timeval', we also have to override gettimeofday.
  54     if test $REPLACE_STRUCT_TIMEVAL = 1; then
  55       REPLACE_GETTIMEOFDAY=1
  56     fi
  57     m4_ifdef([gl_FUNC_TZSET_CLOBBER], [
  58       gl_FUNC_TZSET_CLOBBER
  59       if test $gl_cv_func_tzset_clobber = yes; then
  60         REPLACE_GETTIMEOFDAY=1
  61         gl_GETTIMEOFDAY_REPLACE_LOCALTIME
  62         AC_DEFINE([tzset], [rpl_tzset],
  63           [Define to rpl_tzset if the wrapper function should be used.])
  64         AC_DEFINE([TZSET_CLOBBERS_LOCALTIME], [1],
  65           [Define if tzset clobbers localtime's static buffer.])
  66       fi
  67     ])
  68   fi
  69   AC_DEFINE_UNQUOTED([GETTIMEOFDAY_TIMEZONE], [$gl_gettimeofday_timezone],
  70     [Define this to 'void' or 'struct timezone' to match the system's
  71      declaration of the second argument to gettimeofday.])
  72 ])
  73
  74
  75 dnl See if gettimeofday clobbers the static buffer that localtime uses
  76 dnl for its return value.  The gettimeofday function from Mac OS X 10.0.4
  77 dnl (i.e., Darwin 1.3.7) has this problem.
  78 dnl
  79 dnl If it does, then arrange to use gettimeofday and localtime only via
  80 dnl the wrapper functions that work around the problem.
  81
  82 AC_DEFUN([gl_FUNC_GETTIMEOFDAY_CLOBBER],
  83 [
  84  AC_REQUIRE([gl_HEADER_SYS_TIME_H])
  85
  86  AC_CACHE_CHECK([whether gettimeofday clobbers localtime buffer],
  87   [gl_cv_func_gettimeofday_clobber],
  88   [AC_RUN_IFELSE(
  89      [AC_LANG_PROGRAM(
  90         [[#include <string.h>
  91           #include <sys/time.h>
  92           #include <time.h>
  93           #include <stdlib.h>
  94         ]],
  95         [[
  96           time_t t = 0;
  97           struct tm *lt;
  98           struct tm saved_lt;
  99           struct timeval tv;
 100           lt = localtime (&t);
 101           saved_lt = *lt;
 102           gettimeofday (&tv, NULL);
 103           return memcmp (lt, &saved_lt, sizeof (struct tm)) != 0;
 104         ]])],
 105      [gl_cv_func_gettimeofday_clobber=no],
 106      [gl_cv_func_gettimeofday_clobber=yes],
 107      dnl When crosscompiling, assume it is broken.
 108      [gl_cv_func_gettimeofday_clobber=yes])])
 109
 110  if test $gl_cv_func_gettimeofday_clobber = yes; then
 111    REPLACE_GETTIMEOFDAY=1
 112    gl_GETTIMEOFDAY_REPLACE_LOCALTIME
 113    AC_DEFINE([GETTIMEOFDAY_CLOBBERS_LOCALTIME], [1],
 114      [Define if gettimeofday clobbers the localtime buffer.])
 115  fi
 116 ])
 117
 118 AC_DEFUN([gl_GETTIMEOFDAY_REPLACE_LOCALTIME], [
 119   AC_DEFINE([gmtime], [rpl_gmtime],
 120     [Define to rpl_gmtime if the replacement function should be used.])
 121   AC_DEFINE([localtime], [rpl_localtime],
 122     [Define to rpl_localtime if the replacement function should be used.])
 123 ])
 124
 125 # Prerequisites of lib/gettimeofday.c.
 126 AC_DEFUN([gl_PREREQ_GETTIMEOFDAY], [
 127   AC_CHECK_HEADERS([sys/timeb.h])
 128   AC_CHECK_FUNCS([_ftime])
 129 ])